 Lesson 12: Object and Frame Management - Maple Help

DifferentialGeometry Lessons

Lesson 12: DGinfo Overview

This lesson is dedicated to the Tools command DGinfo.  This command provides access to the information internal to DifferentialGeometry objects (vectors, forms, tensors, and transformations) and to the user-defined coordinate systems, frames, and Lie algebras.The DGinfo command is used primarily when writing new application programs.

In this lesson, you will learn to do the following:

 – Interpret the internal representation of a differential geometry object.
 – Find the frame in which a vector field, differential form, or tensor is defined.
 – Find the domain and range frames of a transformation.
 – Determine the DifferentialGeometry type of a object (ie, vector, differential form, tensor ...).
 – Find the degree of a differential form and the index type of a tensor.
 – Find the differential order of a function, vector field, or differential form defined on a jet space.
 – Obtain the list or set of coefficients of a given vector field, differential form, or tensor.
 – List the coordinates defined for a given frame.
 – Obtain the bases for the tangent space and cotangent space for a given frame.
 – Obtain the structure equations for an anholonomic frame.

For the full list of keyword options for the command DGinfo, see the help page DGinfo. ObjectAttributes, ObjectComponents

All DifferentialGeomety objects are defined by unevaluated functions of the form _DG([A, C]).

 – Here A is the attribute list and C is the component list.
 – The first element of the attribute list A always specifies the object type.
 – The second element of the attribute list A always specifies the frame information for the object.
 – Other attributes include form degree, tensor index type, Jacobian, etc...
 – The component list is a list of two-element sublists C = [C1, C2, C3 , ...].  The first element of the sublist Ck specifies the component and the second element of Ck gives the coefficient for that component.
 – The use of the unevaluated function _DG enables the DifferentialGeometry package to control the printing (and LaTeX formatting) of all the various DifferentialGeometry objects (see print).

The DGinfo keywords "ObjectAttributes", "ObjectComponents" return the attribute list and the component list of the given DifferentialGeometry object.  Other keywords return specific entries in the attribute list and component list.

 > with(DifferentialGeometry): with(Tools):
 E1 > DGsetup([x, y, z], M): DGsetup([t], R):

Define a vector field:

 R > X := evalDG(a*D_x + b*D_y + c*D_z);
 ${X}{≔}{a}{}{\mathrm{D_x}}{+}{b}{}{\mathrm{D_y}}{+}{c}{}{\mathrm{D_z}}$ (2.1)
 M > op(0, X);
 ${\mathrm{_DG}}$ (2.2)
 M > internalX := op(X);
 ${\mathrm{internalX}}{≔}\left[\left[{"vector"}{,}{M}{,}\left[{}\right]\right]{,}\left[\left[\left[{1}\right]{,}{a}\right]{,}\left[\left[{2}\right]{,}{b}\right]{,}\left[\left[{3}\right]{,}{c}\right]\right]\right]$ (2.3)

We see that the internal representation of X is a list with 2 components.

 M > nops(internalX);
 ${2}$ (2.4)
 M > AttributeList := internalX;
 ${\mathrm{AttributeList}}{≔}\left[{"vector"}{,}{M}{,}\left[{}\right]\right]$ (2.5)
 M > ComponentList := internalX;
 ${\mathrm{ComponentList}}{≔}\left[\left[\left[{1}\right]{,}{a}\right]{,}\left[\left[{2}\right]{,}{b}\right]{,}\left[\left[{3}\right]{,}{c}\right]\right]$ (2.6)

The attribute list and component list can be obtained directly from DGinfo.

 M > DGinfo(X, "ObjectAttributes");
 $\left[{"vector"}{,}{M}{,}\left[{}\right]\right]$ (2.7)
 M > DGinfo(X, "ObjectComponents");
 $\left[\left[\left[{1}\right]{,}{a}\right]{,}\left[\left[{2}\right]{,}{b}\right]{,}\left[\left[{3}\right]{,}{c}\right]\right]$ (2.8)

Here are the attribute and component lists for a 2-form alpha.

 M > alpha := evalDG(x^2*dx &w dy - y^2*dy &w dz);
 ${\mathrm{α}}{≔}{{x}}^{{2}}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{-}{{y}}^{{2}}{}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}$ (2.9)
 M > DGinfo(alpha, "ObjectAttributes");
 $\left[{"form"}{,}{M}{,}{2}\right]$ (2.10)
 M > DGinfo(alpha, "ObjectComponents");
 $\left[\left[\left[{1}{,}{2}\right]{,}{{x}}^{{2}}\right]{,}\left[\left[{2}{,}{3}\right]{,}{-}{{y}}^{{2}}\right]\right]$ (2.11)

Here are the attribute and component lists for a rank 3 tensor T.

 M > T := evalDG(dx &t dy &t D_z - dy &t dz &t D_x);
 ${T}{≔}{\mathrm{dx}}{}{\mathrm{dy}}{}{\mathrm{D_z}}{-}{\mathrm{dy}}{}{\mathrm{dz}}{}{\mathrm{D_x}}$ (2.12)
 M > DGinfo(T, "ObjectAttributes");
 $\left[{"tensor"}{,}{M}{,}\left[\left[{"cov_bas"}{,}{"cov_bas"}{,}{"con_bas"}\right]{,}\left[{}\right]\right]\right]$ (2.13)
 M > DGinfo(T, "ObjectComponents");
 $\left[\left[\left[{1}{,}{2}{,}{3}\right]{,}{1}\right]{,}\left[\left[{2}{,}{3}{,}{1}\right]{,}{-}{1}\right]\right]$ (2.14)

Here are the attribute and component lists for a transformation.

 M > Phi := Transformation(R, M, [x = t*cos(t), y = t*sin(t), z = t^2]);
 ${\mathrm{Φ}}{≔}\left[{x}{=}{t}{}{\mathrm{cos}}{}\left({t}\right){,}{y}{=}{t}{}{\mathrm{sin}}{}\left({t}\right){,}{z}{=}{{t}}^{{2}}\right]$ (2.15)
 R > DGinfo(Phi, "ObjectAttributes"); R > DGinfo(Phi, "ObjectComponents");
 $\left[\left[{t}{}{\mathrm{cos}}{}\left({t}\right){,}{x}\right]{,}\left[{t}{}{\mathrm{sin}}{}\left({t}\right){,}{y}\right]{,}\left[{{t}}^{{2}}{,}{z}\right]\right]$ (2.16) ObjectType

The first attribute in the attribute list of a DifferentialGeometry object is its type.  This information can be obtained with the command DGinfo using the keyword "ObjectType".  At present, the following object types are used in the DifferentialGeometry package: "biform", "DE", "form", "LieAlgebra", "moving_frame", "tensor", "transformation", "representation", "vector".

 E1 > with(DifferentialGeometry): with(LieAlgebras): with(Tools):
 R > DGsetup([x, y], M):

Find the type of the differential form dx.

 M > lprint(dx);
 _DG([["form", M, 1], [[, 1]]])
 M > DGinfo(dx, "ObjectType");
 ${"form"}$ (3.1)

Find the type of the vector D_x.

 M > lprint(D_x);
 _DG([["vector", M, []], [[, 1]]])
 M > DGinfo(D_x, "ObjectType");
 ${"vector"}$ (3.2)

Find the type of the tensor D_xdy.

 M > lprint(D_x &tensor dy);
 _DG([["tensor", M, [["con_bas", "cov_bas"], []]], [[[1, 2], 1]]])
 M > DGinfo(D_x &tensor dy, "ObjectType");
 ${"tensor"}$ (3.3)

Find the type of the transformation f.

 M > f := Transformation(M, M, [x= 1, y = y]);
 ${f}{≔}\left[{x}{=}{1}{,}{y}{=}{y}\right]$ (3.4)
 M > lprint(f);
 _DG([["transformation", [[M, 0], [M, 0]], [], [Matrix(2,2,{(2, 2) = 1},datatype = anything,storage = rectangular,order = Fortran_order,shape = [])]], [[1, x], [y, y]]])
 M > DGinfo(f, "ObjectType");
 ${"transformation"}$ (3.5) ObjectFrame, DomainFrame, RangeFrame

If X is a vector field, differential form, or tensor, then the second element in the attribute list is the name of the frame in which the object X is defined.

If X is a transformation, then the second element in the attribute list is a list defining the range and domain of the transformation.

 M > with(DifferentialGeometry): with(Tools):
 M > DGsetup([x, y], M): DGsetup([u, v], N):

Find the frame of the vector D_x.

 N > DGinfo(D_x, "ObjectFrame");
 ${M}$ (4.1)

Find the frame of the 1-form du.

 N > DGinfo(du, "ObjectFrame");
 ${N}$ (4.2)
 N > f := Transformation(M, N, [u = x^2 + y^2, v = x/y]);
 ${f}{≔}\left[{u}{=}{{x}}^{{2}}{+}{{y}}^{{2}}{,}{v}{=}\frac{{x}}{{y}}\right]$ (4.3)

Find the domain and range of the transformation f.

 M > DGinfo(f, "DomainFrame");
 ${M}$ (4.4)
 M > DGinfo(f, "RangeFrame");
 ${N}$ (4.5) FormDegree, TensorType, TensorIndexType, TensorDensityType, TensorIndexPart1, TensorIndexPart2

 M > with(DifferentialGeometry): with(Tensor): with(Tools):
 M > DGsetup([x, y], [u], M):

Find the degree of the differential form alpha.

 M > alpha := evalDG(dx &w dy);
 ${\mathrm{α}}{≔}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}$ (5.1)
 M > DGinfo(alpha, "FormDegree");
 ${2}$ (5.2)

Find the tensor index type and density type of the tensor T.  For a discussion of the different index types, see Lesson 9: Tensor Algebra.

 M > T := evalDG(D_x &t dy &t PermutationSymbol("con_vrt"));
 ${T}{≔}{\mathrm{D_x}}{}{\mathrm{dy}}{}{\mathrm{D_u}}$ (5.3)
 M > DGinfo(T, "TensorType");
 $\left[\left[{"con_bas"}{,}{"cov_bas"}{,}{"con_vrt"}\right]{,}\left[\left[{"vrt"}{,}{1}\right]\right]\right]$ (5.4)

Find just the index type.

 M > DGinfo(T, "TensorIndexType");
 $\left[{"con_bas"}{,}{"cov_bas"}{,}{"con_vrt"}\right]$ (5.5)

Find just the density type.

 M > DGinfo(T, "TensorDensityType");
 $\left[\left[{"vrt"}{,}{1}\right]\right]$ (5.6)

Find the valency type of a tensor index ("con" or "cov").

 M > DGinfo("con_bas", "TensorIndexPart1");
 ${"con"}$ (5.7)

Find the spatial type of a tensor index ("bas" or "vrt").

 M > DGinfo("con_bas", "TensorIndexPart2");
 ${"bas"}$ (5.8) JacobianMatrix

The Jacobian matrix of a transformation defined by the command Transformation is computed and stored in the internal representation of the transformation.  The Jacobian matrix can be retrieved using the command DGinfo with the keyword "JacobianMatrix".

 M > with(DifferentialGeometry): with(Tools):
 M > DGsetup([x, y, z], M): DGsetup([u, v], N):
 N > Phi := Transformation(N, M, [x = u, y = v, z = 1 - u^2 - v^2]);
 ${\mathrm{Φ}}{≔}\left[{x}{=}{u}{,}{y}{=}{v}{,}{z}{=}{1}{-}{{u}}^{{2}}{-}{{v}}^{{2}}\right]$ (6.1)
 N > DGinfo(Phi, "JacobianMatrix");  CoefficientSet, CoefficientList

With the keyword "CoefficientSet", DGinfo returns the set of all coefficients of a vector field, differential form, or tensor.  With the keyword "CoefficientList", one can retrieve a list of all coefficients or just a specific list of coefficients.

 E1 > with(DifferentialGeometry): with(Tools):
 N > DGsetup([x, y, z, w], M):
 M > omega := evalDG(a*dx &w dy + b*dx &w dz + b*dy &w dz + d*dx &w dw + e*dz &w dw);
 ${\mathrm{ω}}{≔}{a}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{+}{b}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dz}}{+}{d}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dw}}{+}{b}{}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}{+}{e}{}{\mathrm{dz}}{}{\mathrm{^}}{}{\mathrm{dw}}$ (7.1)

Find the set of coefficients of the 2-form omega.

 M > DGinfo(omega, "CoefficientSet");
 $\left\{{a}{,}{b}{,}{e}{,}{d}\right\}$ (7.2)

Find the list of all coefficients of omega.

 M > DGinfo(omega, "CoefficientList", "all");
 $\left[{a}{,}{b}{,}{d}{,}{b}{,}{e}\right]$ (7.3)

Find the coefficients of dx^dy, dx^dz, dy^dw in the 2-form omega.

 M > DGinfo(omega, "CoefficientList", [dx &w dy, dx &w dz, dy &w dw]);
 $\left[{a}{,}{b}{,}{0}\right]$ (7.4)

Find the coefficients of dx^dy, dx^dz, dy^dw in the 2-form omega (alternative method).

 M > DGinfo(omega, "CoefficientList", [[1, 2], [1, 3], [2, 4]]);
 $\left[{a}{,}{b}{,}{0}\right]$ (7.5) CurrentFrame, FrameNames, FrameGlobals

The command DGinfo also provides information regarding all the user-defined coordinates systems, frames, and Lie algebras.

 E1 > restart: with(DifferentialGeometry): with(Tools):
 > DGsetup([x, y], M):
 M > DGsetup([t], R):
 R > DGsetup([x, y], [z], E):

Find the current frame.

 E > DGinfo("CurrentFrame");
 ${E}$ (8.1)

List all the defined frames.

 E > DGinfo("FrameNames");
 $\left[{E}{,}{M}{,}{R}\right]$ (8.2)

List all the assigned and protected names for a given frame.

 E > DGinfo(E,"FrameGlobals");
 $\left\{{x}{,}{E}{,}{y}{,}{z}{,}{\mathrm{D_x}}{,}{\mathrm{D_y}}{,}{\mathrm{D_z}}{,}{\mathrm{dx}}{,}{\mathrm{dy}}{,}{\mathrm{dz}}\right\}$ (8.3)

Display all the information for a given frame.

 E > DGinfo(M, "FrameInformation");
 ${\mathrm{frame name: M}}$ ${\mathrm{library name: CoordinateProtocol}}$ ${\mathrm{Frame Variables:}}$ $\left[{x}{,}{y}\right]$ ${\mathrm{Frame Labels}}$ $\left[{\mathrm{D_x}}{,}{\mathrm{D_y}}\right]$ ${\mathrm{Coframe Labels}}$ $\left[{\mathrm{dx}}{,}{\mathrm{dy}}\right]$ ${\mathrm{--------------}}$ (8.4)

If the frame is not a coordinate frame, then "FrameInformation" also returns the structure equations.

 E > ChangeFrame(M):
 M > Omega := FrameData([1/y*dx, 1/x*dy], P);
 ${\mathrm{Ω}}{≔}\left[{d}{}{\mathrm{Θ1}}{=}\frac{{x}{}{\mathrm{Θ1}}{}{\mathrm{^}}{}{\mathrm{Θ2}}}{{y}}{,}{d}{}{\mathrm{Θ2}}{=}{-}\frac{{y}{}{\mathrm{Θ1}}{}{\mathrm{^}}{}{\mathrm{Θ2}}}{{x}}\right]$ (8.5)
 M > DGsetup(Omega, [E], [beta]);
 ${\mathrm{frame name: P}}$ (8.6)
 P > DGinfo(P, "FrameInformation");
 ${\mathrm{frame name: P}}$ ${\mathrm{library name: AnholonomicFrameProtocol}}$ ${\mathrm{Frame Variables:}}$ $\left[{x}{,}{y}\right]$ ${\mathrm{Frame Labels}}$ $\left[{\mathrm{E1}}{,}{\mathrm{E2}}\right]$ ${\mathrm{Coframe Labels}}$ $\left[{\mathrm{β1}}{,}{\mathrm{β2}}\right]$ ${\mathrm{ext_d:}}{,}{x}{,}{y}{}{\mathrm{β1}}$ ${\mathrm{ext_d:}}{,}{y}{,}{x}{}{\mathrm{β2}}$ ${\mathrm{ext_d:}}{,}{\mathrm{β1}}{,}\frac{{x}{}{\mathrm{β1}}{}{\mathrm{^}}{}{\mathrm{β2}}}{{y}}$ ${\mathrm{ext_d:}}{,}{\mathrm{β2}}{,}{-}\frac{{y}{}{\mathrm{β1}}{}{\mathrm{^}}{}{\mathrm{β2}}}{{x}}$ ${\mathrm{--------------}}$ (8.7) FrameBaseDimension, FrameFiberDimension

These keywords simply return the dimensions of the manifold and, in the case of a fiber bundle, the dimensions of the base and fiber spaces.

 P > with(DifferentialGeometry): with(Tools):
 P > DGsetup([x, y, z], M): DGsetup([x, y], [u, v, w, z], E):

Find the dimension of the manifold M.

 E > DGinfo(M, "FrameBaseDimension");
 ${3}$ (9.1)

Find the base dimension of bundle E.

 E > DGinfo(E, "FrameBaseDimension");
 ${2}$ (9.2)

Find the fiber dimension of the bundle E.

 E > DGinfo(E, "FrameFiberDimension");
 ${4}$ (9.3) FrameIndependentVariables, FrameDependentVariables

These keywords simply return the coordinates of the manifold or, in the case of a fiber bundle, the base and fiber space coordinates.

 E > with(DifferentialGeometry): with(Tools):
 E > DGsetup([x, y, z], M):
 M > DGsetup([x, y], [u, v, w, z], E):

Find the coordinates of the manifold M.

 E > DGinfo(M, "FrameIndependentVariables");
 $\left[{x}{,}{y}{,}{z}\right]$ (10.1)

Find the base coordinates for the bundle E.

 E > DGinfo(E, "FrameIndependentVariables");
 $\left[{x}{,}{y}\right]$ (10.2)

Find the fiber coordinates of the bundle E.

 E > DGinfo(E, "FrameDependentVariables");
 $\left[{u}{,}{v}{,}{w}{,}{z}\right]$ (10.3) FrameBaseVectors, FrameBaseForms, FrameFiberVectors, FrameFiberForms

These keywords return the basis for the tangent and cotangent spaces.  These options for DGinfo are useful in conjunction with the commands GetComponents and DGzip.

 E > with(DifferentialGeometry): with(Tools):
 E > DGsetup([x, y, z], M): DGsetup([x, y], [u, v, w, z], E):

List the basis vectors for the tangent space of M.

 E > DGinfo(M, "FrameBaseVectors");
 $\left[{\mathrm{D_x}}{,}{\mathrm{D_y}}{,}{\mathrm{D_z}}\right]$ (11.1)

List the basis of 1-forms for the cotangent space of M.

 M > DGinfo(M, "FrameBaseForms");
 $\left[{\mathrm{dx}}{,}{\mathrm{dy}}{,}{\mathrm{dz}}\right]$ (11.2)

List the basis for the vertical vectors on E.

 M > DGinfo(E, "FrameFiberVectors");
 $\left[{\mathrm{D_u}}{,}{\mathrm{D_v}}{,}{\mathrm{D_w}}{,}{\mathrm{D_z}}\right]$ (11.3)
 E > DGinfo(E, "FrameFiberForms");
 $\left[{\mathrm{du}}{,}{\mathrm{dv}}{,}{\mathrm{dw}}{,}{\mathrm{dz}}\right]$ (11.4)

Here are simple computations which illustrate the use of DGinfo/"FrameBaseVectors" with the commands DGzip and GetComponents.

 E > F := DGinfo(M, "FrameBaseVectors");
 ${F}{≔}\left[{\mathrm{D_x}}{,}{\mathrm{D_y}}{,}{\mathrm{D_z}}\right]$ (11.5)
 M > X := DGzip([a, b, c], F, "plus");
 ${X}{≔}{a}{}{\mathrm{D_x}}{+}{b}{}{\mathrm{D_y}}{+}{c}{}{\mathrm{D_z}}$ (11.6)
 M > C := GetComponents(X, F);
 ${C}{≔}\left[{a}{,}{b}{,}{c}\right]$ (11.7) Exercises Exercise 1

[i]  Find the form degree of alpha.

[ii]  Find the manifold on which the vector X is defined.

[iii]  Find the index structure of the tensor T.

[iv]  Find the coefficient of D_y in the vector X.

[v]  Find the name of the range space for the transformation F.

[vi]  Show that the Jacobian of the transformation F is full rank.

[vii]  How many coordinate systems are presently defined?

[viii]  What are the protected names for the coordinate system N?

[ix]  What is the dimension of the manifold M?

[x]  Create a general 1-form on M whose coefficients are arbitrary functions of the coordinates.

 E1 > restart: with(DifferentialGeometry): with(Tools):
 > DGsetup([x, y, z], M):
 M > DGsetup([t], N):
 N > DGsetup([u, v], P):
 P > X := evalDG(7*D_x - y*D_y + x*D_z);
 ${X}{≔}{7}{}{\mathrm{D_x}}{-}{y}{}{\mathrm{D_y}}{+}{x}{}{\mathrm{D_z}}$ (12.1.1)
 M > omega := evalDG(dx &w dy &w dz);
 ${\mathrm{ω}}{≔}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}$ (12.1.2)
 M > T := evalDG(dx &t D_y &t dz - dy &t D_z &t dz);
 ${T}{≔}{\mathrm{dx}}{}{\mathrm{D_y}}{}{\mathrm{dz}}{-}{\mathrm{dy}}{}{\mathrm{D_z}}{}{\mathrm{dz}}$ (12.1.3)
 M > F := Transformation(M, P, [u = x*y, v = y*z]);
 ${F}{≔}\left[{u}{=}{x}{}{y}{,}{v}{=}{y}{}{z}\right]$ (12.1.4) Solutions

Part [i]  Find the form degree of alpha.

 E1 > DGinfo(omega, "FormDegree");
 ${3}$ (12.1.1.1)

Part [ii]  Find the manifold on which the vector X is defined.

 M > DGinfo(X, "ObjectFrame");
 ${M}$ (12.1.1.2)

Part [iii]  Find the index structure of the tensor T.

 M > DGinfo(T, "TensorIndexType");
 $\left[{"cov_bas"}{,}{"con_bas"}{,}{"cov_bas"}\right]$ (12.1.1.3)

Part [iv]  Find the coefficient of D_y in the vector X.

 M > DGinfo(X, "CoefficientList", [D_y]);
 $\left[{-}{y}\right]$ (12.1.1.4)

Part [v]  Find the name of the range space for the transformation F.

 M > DGinfo(F, "RangeFrame");
 ${P}$ (12.1.1.5)

Part [vi]  Show that the Jacobian of the transformation F is full rank.

 M > J := DGinfo(F, "JacobianMatrix"); M > LinearAlgebra:-Rank(J);
 ${2}$ (12.1.1.6)

Part [vii]  How many coordinate systems are presently defined?

 M > nops(DGinfo("FrameNames"));
 ${3}$ (12.1.1.7)

Part [viii]  What are the protected names for the coordinate system N?

 M > DGinfo(M, "FrameGlobals");
 $\left\{{x}{,}{\mathrm{dx}}{,}{M}{,}{z}{,}{\mathrm{D_x}}{,}{y}{,}{\mathrm{D_y}}{,}{\mathrm{D_z}}{,}{\mathrm{dy}}{,}{\mathrm{dz}}\right\}$ (12.1.1.8)

Part [ix]  What is the dimension of the manifold M?

 M > DGinfo(M, "FrameBaseDimension");
 ${3}$ (12.1.1.9)

Part [x]  Create a general 1-form on M whose coefficients are arbitrary functions of the coordinates.

 M > vars := op(DGinfo(M, "FrameIndependentVariables"));
 ${\mathrm{vars}}{≔}{x}{,}{y}{,}{z}$ (12.1.1.10)
 M > C := [a1, a2, a3](vars);
 ${C}{≔}\left[{\mathrm{a1}}{}\left({x}{,}{y}{,}{z}\right){,}{\mathrm{a2}}{}\left({x}{,}{y}{,}{z}\right){,}{\mathrm{a3}}{}\left({x}{,}{y}{,}{z}\right)\right]$ (12.1.1.11)
 M > Omega := DGinfo(M, "FrameBaseForms");
 ${\mathrm{Ω}}{≔}\left[{\mathrm{dx}}{,}{\mathrm{dy}}{,}{\mathrm{dz}}\right]$ (12.1.1.12)
 M > DGzip(C, Omega, "plus");
 ${\mathrm{a1}}{}\left({x}{,}{y}{,}{z}\right){}{\mathrm{dx}}{+}{\mathrm{a2}}{}\left({x}{,}{y}{,}{z}\right){}{\mathrm{dy}}{+}{\mathrm{a3}}{}\left({x}{,}{y}{,}{z}\right){}{\mathrm{dz}}$ (12.1.1.13) Exercise 2

Write a program TestFormList which will test if a list of differential forms are all defined on the same space and all have the same degree.  Test your program on the following lists of forms.

 M > with(DifferentialGeometry):
 M > DGsetup([x,y,z], M): DGsetup([r,s,t], N):
 N > L1 := evalDG([dx, dy + dz, dx - dy + dz]);
 ${\mathrm{L1}}{≔}\left[{\mathrm{dx}}{,}{\mathrm{dy}}{+}{\mathrm{dz}}{,}{\mathrm{dx}}{-}{\mathrm{dy}}{+}{\mathrm{dz}}\right]$ (12.2.1)
 M > L2 := evalDG([dx, dy, dx &w dy]);
 ${\mathrm{L2}}{≔}\left[{\mathrm{dx}}{,}{\mathrm{dy}}{,}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}\right]$ (12.2.2)
 M > L3 := evalDG([dr,ds,dz]);
 ${\mathrm{L3}}{≔}\left[{\mathrm{dr}}{,}{\mathrm{ds}}{,}{\mathrm{dz}}\right]$ (12.2.3) Solution

 M > TestFormList := proc(Omega)
 M > local fr, p, n, i;
 M > fr := Tools:-DGinfo(Omega, "ObjectFrame");
 M > p := Tools:-DGinfo(Omega, "FormDegree");
 M > n := nops(Omega);
 M > for i from 2 to n do
 M > if Tools:-DGinfo(Omega[i], "ObjectFrame") <> fr then return(false) fi;
 M > if Tools:-DGinfo(Omega[i], "FormDegree") <> p then return(false) fi;
 M > od;
 M > true;
 E1 > end:
 M >
 E1 > TestFormList(L1);
 ${\mathrm{true}}$ (12.2.1.1)
 M > TestFormList(L2);
 ${\mathrm{false}}$ (12.2.1.2)
 M > TestFormList(L3);
 ${\mathrm{false}}$ (12.2.1.3) Exercise 3

Write a program CreateForm which will create a general 1-form on the current manifold.  Design the program to accept a kernel letter for the coefficient functions.

Remark: This program can be generalized to create a general p-form using the command GenerateForms.

 E1 > with(DifferentialGeometry):
 M > DGsetup([x1,x2,x3,x4], P);
 ${\mathrm{frame name: P}}$ (12.3.1) Solution

 M > CreateForm := proc(A)
 M > local M, C, Omega, n, vars;
 M > M := Tools:-DGinfo("CurrentFrame");
 M > Omega := Tools:-DGinfo(M, "FrameBaseForms");
 M > n := nops(Omega):
 M > vars := Tools:-DGinfo(M, "FrameIndependentVariables"):
 M > C:= [seq(cat(A, i), i = 1 .. n)](op(vars));
 M > DGzip(C, Omega, "plus");
 E1 > end:
 P >
 E1 > CreateForm(Q);
 ${\mathrm{Q1}}{}\left({\mathrm{x1}}{,}{\mathrm{x2}}{,}{\mathrm{x3}}{,}{\mathrm{x4}}\right){}{\mathrm{dx1}}{+}{\mathrm{Q2}}{}\left({\mathrm{x1}}{,}{\mathrm{x2}}{,}{\mathrm{x3}}{,}{\mathrm{x4}}\right){}{\mathrm{dx2}}{+}{\mathrm{Q3}}{}\left({\mathrm{x1}}{,}{\mathrm{x2}}{,}{\mathrm{x3}}{,}{\mathrm{x4}}\right){}{\mathrm{dx3}}{+}{\mathrm{Q4}}{}\left({\mathrm{x1}}{,}{\mathrm{x2}}{,}{\mathrm{x3}}{,}{\mathrm{x4}}\right){}{\mathrm{dx4}}$ (12.3.1.1) Exercise 4

The following set of exercises deal with the application of DGinfo to vector fields and differential forms defined on jet spaces.  For each problem, first identify the relevant keyword from the DGinfo help page.

[i]  Find the jet order of the function f, the differential form omega, and the vector field X.

[ii]  Find the order of the jet spaces E1 and E2.

[iii]  Find the dimension of the jet spaces E1 and E2.

[iv]  List the independent variables, the dependent variables, and the jet space variables for the jet space E1.

[v]  List the basis vector fields and differential forms for the jet space E2.

[vi]  List the contact 1-forms defined on the jet space E1.

[vii]  Find the order of the domain jet space for the transformations Phi and PhiP.  Find the order of the range jet space for the transformations Phi and PhiP.

[viii] Find the type of the vector fields Y1, Y1P, Y2, and Y2P (See the help page AssignVectorType)

[ix]  Find the type of the transformations Phi1, Phi1P, Phi2, and PhiP (See the help page AssignTransformationType)

[x]  Find the variables in the expression A which are jet variables for the jet space E1.

[xi]  Find the variables in the expression A which are not jet variables for the jet space E1.

 E1 > with(DifferentialGeometry): with(JetCalculus): with(Tools):
 P > DGsetup([t], [u], E1, 3):
 E1 > DGsetup([x, y], [z], E2, 2):
 E2 > f := z[1, 1, 1]*z[2, 2]^2;
 ${f}{≔}{{z}}_{{1}{,}{1}{,}{1}}{}{{z}}_{{2}{,}{2}}^{{2}}$ (12.4.1)
 E2 > omega := evalDG(u[1, 1] &t du[1, 1, 1]);
 ${\mathrm{ω}}{≔}{{u}}_{{1}{,}{1}}{}{{\mathrm{du}}}_{{1}{,}{1}{,}{1}}$ (12.4.2)
 E1 > X := u[1, 1, 2, 2, 2]*D_x;
 ${X}{≔}{{u}}_{{1}{,}{1}{,}{2}{,}{2}{,}{2}}{}{\mathrm{D_x}}$ (12.4.3)
 E2 > Phi := Transformation(E2, E1,[t= x, u[] = z[1, 1]]);
 ${\mathrm{Φ}}{≔}\left[{t}{=}{x}{,}{{u}}_{{[}{]}}{=}{{z}}_{{1}{,}{1}}\right]$ (12.4.4)
 E2 > PhiP := Prolong(Phi, 3);
 ${\mathrm{PhiP}}{≔}\left[{t}{=}{x}{,}{{u}}_{{[}{]}}{=}{{z}}_{{1}{,}{1}}{,}{{u}}_{{1}}{=}{{z}}_{{1}{,}{1}{,}{1}}{,}{{u}}_{{1}{,}{1}}{=}{{z}}_{{1}{,}{1}{,}{1}{,}{1}}{,}{{u}}_{{1}{,}{1}{,}{1}}{=}{{z}}_{{1}{,}{1}{,}{1}{,}{1}{,}{1}}\right]$ (12.4.5)
 E2 > Y1 := AssignVectorType(D_x + x*D_z[]);
 ${\mathrm{Y1}}{≔}{\mathrm{D_x}}{+}{x}{}{{\mathrm{D_z}}}_{{[}{]}}$ (12.4.6)
 E2 > Y1P := Prolong(Y1, 2);
 ${\mathrm{Y1P}}{≔}{\mathrm{D_x}}{+}{x}{}{{\mathrm{D_z}}}_{{[}{]}}{+}{{\mathrm{D_z}}}_{{1}}$ (12.4.7)
 E2 > Y2 := AssignVectorType(u[]*D_t);
 ${\mathrm{Y2}}{≔}{{u}}_{{[}{]}}{}{\mathrm{D_t}}$ (12.4.8)
 E1 > Y2P := Prolong(Y2, 2);
 ${\mathrm{Y2P}}{≔}{{u}}_{{[}{]}}{}{\mathrm{D_t}}{-}{{u}}_{{1}}^{{2}}{}{{\mathrm{D_u}}}_{{1}}{-}{3}{}{{u}}_{{1}}{}{{u}}_{{1}{,}{1}}{}{{\mathrm{D_u}}}_{{1}{,}{1}}$ (12.4.9)
 E1 > Phi1 := AssignTransformationType(Flow(Y1, epsilon));
 ${\mathrm{Φ1}}{≔}\left[{x}{=}{\mathrm{ε}}{+}{x}{,}{y}{=}{y}{,}{{z}}_{{[}{]}}{=}\frac{{{\mathrm{ε}}}^{{2}}}{{2}}{+}{x}{}{\mathrm{ε}}{+}{{z}}_{{[}{]}}\right]$ (12.4.10)
 E2 > Phi1P := Prolong(Phi1, 1);
 ${\mathrm{Phi1P}}{≔}\left[{x}{=}{\mathrm{ε}}{+}{x}{,}{y}{=}{y}{,}{{z}}_{{[}{]}}{=}\frac{{{\mathrm{ε}}}^{{2}}}{{2}}{+}{x}{}{\mathrm{ε}}{+}{{z}}_{{[}{]}}{,}{{z}}_{{1}}{=}{\mathrm{ε}}{+}{{z}}_{{1}}{,}{{z}}_{{2}}{=}{{z}}_{{2}}\right]$ (12.4.11)
 E2 > Phi2 := AssignTransformationType(Flow(Y2, epsilon));
 ${\mathrm{Φ2}}{≔}\left[{t}{=}{{u}}_{{[}{]}}{}{\mathrm{ε}}{+}{t}{,}{{u}}_{{[}{]}}{=}{{u}}_{{[}{]}}\right]$ (12.4.12)
 E1 > Phi2P := simplify(Prolong(Phi2, 2));
 ${\mathrm{Phi2P}}{≔}\left[{t}{=}{{u}}_{{[}{]}}{}{\mathrm{ε}}{+}{t}{,}{{u}}_{{[}{]}}{=}{{u}}_{{[}{]}}{,}{{u}}_{{1}}{=}\frac{{{u}}_{{1}}}{{1}{+}{\mathrm{ε}}{}{{u}}_{{1}}}{,}{{u}}_{{1}{,}{1}}{=}\frac{{{u}}_{{1}{,}{1}}}{{\left({1}{+}{\mathrm{ε}}{}{{u}}_{{1}}\right)}^{{3}}}\right]$ (12.4.13)
 E1 > A := r*u + s*t*u[1, 1]^2;
 ${A}{≔}{r}{}{{u}}_{{1}}{+}{s}{}{t}{}{{u}}_{{1}{,}{1}}^{{2}}$ (12.4.14) Solutions

Part [i]  Find the jet order of the functions f, the differential form omega, and the vector field X.

 E1 > f; DGinfo(f, "ObjectOrder");
 ${{z}}_{{1}{,}{1}{,}{1}}{}{{z}}_{{2}{,}{2}}^{{2}}$ ${0}$ (12.4.1.1)
 E1 > omega, DGinfo(f, "ObjectOrder");
 ${{u}}_{{1}{,}{1}}{}{{\mathrm{du}}}_{{1}{,}{1}{,}{1}}{,}{0}$ (12.4.1.2)

Part [ii]  Find the order of the jet spaces E1 and E2.

 E1 > DGinfo(E1, "FrameJetOrder");
 ${3}$ (12.4.1.3)
 E1 > DGinfo(E2, "FrameJetOrder");
 ${5}$ (12.4.1.4)

Part [iii]  Find dimension of the jet spaces E1 and  E2.

 E1 > DGinfo(3, "JetSpaceDimension", E1);
 ${5}$ (12.4.1.5)
 E1 > DGinfo(2, "JetSpaceDimension", E2);
 ${8}$ (12.4.1.6)

Part [iv]  List the independent variables, the dependent variables and the jet space variables for the jet space E1.

 E2 > DGinfo(E1, "FrameIndependentVariables");
 $\left[{t}\right]$ (12.4.1.7)
 E2 > DGinfo(E1, "FrameDependentVariables");
 $\left[{u}\right]$ (12.4.1.8)
 E2 > DGinfo(E1, "FrameJetVariables");
 $\left[{t}{,}{{u}}_{{[}{]}}{,}{{u}}_{{1}}{,}{{u}}_{{1}{,}{1}}{,}{{u}}_{{1}{,}{1}{,}{1}}\right]$ (12.4.1.9)

Part [iv]  List the basis vector fields and differential forms for the jet space E2.

 E2 > DGinfo(E2, "FrameJetVectors");
 $\left[{\mathrm{D_x}}{,}{\mathrm{D_y}}{,}{{\mathrm{D_z}}}_{{[}{]}}{,}{{\mathrm{D_z}}}_{{1}}{,}{{\mathrm{D_z}}}_{{2}}{,}{{\mathrm{D_z}}}_{{1}{,}{1}}{,}{{\mathrm{D_z}}}_{{1}{,}{2}}{,}{{\mathrm{D_z}}}_{{2}{,}{2}}{,}{{\mathrm{D_z}}}_{{1}{,}{1}{,}{1}}{,}{{\mathrm{D_z}}}_{{1}{,}{1}{,}{2}}{,}{{\mathrm{D_z}}}_{{1}{,}{2}{,}{2}}{,}{{\mathrm{D_z}}}_{{2}{,}{2}{,}{2}}{,}{{\mathrm{D_z}}}_{{1}{,}{1}{,}{1}{,}{1}}{,}{{\mathrm{D_z}}}_{{1}{,}{1}{,}{1}{,}{2}}{,}{{\mathrm{D_z}}}_{{1}{,}{1}{,}{2}{,}{2}}{,}{{\mathrm{D_z}}}_{{1}{,}{2}{,}{2}{,}{2}}{,}{{\mathrm{D_z}}}_{{2}{,}{2}{,}{2}{,}{2}}{,}{{\mathrm{D_z}}}_{{1}{,}{1}{,}{1}{,}{1}{,}{1}}{,}{{\mathrm{D_z}}}_{{1}{,}{1}{,}{1}{,}{1}{,}{2}}{,}{{\mathrm{D_z}}}_{{1}{,}{1}{,}{1}{,}{2}{,}{2}}{,}{{\mathrm{D_z}}}_{{1}{,}{1}{,}{2}{,}{2}{,}{2}}{,}{{\mathrm{D_z}}}_{{1}{,}{2}{,}{2}{,}{2}{,}{2}}{,}{{\mathrm{D_z}}}_{{2}{,}{2}{,}{2}{,}{2}{,}{2}}\right]$ (12.4.1.10)
 E2 > DGinfo(E2, "FrameJetForms");
 $\left[{\mathrm{dx}}{,}{\mathrm{dy}}{,}{{\mathrm{dz}}}_{{[}{]}}{,}{{\mathrm{dz}}}_{{1}}{,}{{\mathrm{dz}}}_{{2}}{,}{{\mathrm{dz}}}_{{1}{,}{1}}{,}{{\mathrm{dz}}}_{{1}{,}{2}}{,}{{\mathrm{dz}}}_{{2}{,}{2}}{,}{{\mathrm{dz}}}_{{1}{,}{1}{,}{1}}{,}{{\mathrm{dz}}}_{{1}{,}{1}{,}{2}}{,}{{\mathrm{dz}}}_{{1}{,}{2}{,}{2}}{,}{{\mathrm{dz}}}_{{2}{,}{2}{,}{2}}{,}{{\mathrm{dz}}}_{{1}{,}{1}{,}{1}{,}{1}}{,}{{\mathrm{dz}}}_{{1}{,}{1}{,}{1}{,}{2}}{,}{{\mathrm{dz}}}_{{1}{,}{1}{,}{2}{,}{2}}{,}{{\mathrm{dz}}}_{{1}{,}{2}{,}{2}{,}{2}}{,}{{\mathrm{dz}}}_{{2}{,}{2}{,}{2}{,}{2}}{,}{{\mathrm{dz}}}_{{1}{,}{1}{,}{1}{,}{1}{,}{1}}{,}{{\mathrm{dz}}}_{{1}{,}{1}{,}{1}{,}{1}{,}{2}}{,}{{\mathrm{dz}}}_{{1}{,}{1}{,}{1}{,}{2}{,}{2}}{,}{{\mathrm{dz}}}_{{1}{,}{1}{,}{2}{,}{2}{,}{2}}{,}{{\mathrm{dz}}}_{{1}{,}{2}{,}{2}{,}{2}{,}{2}}{,}{{\mathrm{dz}}}_{{2}{,}{2}{,}{2}{,}{2}{,}{2}}\right]$ (12.4.1.11)

Part [vi]  List the contact 1-forms define on the jet space E1.

 E2 > DGinfo(E1, "FrameVerticalBiforms");
 $\left[{{\mathrm{Cu}}}_{{[}{]}}{,}{{\mathrm{Cu}}}_{{1}}{,}{{\mathrm{Cu}}}_{{1}{,}{1}}{,}{{\mathrm{Cu}}}_{{1}{,}{1}{,}{1}}\right]$ (12.4.1.12)

Part [vii]  Find the order of the domain jet space for the transformations Phi and PhiP.  Find the order of the range jet space for the transformations Phi and PhiP.

 E1 > Phi, PhiP;
 $\left[{t}{=}{x}{,}{{u}}_{{[}{]}}{=}{{z}}_{{1}{,}{1}}\right]{,}\left[{t}{=}{x}{,}{{u}}_{{[}{]}}{=}{{z}}_{{1}{,}{1}}{,}{{u}}_{{1}}{=}{{z}}_{{1}{,}{1}{,}{1}}{,}{{u}}_{{1}{,}{1}}{=}{{z}}_{{1}{,}{1}{,}{1}{,}{1}}{,}{{u}}_{{1}{,}{1}{,}{1}}{=}{{z}}_{{1}{,}{1}{,}{1}{,}{1}{,}{1}}\right]$ (12.4.1.13)
 E1 > DGinfo(Phi, "DomainOrder");
 ${2}$ (12.4.1.14)
 E1 > DGinfo(PhiP, "DomainOrder");
 ${5}$ (12.4.1.15)
 E1 > DGinfo(Phi, "RangeOrder");
 ${0}$ (12.4.1.16)
 E1 > DGinfo(PhiP, "RangeOrder");
 ${3}$ (12.4.1.17)

Part [viii]  Find the type of the vector fields Y1 and Y2 (See the help page AssignVectorType)

 E1 > Y1, Y1P;
 ${\mathrm{D_x}}{+}{x}{}{{\mathrm{D_z}}}_{{[}{]}}{,}{\mathrm{D_x}}{+}{x}{}{{\mathrm{D_z}}}_{{[}{]}}{+}{{\mathrm{D_z}}}_{{1}}$ (12.4.1.18)
 E2 > DGinfo(Y1, "VectorType");
 $\left[{"projectable"}{,}{0}\right]$ (12.4.1.19)

 E2 > DGinfo(Y1P, "VectorType");
 $\left[{"projectable"}{,}{2}\right]$ (12.4.1.20)
 E2 > Y2, Y2P;
 ${{u}}_{{[}{]}}{}{\mathrm{D_t}}{,}{{u}}_{{[}{]}}{}{\mathrm{D_t}}{-}{{u}}_{{1}}^{{2}}{}{{\mathrm{D_u}}}_{{1}}{-}{3}{}{{u}}_{{1}}{}{{u}}_{{1}{,}{1}}{}{{\mathrm{D_u}}}_{{1}{,}{1}}$ (12.4.1.21)
 E1 > DGinfo(Y2, "VectorType");
 $\left[{"point"}{,}{0}\right]$ (12.4.1.22)
 E1 > DGinfo(Y2P, "VectorType");
 $\left[{"point"}{,}{2}\right]$ (12.4.1.23)

Part [ix]  Find the type of the transformations Phi1, Phi1P, Phi2, and Phi2P (See the help page AssignTransformationType)

 E2 > Phi1, Phi1P;
 $\left[{x}{=}{\mathrm{ε}}{+}{x}{,}{y}{=}{y}{,}{{z}}_{{[}{]}}{=}\frac{{{\mathrm{ε}}}^{{2}}}{{2}}{+}{x}{}{\mathrm{ε}}{+}{{z}}_{{[}{]}}\right]{,}\left[{x}{=}{\mathrm{ε}}{+}{x}{,}{y}{=}{y}{,}{{z}}_{{[}{]}}{=}\frac{{{\mathrm{ε}}}^{{2}}}{{2}}{+}{x}{}{\mathrm{ε}}{+}{{z}}_{{[}{]}}{,}{{z}}_{{1}}{=}{\mathrm{ε}}{+}{{z}}_{{1}}{,}{{z}}_{{2}}{=}{{z}}_{{2}}\right]$ (12.4.1.24)
 E1 > DGinfo(Phi1, "TransformationType");
 $\left[{"projectable"}{,}{0}\right]$ (12.4.1.25)
 E1 > DGinfo(Phi1P, "TransformationType");
 $\left[{"projectable"}{,}{1}\right]$ (12.4.1.26)
 E1 > Phi2, Phi2P;
 $\left[{t}{=}{{u}}_{{[}{]}}{}{\mathrm{ε}}{+}{t}{,}{{u}}_{{[}{]}}{=}{{u}}_{{[}{]}}\right]{,}\left[{t}{=}{{u}}_{{[}{]}}{}{\mathrm{ε}}{+}{t}{,}{{u}}_{{[}{]}}{=}{{u}}_{{[}{]}}{,}{{u}}_{{1}}{=}\frac{{{u}}_{{1}}}{{1}{+}{\mathrm{ε}}{}{{u}}_{{1}}}{,}{{u}}_{{1}{,}{1}}{=}\frac{{{u}}_{{1}{,}{1}}}{{\left({1}{+}{\mathrm{ε}}{}{{u}}_{{1}}\right)}^{{3}}}\right]$ (12.4.1.27)
 E1 > DGinfo(Phi2, "TransformationType");
 $\left[{"point"}{,}{0}\right]$ (12.4.1.28)
 E1 > DGinfo(Phi2P, "TransformationType");
 $\left[{"point"}{,}{2}\right]$ (12.4.1.29)

Part [x]  Find the variables in the expression A which are jet variables for the jet space E1.

 E1 > A;
 ${r}{}{{u}}_{{1}}{+}{s}{}{t}{}{{u}}_{{1}{,}{1}}^{{2}}$ (12.4.1.30)
 E1 > DGinfo(A, "JetIndets");
 $\left\{{t}{,}{{u}}_{{1}}{,}{{u}}_{{1}{,}{1}}\right\}$ (12.4.1.31)

Part [xi]  Find the variables in the expression A which are not jet variables for the jet space E1.

 E1 > A;
 ${r}{}{{u}}_{{1}}{+}{s}{}{t}{}{{u}}_{{1}{,}{1}}^{{2}}$ (12.4.1.32)
 E1 > DGinfo(A, "NonJetIndets");
 $\left\{{r}{,}{s}\right\}$ (12.4.1.33)