ModuleIterator ルーチンにより、module または object はモジュール (またはオブジェクト) 内に含まれる要素を繰り返すために使用可能なインターフェースを出力します。

モジュールが ModuleIterator ルーチンを定義する場合、そのモジュールは for-in ループのコンテナとして、および seq、add および mul のコールとして使用できます。

ModuleIterator のコールは、2 つのプロシージャを出力します。

(hasNext,getNext) := ModuleIterator( obj );

これらのルーチンを使用するための基本的なパターンは、以下のとおりです。

while hasNext() do
      e := getNext();
      # Do something with e.
  od;

hasNext が true を出力する場合は、getNext のコールは常に安全です。hasNext のコールが false を出力する場合は、getNext のコールのリターン値は未指定です。

ModuleIterator コマンドは Maple 16 で導入されました。

Maple 16 における変更点についての詳細は、Maple 16 の新機能 を参照してください。

Primes := module()
   export ModuleIterator := proc()
       local i;
       i := 1;
       (
           proc()
               i := nextprime( i );
               true;
           end,
           proc()
               i;
           end
       )
   end;
end;

for i in Primes
do
   if ( i > 100 ) then
       break;
   end;
   print( i );
end;

module IterObj()
   option object;
   local _list;
   export setValue::static := proc( obj::IterObj, l::list )
       obj:-_list := l
   end;
   export ModuleIterator::static := proc( obj::IterObj )
       local i, l;
       i := 1;
       l := obj:-_list;
       (
           proc()
               i <= numelems( l )
           end,
           proc()
               local e;
               e := l[i];
               i := i+1;
               e;
           end
       );
   end;
end:

io := Object( IterObj ):

setValue( io, [1,2,3] ):

( hasNext, getNext ) := ModuleIterator( io );

while hasNext() do
   e := getNext();
od;

for i in io
do
    i;
od;

add( i, i in io );

mul( i, i in io );

seq( i^2, i in io );