コマンドライン版で Maplet アプリケーションを使用するためには、Maple のコードと同じように、Maple のプロンプトに対して Mapletアプリケーションのコードを入力します。

代わりに、テキストエディタを用いて Maplet アプリケーションの定義をテキストファイルに入力する方法もあります。このテキストファイルは、拡張子 .mpl で保存して下さい。

ご利用のオペレーティングシステムに依り、つぎの方法で .mpl ファイルを実行することができます。

* ファイルブラウザでこの .mpl ファイルをダブルクリックします。 あるいは、

* コマンドラインで、引数として maple と filename を入力します。

Maple のコードが、コマンドライン版の Maple で実行されます。Maplet[Display] コマンドによる指定が Maplet アプリケーションの定義に含まれていると、それにより表示が行われます。

with(Maplets[Elements]):
maplet := Maplet([
   "Click a Button:",
   [Button("OK", Shutdown("true")), Button("Cancel", Shutdown())]
]):
result := Maplets[Display](maplet);

use Maplets in
   use Elements in
      maplet := Maplet(
         Window( 'title' = "Hilbert Matrix", [
            ["Dimension: ", TextField['TB1']( "10" )],
            ["Target format: ", DropDownBox['DDB1']( ["Matlab",
             "MatrixMarket", "delimited"] )],
            ["File name:", TextField['TB2']( "hilmat" )],
            [
               Button( "OK", Shutdown(['TB1', 'DDB1', 'TB2']) ),
               Button( "Cancel", Shutdown() )
            ]
         ] )
      );
   end use;
   result := Display( maplet );
end use:
if result <> [] and result[3] <> "" then
   try
      n := parse( result[1] );
   catch:
   end try;
   if type( n, 'integer' ) then
      ExportMatrix(
         result[3],
         LinearAlgebra:-HilbertMatrix( n, outputoptions=[
         'datatype'=float[8]] ),
         'target' = convert( result[2], 'symbol' )
      );
   end if;
end if: