NormalForm コマンドは多変数多項式 f を多変数多項式のリスト G で簡約します。この割り算は 単項式順序 (monomial order) T に関して行われます。G が T に関する Groebner 基底 の場合、G を法とする f の同値類の正規表現を与えます。商のリストはオプションの第 4 引数 Q に割り当てられます。

Reduce コマンドは擬除算が用いられることを除き、NormalForm と同様に動作します。結果は  なる擬剰余 r と分母 s と商 Q であり、r/s は正規形となります。NormalForm と Reduce は同じ商 Q を返します (これらは s によって規格化されません)。 実際、これらのコマンドは同じ方法で実装されています。

第 1 引数がリストか集合だった場合、線型代数を用いたスパースなアルゴリズムを用いて全ての多項式を同時に簡約していきます。これは NormalForm や Reduce をリストや集合にマッピングするよりも効率的です。また、この方法は (多項式の次数が高い場合や、項の数が多いなど) 簡約が多く行われると思われる場合にも有効です。このスパースなアルゴリズムは商を計算しません。infolevel[F4] を 4 か 5 に設定するとどの程度の線型方程式系が解かれたか出力するようになります。

T が 単項式順序の短い記述 (ShortMonomialOrder) であった場合、f と G は T を単項式順序とするような環の多項式でなくてはなりません。T が Groebner[MonomialOrder] コマンドによって作られたものだった場合、f と G は T を定義するのに用いた代数の元でなくてはなりません。G が PolynomialIdeal の場合簡約に使うため、T に関する Groebner 基底が自動的に計算されます。

オプションの引数 characteristic=p は G が多項式のリストで、T が単項式順序の短い記述であった場合、その環の標数を指定します。特に指定しなければ値は 0 として扱われます。

normalf コマンドと reduce コマンドはそれぞれ NormalForm と Reduce に置き換えられています。いまは同じ働きをしますが、今後リリースされる Maple ではサポートされない可能性があります。

with(Groebner):

F := [x^2-2*x*z+5, x*y^2+y*z^3, 3*y^2-8*z^3];

G := Basis(F, tdeg(x,y,z));

p := 320*x*y^2+9*x*y^4-96*z^2*y^4*x+1600*y^3-18*y^5*x*z-592*x*z*y^3+45*y^5+240*z*y^4;

NormalForm(p, G, tdeg(x,y,z), 'Q');

Q;

r := p - add(Q[i]*G[i], i=1..nops(G));

expand(r);

q := 3*x^3*y*z^2-x*z^2+y^3+y*z;

NormalForm(q, G, tdeg(x,y,z));

Reduce(q, G, tdeg(x,y,z), 's');

s;

infolevel[F4] := 5:

NormalForm([p,q], G, tdeg(x,y,z));

 19 x 19 with 2 rhs
 symbolic preproc       0.004 sec
 linear solve           0.000 sec
 build result           0.000 sec

with(Ore_algebra):

A := diff_algebra([Dn, n]);

T := MonomialOrder(A, tdeg(Dn));

w1 := 7*n*Dn+1;

w2 := 5*Dn-2;

Reduce(skew_product(n^5*Dn^4-1, w1, A), [w1], T);

w := skew_product(skew_product(n*Dn+5, w1, A), skew_product(n^3*Dn^2, w2, A), A) + Dn^5 - 1;

Reduce(w, [w1, w2], T, 's');

s;

r := NormalForm(w, [w1, w2], T, 'Q');

Q;

normal( w - (skew_product(Q[1], w1, A) + skew_product(Q[2], w2, A)), expanded);

D. Cox, J. Little, D. O'Shea. "Ideals, Varieties, and Algorithms, 2nd edition."  Springer-Verlag, 1997.

R. Pearce, M. Monagan.  "A Sparse Algorithm for Polynomial Division with Application to F4."  in preparation, 2006.