restart:

# Invoke the Maplets Elements subpackage.
with(Maplets[Elements]):

# Define the confirm Maplet application. Define an abnormal
# shutdown as one that returns FAIL.
maplet1 := Maplet( 'abnormalshutdown' = "FAIL",
    ConfirmDialog(

        # The text that appears as the confirm Maplet application's
        # message and title.
        "Assuming x > 0 leads to a contradiction",
        'title' = "Warning:  Contradiction",

        # The value returned. Click "Yes", true.
        # Click "No", false. Click "Cancel", FAIL.
        'onapprove' = Shutdown( "true" ),
        'ondecline' = Shutdown( "false" ),
        'oncancel' = Shutdown( "FAIL" )
    )
):

# Assign result to the value returned by the Maplet application.
result := parse(Maplets[Display](maplet1));

with(Maplets[Elements]):

# Define the "onstartup" option referenced by A0.
maplet2 := Maplet( 'abnormalshutdown' = "FAIL", 'onstartup' = 'A0',
    ConfirmDialog( 'reference' = 'AD1',
        'caption' = "Assuming x > 0 leads to a contradiction",
        'title' = "Warning:  Contradiction",
        'onapprove' = 'A1',
        'ondecline' = 'A2',
        'oncancel' = 'A3'
    ),

    # Starts the ConfirmDialog.
    Action( 'reference' = 'A0',
        RunDialog( 'dialog' = 'AD1' )
    ),
    
    # Define the resulting action if "Yes" is clicked.
    Action( 'reference' = 'A1',
        Shutdown( 'value' = "true" )
    ),

    # Define the resulting action if "No" is clicked.
    Action( 'reference' = 'A2',
        Shutdown( 'value' = "false" )
    ),

    # Define the resulting action if "Cancel" is clicked.
    Action( 'reference' = 'A3',
        Shutdown( 'value' = "FAIL" )
    )
):

result := parse(Maplets[Display](maplet2));

Maplets[Tools][Print](maplet1);

Maplets[Tools][Print](maplet2);

?Maplets[Examples][Confirm]

print( Maplets[Examples][Confirm] );