diffalg - Maple Help

Overview of the diffalg Package

 Calling Sequence diffalg[command](arguments) command(arguments)

Description

 • Important: The diffalg package has been deprecated. Use the superseding package Differential Algebra instead.
 • The diffalg package is a collection of commands to handle systems of polynomial differential equations (ODEs and PDEs) and inequations. The functionalities include differential elimination, expansion of the solutions into formal power series, and analysis of singular solutions. The underlying theory and terminology derive from differential algebra. Basic concepts in constructive differential algebra and their representation in the diffalg package are presented in a more substantial way in the page diffalg[differential_algebra].
 • Each command in the diffalg package can be accessed by using either the long form or the short form of the command name in the command calling sequence.
 Important: Prior to any computations with the diffalg package, the appropriate differential indeterminates (dependent variables) and derivation variables (independent variables) with the ranking must be defined with the command differential_ring. This command issues a table (appearing as ODE_ring or $\mathrm{PDE_ring}$) that must be used as a last parameter to most other commands.
 • Central in this package is the Rosenfeld_Groebner algorithm. This page gives an overview of the functionalities of diffalg illustrated by some basic examples. Pointers to diffalg[differential_algebra] are given for precise definitions.
 • In this package differential equations are represented by the equivalent differential polynomials (that is, the difference of the right-hand sides and the left-hand sides of the equations). A zero of a differential polynomial is a meromorphic solution of the associated differential equation. The terms derivation variables and differential indeterminates refer respectively to the independent and dependent variables.
 • In simple terms, Rosenfeld_Groebner decomposes the zero set of a system of differential polynomials into the union of the nonsingular zeros of differential characteristic sets. Each differential characteristic set defines a characterizable component.
 • Differential characteristic sets, as to be found in the output of Rosenfeld_Groebner, are kinds of canonical forms. Their nonsingular zeros are defined as the solutions of a set of equations plus a set of inequations. A differential characteristic set is minimal among the sets of differential polynomials admitting the same nonsingular zero set. That is, many structural properties of the nonsingular zero set can be read from the differential characteristic set.
 • For illustration, the decomposition by Rosenfeld_Groebner on a single differential polynomial splits the singular zeros, if any, from the general zero (see example below). As for systems of differential equations, Rosenfeld_Groebner first detects if the system bears inconsistency (contradiction) and therefore has no solution (see example below)
 • A ranking is an order on the differential indeterminates and all their derivatives that is compatible with derivation. The computations and the differential characteristic sets obtained depend on the chosen ranking. Various properties of the zero set of a system of differential polynomials can be exhibited with an appropriate choice of the ranking. It can answer questions like: do the zeros of the given system satisfy
 * Differential equations involving only a specific subset of the differential indeterminates? Computing with an elimination ranking determines the minimal such equations if they exist (see example below).
 * Algebraic equations? Computing with an orderly ranking determines these constraints if they exist (see example below).
 * An ordinary differential equation in one derivation variable? Computing with a lexicographic ranking determines the minimal such equations if they exist (see example below).
 • The ranking to be used with the derivation variables and the differential indeterminates are defined with the differential_ring command.
 • An example of the analysis that can be performed with essential_components on the singular zeros of a differential polynomial is given (see example below).
 • Power series expansion of the nonsingular zeros of a differential characteristic set can be performed with the power_series_solution routine. Examples are provided in diffalg[power_series_solution] help page.

Typical uses and examples for Rosenfeld_Groebner

 > with(diffalg);
 $\left[{\mathrm{Rosenfeld_Groebner}}{,}{\mathrm{belongs_to}}{,}{\mathrm{delta_leader}}{,}{\mathrm{delta_polynomial}}{,}{\mathrm{denote}}{,}{\mathrm{derivatives}}{,}{\mathrm{differential_ring}}{,}{\mathrm{differential_sprem}}{,}{\mathrm{differentiate}}{,}{\mathrm{equations}}{,}{\mathrm{essential_components}}{,}{\mathrm{field_extension}}{,}{\mathrm{greater}}{,}{\mathrm{inequations}}{,}{\mathrm{initial}}{,}{\mathrm{initial_conditions}}{,}{\mathrm{is_orthonomic}}{,}{\mathrm{leader}}{,}{\mathrm{power_series_solution}}{,}{\mathrm{preparation_polynomial}}{,}{\mathrm{print_ranking}}{,}{\mathrm{rank}}{,}{\mathrm{reduced}}{,}{\mathrm{reduced_form}}{,}{\mathrm{rewrite_rules}}{,}{\mathrm{separant}}\right]$ (1)
 Prior to any computations with the diffalg package, the appropriate differential indeterminates (dependent variables) and derivation variables (independent variables) with the ranking must be defined with the command differential_ring. This command issues a table (appearing as ODE_ring or $\mathrm{PDE_ring}$) that must be used as a last parameter to most other commands.

Computing singular solutions

 Consider the following Clairaut partial differential equation.
 > u(x,y) = x*diff(u(x,y),x)+y*diff(u(x,y),y)+diff(u(x,y),x)*diff(u(x,y),y);
 ${u}{}\left({x}{,}{y}\right){=}{x}{}\left(\frac{{\partial }}{{\partial }{x}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({x}{,}{y}\right)\right){+}{y}{}\left(\frac{{\partial }}{{\partial }{y}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({x}{,}{y}\right)\right){+}\left(\frac{{\partial }}{{\partial }{x}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({x}{,}{y}\right)\right){}\left(\frac{{\partial }}{{\partial }{y}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({x}{,}{y}\right)\right)$ (2)
 Represent it by the differential polynomial $p$ with a more compact syntax, called jet notation.
 > p := -u[]+x*u[x]+y*u[y]+u[x]*u[y];
 ${p}{≔}{x}{}{{u}}_{{x}}{+}{y}{}{{u}}_{{y}}{+}{{u}}_{{x}}{}{{u}}_{{y}}{-}{u}\left[\right]$ (3)
 Before any manipulation of this differential polynomial, define a differential polynomial ring it belongs to:
 > R := differential_ring(ranking=[u], derivations=[x,y], notation=jet);
 ${R}{≔}{\mathrm{PDE_ring}}$ (4)
 The Clairaut equation under consideration has a singular solution. This is shown by Rosenfeld_Groebner. The result of Rosenfeld_Groebner is a list of tables (appearing as characterizable), each defining a characterizable component.
 > Clairaut := Rosenfeld_Groebner({p}, R);
 ${\mathrm{Clairaut}}{≔}\left[{\mathrm{characterizable}}{,}{\mathrm{characterizable}}\right]$ (5)
 Each characterizable component is defined by a differential characteristic set that can be accessed using the equations command. The nonsingular zeros of this differential characteristic set are the zeros at which some additional differential polynomials do not vanish. They can be accessed using the inequations command.
 > equations(Clairaut[1]), inequations(Clairaut[1]);
 $\left[{x}{}{{u}}_{{x}}{+}{y}{}{{u}}_{{y}}{+}{{u}}_{{x}}{}{{u}}_{{y}}{-}{u}\left[\right]\right]{,}\left[{x}{+}{{u}}_{{y}}\right]$ (6)
 > equations(Clairaut[2]), inequations(Clairaut[2]);
 $\left[{x}{}{y}{+}{u}\left[\right]\right]{,}\left[\right]$ (7)
 The second component represents the singular solution of this Clairaut equation while the first represents the general solution of the Clairaut equation.

Detection of inconsistencies in a differential system

 Consider the 3 following differential polynomials.
 > p1:=diff(u(x,y),x)+v(x,y)-y;
 ${\mathrm{p1}}{≔}\frac{{\partial }}{{\partial }{x}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({x}{,}{y}\right){+}{v}{}\left({x}{,}{y}\right){-}{y}$ (8)
 > p2:=diff(u(x,y),y)+v(x,y);
 ${\mathrm{p2}}{≔}\frac{{\partial }}{{\partial }{y}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({x}{,}{y}\right){+}{v}{}\left({x}{,}{y}\right)$ (9)
 > p3:=diff(v(x,y),x)-diff(v(x,y),y);
 ${\mathrm{p3}}{≔}\frac{{\partial }}{{\partial }{x}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{v}{}\left({x}{,}{y}\right){-}\frac{{\partial }}{{\partial }{y}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{v}{}\left({x}{,}{y}\right)$ (10)
 They define the system of differential equations $S:\mathrm{p1}=0,\mathrm{p2}=0,\mathrm{p3}=0$. Before any manipulation of these differential polynomials, define a structure they belong to. It is possible to work with the Maple notation of derivatives.
 > R := differential_ring(ranking=[u,v], derivations=[x,y], notation=diff);
 ${R}{≔}{\mathrm{PDE_ring}}$ (11)
 Convert to the jet notation, introduced in the previous example.
 > denote(p1, 'jet', R), denote(p2, 'jet', R), denote(p3, 'jet', R);
 ${{u}}_{{x}}{+}{v}\left[\right]{-}{y}{,}{{u}}_{{y}}{+}{v}\left[\right]{,}{{v}}_{{x}}{-}{{v}}_{{y}}$ (12)
 What does Rosenfeld_Groebner tell us about the system $S$?
 > Rosenfeld_Groebner({p1,p2,p3}, R);
 $\left[\right]$ (13)
 This indicates that the system bears a contradiction: $\mathrm{p1}$, $\mathrm{p2}$, and $\mathrm{p3}$ have no common zero. In this case it is quite easy to detect the contradiction. Differentiating $\mathrm{p1}$ with respect to $y$ produces:
 > differentiate(p1, y, R);
 $\frac{{{\partial }}^{{2}}}{{\partial }{x}{\partial }{y}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({x}{,}{y}\right){+}\frac{{\partial }}{{\partial }{y}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{v}{}\left({x}{,}{y}\right){-}{1}$ (14)
 The meromorphic solutions of $S$, if they exist, shall make this differential polynomial vanish. They shall also make the following differential polynomial vanish
 > differentiate(p2, x, R)- p3;
 $\frac{{{\partial }}^{{2}}}{{\partial }{x}{\partial }{y}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({x}{,}{y}\right){+}\frac{{\partial }}{{\partial }{y}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{v}{}\left({x}{,}{y}\right)$ (15)
 The two equations cannot be satisfied simultaneously: the system $S$ bears a contradiction $1=0$ and therefore admits no solution.

Solving ordinary differential systems: Elimination ranking

 To perform a chain resolution of a system of ordinary differential equations, use an elimination ranking. Consider the differential system defined by the following set $S$ of differential polynomials in the unknown functions $x\left(t\right),y\left(t\right),z\left(t\right)$.
 > S := [diff(x(t),t)-x(t)*(x(t)+y(t)), diff(y(t),t)+y(t)*(x(t)+y(t)), diff(x(t),t)^2+diff(y(t),t)^2+diff(z(t),t)^2-1];
 ${S}{≔}\left[\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{x}{}\left({t}\right){-}{x}{}\left({t}\right){}\left({x}{}\left({t}\right){+}{y}{}\left({t}\right)\right){,}\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{y}{}\left({t}\right){+}{y}{}\left({t}\right){}\left({x}{}\left({t}\right){+}{y}{}\left({t}\right)\right){,}{\left(\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{x}{}\left({t}\right)\right)}^{{2}}{+}{\left(\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{y}{}\left({t}\right)\right)}^{{2}}{+}{\left(\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{z}{}\left({t}\right)\right)}^{{2}}{-}{1}\right]$ (16)
 Using an elimination ranking where $z\left(t\right)>y\left(t\right)>x\left(t\right)$, you obtain differential characteristic sets containing a differential polynomial in $x\left(t\right)$ alone, a differential polynomial determining $y\left(t\right)$ in terms of $x\left(t\right)$, and finally a differential polynomial determining $z\left(t\right)$ in terms of $y\left(t\right)$ and $x\left(t\right)$. To see more clearly the dependencies of these differential polynomials, use the rewrite_rules command, which is an alternative to the equations command.
 > R := differential_ring(ranking=[z,y,x], derivations=[t], notation=diff):
 > G :=Rosenfeld_Groebner(S, R);
 ${G}{≔}\left[{\mathrm{characterizable}}{,}{\mathrm{characterizable}}\right]$ (17)
 > rewrite_rules(G[1]); inequations(G[1]);
 $\left[{\left(\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{z}{}\left({t}\right)\right)}^{{2}}{=}{-}\frac{{2}{}{\left(\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{x}{}\left({t}\right)\right)}^{{2}}{}{{x}{}\left({t}\right)}^{{4}}{-}{2}{}{\left(\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{x}{}\left({t}\right)\right)}^{{3}}{}{{x}{}\left({t}\right)}^{{2}}{-}{{x}{}\left({t}\right)}^{{4}}{+}{\left(\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{x}{}\left({t}\right)\right)}^{{4}}}{{{x}{}\left({t}\right)}^{{4}}}{,}{y}{}\left({t}\right){=}\frac{{-}{{x}{}\left({t}\right)}^{{2}}{+}\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{x}{}\left({t}\right)}{{x}{}\left({t}\right)}{,}\frac{{{ⅆ}}^{{2}}}{{ⅆ}{{t}}^{{2}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{x}{}\left({t}\right){=}{2}{}\left(\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{x}{}\left({t}\right)\right){}{x}{}\left({t}\right)\right]$
 $\left[{x}{}\left({t}\right){,}\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{z}{}\left({t}\right)\right]$ (18)
 > rewrite_rules(G[2]); inequations(G[2]);
 $\left[{\left(\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{z}{}\left({t}\right)\right)}^{{2}}{=}{-}{{y}{}\left({t}\right)}^{{4}}{+}{1}{,}\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{y}{}\left({t}\right){=}{-}{{y}{}\left({t}\right)}^{{2}}{,}{x}{}\left({t}\right){=}{0}\right]$
 $\left[\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{z}{}\left({t}\right)\right]$ (19)
 Perform a chain resolution to both components of the result. Note that the singular solution $x\left(t\right)=0$ must be discarded in the resolution of the first component, as indicated by the differential polynomials of its inequations. The correct complete solution with $x\left(t\right)=0$ is given by the second component.

Constrained systems: Orderly and mixed rankings

 Consider the set of differential polynomials describing the motion of a pendulum, that is, a point mass $m$ suspended from a massless rod of length $l$ under the influence of gravity $g$, in Cartesian coordinates $x,y$. The Lagrangian formulation leads to two second order differential equations with an algebraic constraint. $T$ is the Lagrangian multiplier.
 > P := [m*diff(y(t),t,t)+T(t)*y(t)+g, m*diff(x(t),t,t)+T(t)*x(t), x(t)^2+y(t)^2-l^2];
 ${P}{≔}\left[{m}{}\left(\frac{{{ⅆ}}^{{2}}}{{ⅆ}{{t}}^{{2}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{y}{}\left({t}\right)\right){+}{T}{}\left({t}\right){}{y}{}\left({t}\right){+}{g}{,}{m}{}\left(\frac{{{ⅆ}}^{{2}}}{{ⅆ}{{t}}^{{2}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{x}{}\left({t}\right)\right){+}{T}{}\left({t}\right){}{x}{}\left({t}\right){,}{{x}{}\left({t}\right)}^{{2}}{+}{{y}{}\left({t}\right)}^{{2}}{-}{{l}}^{{2}}\right]$ (20)
 To manipulate this system, declare the additional constants $m,l,g$ appearing in the coefficients of these differential polynomials.
 > K := field_extension(transcendental_elements=[m,l,g]);
 ${K}{≔}{\mathrm{ground_field}}$ (21)
 • Orderly Ranking
 • To find the lowest order differential polynomials vanishing on the zeros of the system modeling the pendulum and in particular all the algebraic constraints (that is, the differential polynomials of order $0$), use an orderly ranking.
 > RO := differential_ring(ranking=[[T,x,y]], derivations=[t], field_of_constants=K, notation=diff):
 > GO:= Rosenfeld_Groebner(P, RO);
 ${\mathrm{GO}}{≔}\left[{\mathrm{characterizable}}{,}{\mathrm{characterizable}}\right]$ (22)
 > rewrite_rules(GO[1]);
 $\left[\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{T}{}\left({t}\right){=}{-}\frac{{3}{}\left(\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{y}{}\left({t}\right)\right){}{g}}{{{l}}^{{2}}}{,}{\left(\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{y}{}\left({t}\right)\right)}^{{2}}{=}{-}\frac{{-}{T}{}\left({t}\right){}{{l}}^{{4}}{+}{T}{}\left({t}\right){}{{y}{}\left({t}\right)}^{{2}}{}{{l}}^{{2}}{-}{y}{}\left({t}\right){}{{l}}^{{2}}{}{g}{+}{{y}{}\left({t}\right)}^{{3}}{}{g}}{{{l}}^{{2}}{}{m}}{,}{{x}{}\left({t}\right)}^{{2}}{=}{-}{{y}{}\left({t}\right)}^{{2}}{+}{{l}}^{{2}}\right]$ (23)
 > inequations(GO[1]);
 $\left[{x}{}\left({t}\right){,}\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{y}{}\left({t}\right)\right]$ (24)
 > rewrite_rules(GO[2]);
 $\left[{T}{}\left({t}\right){=}{-}\frac{{y}{}\left({t}\right){}{g}}{{{l}}^{{2}}}{,}{x}{}\left({t}\right){=}{0}{,}{{y}{}\left({t}\right)}^{{2}}{=}{{l}}^{{2}}\right]$ (25)
 > inequations(GO[2]);
 $\left[{y}{}\left({t}\right)\right]$ (26)
 The second component in the output of Rosenfeld_Groebner corresponds to the equilibria of the pendulum. From the first component of the output, it can be seen that the actual motion is described by two first order differential equations with a constraint: the solution depends on only two arbitrary constants.
 • Mixed Ranking
 • To obtain the differential system satisfied by $x$ and $y$ alone, eliminate $T$:
 > RM := differential_ring(ranking=[T,[x,y]], derivations=[t], field_of_constants=K, notation=diff):
 > GM:= Rosenfeld_Groebner(P, RM);
 ${\mathrm{GM}}{≔}\left[{\mathrm{characterizable}}{,}{\mathrm{characterizable}}\right]$ (27)
 > rewrite_rules(GM[1]);
 $\left[{T}{}\left({t}\right){=}{-}\frac{{\left(\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{y}{}\left({t}\right)\right)}^{{2}}{}{m}{}{{l}}^{{2}}{-}{y}{}\left({t}\right){}{{l}}^{{2}}{}{g}{+}{{y}{}\left({t}\right)}^{{3}}{}{g}}{{{l}}^{{2}}{}\left({{y}{}\left({t}\right)}^{{2}}{-}{{l}}^{{2}}\right)}{,}\frac{{{ⅆ}}^{{2}}}{{ⅆ}{{t}}^{{2}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{y}{}\left({t}\right){=}\frac{{\left(\frac{{ⅆ}}{{ⅆ}{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{y}{}\left({t}\right)\right)}^{{2}}{}{y}{}\left({t}\right){}{m}{}{{l}}^{{2}}{+}{{y}{}\left({t}\right)}^{{4}}{}{g}{-}{2}{}{{y}{}\left({t}\right)}^{{2}}{}{{l}}^{{2}}{}{g}{+}{{l}}^{{4}}{}{g}}{{{l}}^{{2}}{}{m}{}\left({{y}{}\left({t}\right)}^{{2}}{-}{{l}}^{{2}}\right)}{,}{{x}{}\left({t}\right)}^{{2}}{=}{-}{{y}{}\left({t}\right)}^{{2}}{+}{{l}}^{{2}}\right]$ (28)
 > rewrite_rules(GM[2]);
 $\left[{T}{}\left({t}\right){=}{-}\frac{{y}{}\left({t}\right){}{g}}{{{l}}^{{2}}}{,}{x}{}\left({t}\right){=}{0}{,}{{y}{}\left({t}\right)}^{{2}}{=}{{l}}^{{2}}\right]$ (29)
 Note here that the motion is given by a second order differential equation in $y\left(t\right)$. Then the Lagrange multiplier is given explicitly in terms of $y\left(t\right)$ and its first derivative.

Solving partial differential system: Lexicographic ranking

 To solve overdetermined systems of partial differential equations it is interesting to compute first the ordinary differential equations satisfied by the solutions of the system. For this purpose, a lexicographic ranking must be chosen. Consider the differential system $S$ defining the infinitesimal generators of the symmetry group of the Burgers equations.
 > Burgers_pde := diff(u(t,x),t)=diff(u(t,x),x,x)-u(t,x)*diff(u(t,x),x);
 ${\mathrm{Burgers_pde}}{≔}\frac{{\partial }}{{\partial }{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({t}{,}{x}\right){=}\frac{{{\partial }}^{{2}}}{{\partial }{{x}}^{{2}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({t}{,}{x}\right){-}{u}{}\left({t}{,}{x}\right){}\left(\frac{{\partial }}{{\partial }{x}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{u}{}\left({t}{,}{x}\right)\right)$ (30)
 > BurgersSymm := PDEtools:-DeterminingPDE(Burgers_pde, u(t, x), [V1, V2, V3](t, x, u));
 ${\mathrm{BurgersSymm}}{≔}\left\{\frac{{\partial }}{{\partial }{u}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V1}}{}\left({t}{,}{x}{,}{u}\right){=}{0}{,}\frac{{\partial }}{{\partial }{x}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V1}}{}\left({t}{,}{x}{,}{u}\right){=}{0}{,}\frac{{\partial }}{{\partial }{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V2}}{}\left({t}{,}{x}{,}{u}\right){=}\frac{\left(\frac{{\partial }}{{\partial }{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V1}}{}\left({t}{,}{x}{,}{u}\right)\right){}{u}}{{2}}{+}{\mathrm{V3}}{}\left({t}{,}{x}{,}{u}\right){,}\frac{{\partial }}{{\partial }{u}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V2}}{}\left({t}{,}{x}{,}{u}\right){=}{0}{,}\frac{{\partial }}{{\partial }{x}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V2}}{}\left({t}{,}{x}{,}{u}\right){=}\frac{\frac{{\partial }}{{\partial }{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V1}}{}\left({t}{,}{x}{,}{u}\right)}{{2}}{,}\frac{{\partial }}{{\partial }{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V3}}{}\left({t}{,}{x}{,}{u}\right){=}{-}\frac{\left(\frac{{{\partial }}^{{2}}}{{\partial }{{t}}^{{2}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V1}}{}\left({t}{,}{x}{,}{u}\right)\right){}{u}}{{2}}{,}\frac{{\partial }}{{\partial }{u}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V3}}{}\left({t}{,}{x}{,}{u}\right){=}{-}\frac{\frac{{\partial }}{{\partial }{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V1}}{}\left({t}{,}{x}{,}{u}\right)}{{2}}{,}\frac{{\partial }}{{\partial }{x}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V3}}{}\left({t}{,}{x}{,}{u}\right){=}\frac{\frac{{{\partial }}^{{2}}}{{\partial }{{t}}^{{2}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V1}}{}\left({t}{,}{x}{,}{u}\right)}{{2}}{,}\frac{{{\partial }}^{{3}}}{{\partial }{{t}}^{{3}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V1}}{}\left({t}{,}{x}{,}{u}\right){=}{0}\right\}$ (31)
 Seek the ordinary differential equations with respect to $t$ satisfied by the solutions of this system.
 > R := differential_ring(ranking=[lex[V3,V2,V1]], derivations=[u,x,t], notation=diff);
 ${R}{≔}{\mathrm{PDE_ring}}$ (32)
 > G := Rosenfeld_Groebner(map(lhs-rhs, BurgersSymm), R);
 ${G}{≔}\left[{\mathrm{characterizable}}\right]$ (33)
 > rewrite_rules(G[1]);
 $\left[\frac{{\partial }}{{\partial }{u}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V3}}{}\left({u}{,}{x}{,}{t}\right){=}{-}\frac{\frac{{\partial }}{{\partial }{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V1}}{}\left({u}{,}{x}{,}{t}\right)}{{2}}{,}\frac{{\partial }}{{\partial }{u}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V2}}{}\left({u}{,}{x}{,}{t}\right){=}{0}{,}\frac{{\partial }}{{\partial }{u}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V1}}{}\left({u}{,}{x}{,}{t}\right){=}{0}{,}\frac{{\partial }}{{\partial }{x}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V3}}{}\left({u}{,}{x}{,}{t}\right){=}{-}\frac{\frac{{\partial }}{{\partial }{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V3}}{}\left({u}{,}{x}{,}{t}\right)}{{u}}{,}\frac{{\partial }}{{\partial }{x}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V2}}{}\left({u}{,}{x}{,}{t}\right){=}\frac{\frac{{\partial }}{{\partial }{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V1}}{}\left({u}{,}{x}{,}{t}\right)}{{2}}{,}\frac{{\partial }}{{\partial }{x}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V1}}{}\left({u}{,}{x}{,}{t}\right){=}{0}{,}\frac{{{\partial }}^{{2}}}{{\partial }{{t}}^{{2}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V3}}{}\left({u}{,}{x}{,}{t}\right){=}{0}{,}\frac{{{\partial }}^{{2}}}{{\partial }{{t}}^{{2}}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V1}}{}\left({u}{,}{x}{,}{t}\right){=}{-}\frac{{2}{}\left(\frac{{\partial }}{{\partial }{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V3}}{}\left({u}{,}{x}{,}{t}\right)\right)}{{u}}{,}\frac{{\partial }}{{\partial }{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V2}}{}\left({u}{,}{x}{,}{t}\right){=}\frac{{u}{}\left(\frac{{\partial }}{{\partial }{t}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{\mathrm{V1}}{}\left({u}{,}{x}{,}{t}\right)\right)}{{2}}{+}{\mathrm{V3}}{}\left({u}{,}{x}{,}{t}\right)\right]$ (34)
 There are three independent ordinary differential polynomials with respect to $t$ (the last three of the differential characteristic set). All other ordinary (in $t$) differential polynomials vanishing on the solutions of $\mathrm{BurgersSymm}$ can be written as linear combination of these three with their derivatives.

Analysis of singular solutions

 All singular zeros are present in the output of Rosenfeld_Groebner. Only the essential singular zeros are present in the output of essential_components. For first order differential equations:
 * The essential singular zeros are envelopes of the nonsingular zeros.
 * The other singular zeros are analytically embedded among the nonsingular zeros.
 Illustrate this analysis on the differential polynomial $\mathrm{Wp}$ (cf. WeierstrassP):
 > Wp := diff(w(z),z)^2-4*w(z)^3+g2*w(z) +g3;
 ${\mathrm{Wp}}{≔}{\left(\frac{{ⅆ}}{{ⅆ}{z}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{w}{}\left({z}\right)\right)}^{{2}}{-}{4}{}{{w}{}\left({z}\right)}^{{3}}{+}{\mathrm{g2}}{}{w}{}\left({z}\right){+}{\mathrm{g3}}$ (35)
 • Generic case ${\mathrm{g2}}^{3}\ne 27{\mathrm{g3}}^{2}$ :
 > K := field_extension(transcendental_elements=[g2,g3]);
 ${K}{≔}{\mathrm{ground_field}}$ (36)
 > R := differential_ring(ranking=[w],derivations=[z],notation=diff,field_of_constants=K);
 ${R}{≔}{\mathrm{ODE_ring}}$ (37)
 > equations(Rosenfeld_Groebner([Wp],R));
 $\left[\left[{\left(\frac{{ⅆ}}{{ⅆ}{z}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{w}{}\left({z}\right)\right)}^{{2}}{-}{4}{}{{w}{}\left({z}\right)}^{{3}}{+}{\mathrm{g2}}{}{w}{}\left({z}\right){+}{\mathrm{g3}}\right]{,}\left[{4}{}{{w}{}\left({z}\right)}^{{3}}{-}{\mathrm{g2}}{}{w}{}\left({z}\right){-}{\mathrm{g3}}\right]\right]$ (38)
 > equations(essential_components(Wp,R));
 $\left[\left[{\left(\frac{{ⅆ}}{{ⅆ}{z}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{w}{}\left({z}\right)\right)}^{{2}}{-}{4}{}{{w}{}\left({z}\right)}^{{3}}{+}{\mathrm{g2}}{}{w}{}\left({z}\right){+}{\mathrm{g3}}\right]{,}\left[{4}{}{{w}{}\left({z}\right)}^{{3}}{-}{\mathrm{g2}}{}{w}{}\left({z}\right){-}{\mathrm{g3}}\right]\right]$ (39)
 There are three singular zeros: $w\left(z\right)=\mathrm{ri}$, where $\mathrm{ri}$ is one of the roots of $4{r}^{3}-\mathrm{g2}r-\mathrm{g3}$. There are all three essential singular zeros. As such they are envelopes of the nonsingular zeros of $\mathrm{Wp}$. This can be observed by plotting the real zeros for $\mathrm{g2}=4,\mathrm{g3}=-1$:
 > singsol := {plot({fsolve(-4*r^3+4*r-1,r)},z=-3..3, color=red, thickness=2)}:
 > galsol1 :={seq(plots[odeplot](dsolve({diff(w(z),z,z)-6*w(z)^2+2,w(ic)=-1,D(w)(ic)=-1.0},      w(z),type=numeric),-3..3,color=blue),ic=0..4)}:
 > galsol2  := {seq(plots[odeplot](dsolve({diff(w(z),z,z)-6*w(z)^2+2,w(ic)=2,D(w)(ic)=-5.0},      w(z),type=numeric),ic-0.15..ic+1.7,color=green),ic=-3..1)}:
 > plots[display](singsol union galsol1 union galsol2,title="g2=4,g3=-1",view=[-3..3,-3/2..3]);
 ${\mathrm{g2}}^{3}=27{\mathrm{g3}}^{2}$
 • Parametrize the equation with $g$.
 > Wps := subs(g2=3*g^2,g3=g^3,Wp);
 ${\mathrm{Wps}}{≔}{\left(\frac{{ⅆ}}{{ⅆ}{z}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{w}{}\left({z}\right)\right)}^{{2}}{-}{4}{}{{w}{}\left({z}\right)}^{{3}}{+}{3}{}{{g}}^{{2}}{}{w}{}\left({z}\right){+}{{g}}^{{3}}$ (40)
 > Ks := field_extension(transcendental_elements=[g]);
 ${\mathrm{Ks}}{≔}{\mathrm{ground_field}}$ (41)
 > Rs := differential_ring(ranking=[w],derivations=[z],notation=diff,field_of_constants=Ks):
 > equations(Rosenfeld_Groebner([Wps],Rs));
 $\left[\left[{\left(\frac{{ⅆ}}{{ⅆ}{z}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{w}{}\left({z}\right)\right)}^{{2}}{-}{4}{}{{w}{}\left({z}\right)}^{{3}}{+}{3}{}{{g}}^{{2}}{}{w}{}\left({z}\right){+}{{g}}^{{3}}\right]{,}\left[{2}{}{w}{}\left({z}\right){+}{g}\right]{,}\left[{w}{}\left({z}\right){-}{g}\right]\right]$ (42)
 > equations(essential_components(Wps,Rs));
 $\left[\left[{\left(\frac{{ⅆ}}{{ⅆ}{z}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{w}{}\left({z}\right)\right)}^{{2}}{-}{4}{}{{w}{}\left({z}\right)}^{{3}}{+}{3}{}{{g}}^{{2}}{}{w}{}\left({z}\right){+}{{g}}^{{3}}\right]{,}\left[{w}{}\left({z}\right){-}{g}\right]\right]$ (43)
 There are two singular zeros: $w\left(z\right)=g$ and $w\left(z\right)=-\frac{g}{2}$. $w\left(z\right)=g$ is an essential singular zero of $\mathrm{Wps}$ and therefore is an envelope of the nonsingular zeros of $\mathrm{Wps}$. On the contrary, the singular zero $w\left(z\right)=-\frac{g}{2}$ of $\mathrm{Wps}$ is not essential and therefore is a limiting case of the nonsingular zeros of $\mathrm{Wps}$. Observe the situation for $g=-1$:
 > singsol:=plot({-1,1/2},color=red,thickness=2):
 > galsol1:=plot({seq(-1+3/2*tanh(1/2*(C-z)*sqrt(6))^2,C=-1..1)},z=-3..3,color=green):
 > galsol2:=plot({seq(-1+3/2*coth(1/2*(C-z)*sqrt(6))^2,C=-1..1)},z=-3..3,color=blue):
 > plots[display]({singsol,galsol1,galsol2},view=[-3..3,-3/2..3],title="g2=3,g3=-1");
 • g2=0, g3=0
 • The equation is:
 > Wp0:=subs(g2=0,g3=0,Wp);
 ${\mathrm{Wp0}}{≔}{\left(\frac{{ⅆ}}{{ⅆ}{z}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{w}{}\left({z}\right)\right)}^{{2}}{-}{4}{}{{w}{}\left({z}\right)}^{{3}}$ (44)
 > R0 := differential_ring(ranking=[w],derivations=[z],notation=diff):
 > equations(Rosenfeld_Groebner([Wp0],R0));
 $\left[\left[{\left(\frac{{ⅆ}}{{ⅆ}{z}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{w}{}\left({z}\right)\right)}^{{2}}{-}{4}{}{{w}{}\left({z}\right)}^{{3}}\right]{,}\left[{w}{}\left({z}\right)\right]\right]$ (45)
 > equations(essential_components(Wp0,R0));
 $\left[\left[{\left(\frac{{ⅆ}}{{ⅆ}{z}}\phantom{\rule[-0.0ex]{0.4em}{0.0ex}}{w}{}\left({z}\right)\right)}^{{2}}{-}{4}{}{{w}{}\left({z}\right)}^{{3}}\right]\right]$ (46)
 There is only one singular zero, $w\left(z\right)=0$. It is not essential. Observe its limiting property with respect to the nonsingular zeros.
 > singsol:=plot(0,s=-4..4, color=red, thickness=2):
 > galsol:= plot({seq(1/((z-C)^2),C=-2..1)},z=-4..4):
 > plots[display]({singsol,galsol},view=[-4..4,-1/2..2]);
 More generally, the commands essential_components, and preparation_polynomial allow you to interpret some qualitative feature of singular zeros (see [Ritt (1950), Kolchin (1973)], [Hubert (1999)]). See their help pages for further examples.

Functionality

 Set up functions, notational aspects
 Differential elimination
 Power series solutions
 Analysis of singular solutions
 Function to manipulate differential polynomials
 • To display the help page for a particular diffalg command, see Getting Help with a Command in a Package.