restart:

# Invoke the Maplets Elements subpackage.
with(Maplets[Elements]):

# Define the get file Maplet application. Define an abnormal
# shutdown as one that returns FAIL.
maplet1 := Maplet( 'abnormalshutdown' = "FAIL",
    FileDialog['FD1'](
        
        # Specify the Maplet application title.
        'title' = "Read File",
        
        # The text appears on the approve button.
        'approvecaption' = "OK",

        # Return the value referenced by FD1
        # when "OK" is clicked.
        'onapprove' = Shutdown( ['FD1'] ),

        # Return FAIL when "Cancel" is clicked.
        'oncancel' = Shutdown( "FAIL" )
    )
):

# Assign result to the value returned by the Maplet application.
result := Maplets[Display](maplet1);

# Check that result is a string. If it is a string,
# result is opened.
if type( result, ['string'] ) then
    read result[1];
end if;

with(Maplets[Elements]):

# Define the "onstartup" option to be referenced by A0.
maplet2 := Maplet( 'abnormalshutdown' = "FAIL",
    'onstartup' = 'A0',
    FileDialog( 'reference' = 'FD1',
        'title' = "Read File",
        'approvecaption' = "OK",
        'onapprove' = 'A1',
        'oncancel' = 'A2'
    ),

    # Start the FileDialog.
    Action( 'reference' = 'A0',
        RunDialog( 'dialog' = 'FD1' )
    ),

    # Define the resulting action if "OK" is clicked.
    Action( 'reference' = 'A1',
        Shutdown( '`return`' = 'R1' )
    ),

    # Define the resulting action if "Cancel" is clicked.
    Action( 'reference' = 'A2',
        Shutdown( 'value' = "FAIL" )
    ),
 
    # Return the value of "R1" to Maple session.
    Return( 'reference' = 'R1',
        ReturnItem( 'item' = 'FD1' )
    )
):

result := Maplets[Display](maplet2);

if type( result, ['string'] ) then
    read result[1];
end if;

Maplets[Tools][Print](maplet1);

Maplets[Tools][Print](maplet2);

?Maplets[Examples][GetFile]

print( Maplets[Examples][GetFile] );