Lesson 10: Tensor Analysis

All Products Maple MapleSim

Home : Support : Online Help : Mathematics : DifferentialGeometry : Lessons and Tutorials : DifferentialGeometry : Lesson 10: Tensor Analysis

DifferentialGeometry Lessons

Lesson 10: Tensor Analysis

Overview

Connections and Christoffel symbols, Torsion tensors

Covariant derivatives

Curvature tensors, Ricci tensor, Ricci scalar, Einstein tensor, Weyl tensor, Cotton tensor

Exercises

Overview

In this lesson, you will learn to do the following:

–	Construct a connection and compute its torsion.

–	Compute the Christoffel connection from a metric.

–	Calculate the covariant derivative of a tensor.

–	Calculate the Riemann curvature tensor of a connection.

–	Calculate the Ricci tensor, the scalar curvature, the Einstein tensor.

–	Calculate the Weyl tensor.

Connections and Christoffel symbols, Torsion tensors

To create an affine connection, first construct a tensor with the desired components and then use the Connection command. The torsion of the connection is computed with the TorsionTensor command.

>	with(DifferentialGeometry): with(Tensor):

>	DGsetup([x, y], E2):

E2 >	T := evalDG(y*dx &t D_y &t dy);

$T ≔ y dx D_y dy$

(2.1)

E2 >	C := Connection(T);

$C ≔ y dx D_y dy$

(2.2)

E2 >	S := TorsionTensor(C);

$S ≔ - y dx D_y dy + y dy D_y dx$

(2.3)

Remark 1. Although the display for the tensor T and the connection C are the same, the internal representations are different.

E2 >	Tools:-DGinfo(T, "ObjectType");

$tensor$

(2.4)

E2 >	Tools:-DGinfo(C, "ObjectType");

$connection$

(2.5)

Remark 2. We illustrate the fact that the rules for transforming and Lie differentiating the tensor T and the connection C are different.

E2 >	X := evalDG(x^3*D_x);

$X ≔ x^{3} D_x$

(2.6)

Here are the Lie derivatives of T and C.

E2 >	LieDerivative(X, T);

$3 x^{2} y dx D_y dy$

(2.7)

E2 >	LieDerivative(X, C);

$6 x dx D_x dx + 3 x^{2} y dx D_y dy$

(2.8)

E2 >	Phi := Transformation(E2, E2, [x = 1/x, y = 1/y]);

$Φ ≔ [x = \frac{1}{x}, y = \frac{1}{y}]$

(2.9)

E2 >	InvPhi := InverseTransformation(Phi);

$InvPhi ≔ [x = \frac{1}{x}, y = \frac{1}{y}]$

(2.10)

Here are the transformations of T and C.

E2 >	PushPullTensor(Phi, InvPhi, T);

$- \frac{dx D_y dy}{y x^{2}}$

(2.11)

E2 >	PushPullTensor(Phi, InvPhi, C);

$- \frac{2 dx D_x dx}{x} - \frac{dx D_y dy}{y x^{2}} - \frac{2 dy D_y dy}{y}$

(2.12)

The command Christoffel is used to construct the Christoffel connection for a metric g. With the optional argument "FirstKind", the Christoffel symbols of the first kind are computed.

E2 >	g := evalDG((1/y^2)*(dx &t dy + dy &t dx));

$g ≔ \frac{dx dy}{y^{2}} + \frac{dy dx}{y^{2}}$

(2.13)

E2 >	Christoffel(g);

$- \frac{2 dy D_y dy}{y}$

(2.14)

E2 >	C2 := Christoffel(g, "FirstKind");

$C2 ≔ - \frac{2 dy dx dy}{y^{3}}$

(2.15)

E2 >	type(g1, DGmetric);

$false$

(2.16)

Covariant derivatives

Let T be a tensor of type (r, s) (r = number of contravariant (upper) indices = number of 1-form arguments, s = number of covariant (lower) indices = number of vector arguments). The command DirectionalCovariantDerivative calculates the covariant derivative of T in the direction of a given vector field and with respect to a given connection -- a tensor of type (r, s) is returned. The command CovariantDerivative returns the covariant derivative of T as an (r, s + 1) tensor.

E2 >	with(DifferentialGeometry): with(Tensor):

E2 >	DGsetup([x, y], E2):

Define a vector field X, a connection C, and tensors T1 and T2.

E2 >	X := evalDG(aD_x + bD_y);

$X ≔ a D_x + b D_y$

(3.1)

E2 >	C := Connection(alphadx &t D_y &t dy + betady &t D_x &t dx);

$C ≔ α dx D_y dy + β dy D_x dx$

(3.2)

E2 >	T1 := evalDG(dx &t D_x);

$T1 ≔ dx D_x$

(3.3)

E2 >	T2 := evalDG(f(x, y)*dy &t D_y);

$T2 ≔ f (x, y) dy D_y$

(3.4)

Calculate the covariant derivative of T1.

E2 >	dT1 := CovariantDerivative(T1, C);

$dT1 ≔ α dx D_y dy - β dy D_x dx$

(3.5)

Calculate the directional derivative of T1.

E2 >	DirectionalCovariantDerivative(X, T1, C);

$α b dx D_y - β a dy D_x$

(3.6)

Show that the directional covariant derivative is the contraction of the vector field X with the covariant derivative dT1.

E2 >	ContractIndices(X, dT1, [[1, 3]]);

$α b dx D_y - β a dy D_x$

(3.7)

Conversely, calculate the covariant derivative dT1 from the directional covariant derivatives of T1 in the coordinate directions.

E2 >	evalDG((DirectionalCovariantDerivative(D_x, T1, C) &t dx) + (DirectionalCovariantDerivative(D_y, T1, C) &t dy));

$α dx D_y dy - β dy D_x dx$

(3.8)

Calculate the covariant derivative of T2.

E2 >	CovariantDerivative(T2, C);

$- α f (x, y) dx D_y dy + β f (x, y) dy D_x dx + (\frac{\partial}{\partial x} f (x, y)) dy D_y dx + (\frac{\partial}{\partial y} f (x, y)) dy D_y dy$

(3.9)

Connections on vector bundles can also be defined.

E2 >	DGsetup([x, y ,z], [u, v], E);

$frame name: E$

(3.10)

E >	C1 := Connection(alphadv &t D_v &t dx + betadu &t D_u &t dy);

$C1 ≔ β du D_u dy + α dv D_v dx$

(3.11)

Define a tensor field T3 on the vector bundle E and take its covariant derivative.

E >	T3 := evalDG(y*du &t D_v);

$T3 ≔ y du D_v$

(3.12)

E >	dT3 := CovariantDerivative(T3, C1);

$dT3 ≔ α y du D_v dx + (- β y + 1) du D_v dy$

(3.13)

Define a mixed tensor T4 -- i.e. a tensor product of tensors on the vector bundle and tensors on the tangent bundle. To covariantly differentiateT4, a connection C2 on the tangent bundle is also required.

E >	T4 := evalDG(x*dx &t D_v);

$T4 ≔ x dx D_v$

(3.14)

E >	C2 := Connection(gamma*dx &t D_x &t dx);

$C2 ≔ γ dx D_x dx$

(3.15)

E >	dT4 := CovariantDerivative(T4, C1, C2);

$dT4 ≔ (α x - γ x + 1) dx D_v dx$

(3.16)

The order in which the connections are specified does not matter.

E >	CovariantDerivative(T4, C2, C1);

$(α x - γ x + 1) dx D_v dx$

(3.17)

Curvature tensors, Ricci tensor, Ricci scalar, Einstein tensor, Weyl tensor, Cotton tensor

These tensors are readily computed using the CurvatureTensor, RicciTensor, RicciScalar, EinsteinTensor, WeylTensor and CottonTensor commands. The CurvatureTensor command accepts either an arbitrary affine connection (connection on the tangent bundle), a connection on a vector bundle or a metric. The RicciTensor command computes the Ricci tensor for an arbitrary affine connection. The RicciScalar, EinsteinTensor, WeylTensor, and Cotton tensor commands may only be computed for metric connections.

E >	with(DifferentialGeometry): with(Tensor):

Example 1.

>	DGsetup([x, y, z], M):

Define a metric g.

M >	g := (1/(k^2 + x^2 + y^2 + z^2)^2) &mult evalDG((dx &t dx + dy &t dy + dz &t dz ));

$g ≔ \frac{dx dx}{{(k^{2} + x^{2} + y^{2} + z^{2})}^{2}} + \frac{dy dy}{{(k^{2} + x^{2} + y^{2} + z^{2})}^{2}} + \frac{dz dz}{{(k^{2} + x^{2} + y^{2} + z^{2})}^{2}}$

(4.1)

Calculate the Christoffel connection of g.

M >	C := Christoffel(g);

$C ≔ - \frac{2 x dx D_x dx}{k^{2} + x^{2} + y^{2} + z^{2}} - \frac{2 y dx D_x dy}{k^{2} + x^{2} + y^{2} + z^{2}} - \frac{2 z dx D_x dz}{k^{2} + x^{2} + y^{2} + z^{2}} + \frac{2 y dx D_y dx}{k^{2} + x^{2} + y^{2} + z^{2}} - \frac{2 x dx D_y dy}{k^{2} + x^{2} + y^{2} + z^{2}} + \frac{2 z dx D_z dx}{k^{2} + x^{2} + y^{2} + z^{2}} - \frac{2 x dx D_z dz}{k^{2} + x^{2} + y^{2} + z^{2}} - \frac{2 y dy D_x dx}{k^{2} + x^{2} + y^{2} + z^{2}} + \frac{2 x dy D_x dy}{k^{2} + x^{2} + y^{2} + z^{2}} - \frac{2 x dy D_y dx}{k^{2} + x^{2} + y^{2} + z^{2}} - \frac{2 y dy D_y dy}{k^{2} + x^{2} + y^{2} + z^{2}} - \frac{2 z dy D_y dz}{k^{2} + x^{2} + y^{2} + z^{2}} + \frac{2 z dy D_z dy}{k^{2} + x^{2} + y^{2} + z^{2}} - \frac{2 y dy D_z dz}{k^{2} + x^{2} + y^{2} + z^{2}} - \frac{2 z dz D_x dx}{k^{2} + x^{2} + y^{2} + z^{2}} + \frac{2 x dz D_x dz}{k^{2} + x^{2} + y^{2} + z^{2}} - \frac{2 z dz D_y dy}{k^{2} + x^{2} + y^{2} + z^{2}} + \frac{2 y dz D_y dz}{k^{2} + x^{2} + y^{2} + z^{2}} - \frac{2 x dz D_z dx}{k^{2} + x^{2} + y^{2} + z^{2}} - \frac{2 y dz D_z dy}{k^{2} + x^{2} + y^{2} + z^{2}} - \frac{2 z dz D_z dz}{k^{2} + x^{2} + y^{2} + z^{2}}$

(4.2)

Calculate the curvature tensor for the metric g from its Christoffel symbol C.

M >	R := CurvatureTensor(C);

$R ≔ \frac{4 k^{2} D_x dy dx dy}{{(k^{2} + x^{2} + y^{2} + z^{2})}^{2}} - \frac{4 k^{2} D_x dy dy dx}{{(k^{2} + x^{2} + y^{2} + z^{2})}^{2}} + \frac{4 k^{2} D_x dz dx dz}{{(k^{2} + x^{2} + y^{2} + z^{2})}^{2}} - \frac{4 k^{2} D_x dz dz dx}{{(k^{2} + x^{2} + y^{2} + z^{2})}^{2}} - \frac{4 k^{2} D_y dx dx dy}{{(k^{2} + x^{2} + y^{2} + z^{2})}^{2}} + \frac{4 k^{2} D_y dx dy dx}{{(k^{2} + x^{2} + y^{2} + z^{2})}^{2}} + \frac{4 k^{2} D_y dz dy dz}{{(k^{2} + x^{2} + y^{2} + z^{2})}^{2}} - \frac{4 k^{2} D_y dz dz dy}{{(k^{2} + x^{2} + y^{2} + z^{2})}^{2}} - \frac{4 k^{2} D_z dx dx dz}{{(k^{2} + x^{2} + y^{2} + z^{2})}^{2}} + \frac{4 k^{2} D_z dx dz dx}{{(k^{2} + x^{2} + y^{2} + z^{2})}^{2}} - \frac{4 k^{2} D_z dy dy dz}{{(k^{2} + x^{2} + y^{2} + z^{2})}^{2}} + \frac{4 k^{2} D_z dy dz dy}{{(k^{2} + x^{2} + y^{2} + z^{2})}^{2}}$

(4.3)

Calculate the Ricci tensor from the curvature tensor.

M >	RicciTensor(R);

$\frac{8 k^{2} dx dx}{{(k^{2} + x^{2} + y^{2} + z^{2})}^{2}} + \frac{8 k^{2} dy dy}{{(k^{2} + x^{2} + y^{2} + z^{2})}^{2}} + \frac{8 k^{2} dz dz}{{(k^{2} + x^{2} + y^{2} + z^{2})}^{2}}$

(4.4)

Calculate the Ricci scalar from the metric and its curvature tensor.

M >	RicciScalar(g, R);

$24 k^{2}$

(4.5)

Calculate the Einstein tensor from the metric and its curvature tensor.

M >	EinsteinTensor(g, R);

$- 4 k^{2} {(k^{2} + x^{2} + y^{2} + z^{2})}^{2} D_x D_x - 4 k^{2} {(k^{2} + x^{2} + y^{2} + z^{2})}^{2} D_y D_y - 4 k^{2} {(k^{2} + x^{2} + y^{2} + z^{2})}^{2} D_z D_z$

(4.6)

Calculate the Cotton tensor from the metric, its Christoffel connection and its curvature. The Cotton tensor vanishes because the metric is conformally flat.

M >	CottonTensor(g, C, R);

$0 D_x D_x$

(4.7)

Example 2.

For a general affine connection, we can still compute the curvature and Ricci tensors. Note that the Ricci tensor is no longer symmetric.

M >	C := Connection(z^2dz &t D_y &t dx - x^2dy &t D_x &t dz);

$C ≔ - x^{2} dy D_x dz + z^{2} dz D_y dx$

(4.8)

M >	R := CurvatureTensor(C);

$R ≔ - 2 x D_x dy dx dz + 2 x D_x dy dz dx + x^{2} z^{2} D_x dz dx dz - x^{2} z^{2} D_x dz dz dx - 2 z D_y dz dx dz + 2 z D_y dz dz dx$

(4.9)

M >	RicciTensor(R);

$- 2 x dy dz + x^{2} z^{2} dz dz$

(4.10)

Example 3.

The CurvatureTensor command also computes the curvature tensor of a connection on a vector bundle.

M >	DGsetup([x, y, z], [u, v], E);

$frame name: E$

(4.11)

E >	C := Connection(z^2*du &t D_v &t dx);

$C ≔ z^{2} du D_v dx$

(4.12)

E >	CurvatureTensor(C);

$- 2 z D_v du dx dz + 2 z D_v du dz dx$

(4.13)

Exercises

Exercise 1

Let g be a metric. Then the Laplacian of a function f with respect to the metric g is defined as the trace of the second covariant derivative of f (that is, the contraction of the second covariant derivative with the inverse of the metric). Use this definition to calculate the Laplacian of a function in spherical coordinates.

Hint: Use the PushPullTensor command to transform the standard metric on Euclidean space to spherical coordinates.

E >	with(DifferentialGeometry): with(Tensor):

Solution

Define Cartesian and spherical coordinate systems.

E >	DGsetup([x, y, z], Euc):

Euc >

DGsetup([rho, theta, phi], Sph):

Define the Euclidean metric on Euc and use the PushPullTensor command to rewrite this metric in spherical coordinates.

Sph >

gEuc := evalDG(dx &t dx + dy &t dy + dz &t dz);

$gEuc ≔ dx dx + dy dy + dz dz$

(5.1.1.1)

Euc >

T := Transformation(Sph, Euc, [x = rho*cos(theta)*sin(phi), y = rho*sin(theta)*sin(phi), z = rho*cos(phi)]);

$T ≔ [x = ρ \cos (θ) \sin (φ), y = ρ \sin (θ) \sin (φ), z = ρ \cos (φ)]$

(5.1.1.2)

Sph >

gSph := Pullback(T, gEuc);

$gSph ≔ drho drho + ρ^{2} {\sin (φ)}^{2} dtheta dtheta + ρ^{2} dphi dphi$

(5.1.1.3)

Calculate the inverse of the metric gSph.

Sph >

h := InverseMetric(gSph);

$h ≔ D_rho D_rho + \frac{D_theta D_theta}{ρ^{2} {\sin (φ)}^{2}} + \frac{D_phi D_phi}{ρ^{2}}$

(5.1.1.4)

Calculate the Christoffel connection for the metric gSph.

Sph >

C := Christoffel(gSph);

$C ≔ \frac{drho D_theta dtheta}{ρ} + \frac{drho D_phi dphi}{ρ} - ρ {\sin (φ)}^{2} dtheta D_rho dtheta + \frac{dtheta D_theta drho}{ρ} + \frac{\cos (φ) dtheta D_theta dphi}{\sin (φ)} - \sin (φ) \cos (φ) dtheta D_phi dtheta - ρ dphi D_rho dphi + \frac{\cos (φ) dphi D_theta dtheta}{\sin (φ)} + \frac{dphi D_phi drho}{ρ}$

(5.1.1.5)

Calculate the covariant derivative of the function f.

Sph >

PDEtools:-declare(f(rho, theta, phi));

$f (ρ, θ, φ) will now be displayed as f$

(5.1.1.6)

Sph >

df := CovariantDerivative(f(rho, theta, phi), C);

$df ≔ f_{ρ} drho + f_{θ} dtheta + f_{φ} dphi$

(5.1.1.7)

Calculate the 2nd covariant derivative of the function f.

Sph >

d2f := CovariantDerivative(df, C);

$d2f ≔ f_{ρ, ρ} drho drho + \frac{(- f_{θ} + f_{ρ, θ} ρ) drho dtheta}{ρ} - \frac{(f_{φ} - f_{φ, ρ} ρ) drho dphi}{ρ} + \frac{(- f_{θ} + f_{ρ, θ} ρ) dtheta drho}{ρ} + (\sin (φ) \cos (φ) f_{φ} + ρ f_{ρ} - ρ f_{ρ} {\cos (φ)}^{2} + f_{θ, θ}) dtheta dtheta + \frac{(- \cos (φ) f_{θ} + f_{φ, θ} \sin (φ)) dtheta dphi}{\sin (φ)} - \frac{(f_{φ} - f_{φ, ρ} ρ) dphi drho}{ρ} + \frac{(- \cos (φ) f_{θ} + f_{φ, θ} \sin (φ)) dphi dtheta}{\sin (φ)} + (ρ f_{ρ} + f_{φ, φ}) dphi dphi$

(5.1.1.8)

Calculate the Laplacian of f.

Sph >

Lap := ContractIndices(h, d2f, [[1, 1], [2, 2]]);

$Lap ≔ - \frac{- 2 ρ f_{ρ} + 2 ρ f_{ρ} {\cos (φ)}^{2} - f_{φ, φ} + f_{φ, φ} {\cos (φ)}^{2} - \sin (φ) \cos (φ) f_{φ} - f_{θ, θ} - f_{ρ, ρ} ρ^{2} + f_{ρ, ρ} ρ^{2} {\cos (φ)}^{2}}{ρ^{2} {\sin (φ)}^{2}}$

(5.1.1.9)

Sph >

simplify(Lap, [cos(phi)^2 = 1 - sin(phi)^2]);

$\frac{f_{θ, θ} + (2 ρ f_{ρ} + f_{φ, φ} + f_{ρ, ρ} ρ^{2}) {\sin (φ)}^{2} + \sin (φ) \cos (φ) f_{φ}}{ρ^{2} {\sin (φ)}^{2}}$

(5.1.1.10)

Exercise 2

An affine connection nabla on a manifold M is abstractly defined as a mapping (X,Y) -> nabla_X(Y) -- the directional covariant derivative of a vector field Y in the direction of the vector field X. In terms of this definition, the curvature tensor R is defined by

R(X, Y)(Z) = nabla_X(nabla_Y(Z)) - nabla_Y(nabla_X(Z)) - nabla_[X, Y](Z).

Here X, Y and Z are vector fields on M and R(X, Y)(Z) denotes the contraction of R against the vector fields X, Y, Z over the 3rd ,4th and 1st indices respectively. Also, [X, Y] is the Lie bracket of X and Y.

Write a program CheckCurvatureDefinition whose arguments are a connection, its curvature and 3 vector fields and which checks the validity of this definition. Test your program on the following example.

Sph >

with(DifferentialGeometry): with(Tensor):

Sph >

DGsetup([x, y, z], M):

M >	C := Connection(x^2dx &t D_y &t dz - yz*dz &t D_z &t dy);

$C ≔ x^{2} dx D_y dz - y z dz D_z dy$

(5.2.1)

M >	X1, Y1, Z1 := evalDG(xD_y - y^2D_z), evalDG(z^2D_x + xyD_y), evalDG(yzD_x + z^2D_z);

$X1, Y1, Z1 ≔ x D_y - y^{2} D_z, z^{2} D_x + x y D_y, y z D_x + z^{2} D_z$

(5.2.2)

Solution

M >	CheckCurvatureDefinition := proc(C, R, X, Y, Z)

M >	local LHS, RHS1, RHS2, RHS3, W, Ans;

M >	LHS := ContractIndices(Z &tensor X &tensor Y, R, [[1, 2], [2, 3], [3, 4]]);

M >	RHS1 := DirectionalCovariantDerivative(X, DirectionalCovariantDerivative(Y, Z, C), C);

M >	RHS2 := DirectionalCovariantDerivative(Y, DirectionalCovariantDerivative(X, Z, C), C);

M >	W := LieBracket(X, Y);

M >	RHS3 := DirectionalCovariantDerivative(W, Z, C);

M >	Ans := evalDG(LHS - (RHS1 - RHS2 - RHS3));

M >	simplify(Ans):

M >

end:

M >	R := CurvatureTensor(C);

$R ≔ 2 x D_y dx dx dz - 2 x D_y dx dz dx + y D_z dz dy dz - y D_z dz dz dy$

(5.2.1.1)

M >	CheckCurvatureDefinition(C, R, X1, Y1, Z1);

$0 D_x$

(5.2.1.2)

Exercise 3

Check that the curvature tensor (as a rank 4 covariant tensor) for the metric g satisfies the following identities:

[i] skew-symmetric in the indices 1, 2.

[ii] skew-symmetric in the indices 3, 4.

[iii] cyclic permutation of the indices 2, 3, 4 vanishes.

[iv] symmetric under interchange of the indices 1 <--> 3 and 2 <--> 4.

[v] cyclic permutation of the indices 3, 4, 5 of the covariant derivative of R vanishes.

M >	with(DifferentialGeometry): with(Tensor):

M >	DGsetup([x, y, z, w], M):

M >	g := evalDG(exp(z)dx &t dx + exp(x)dy &t dy + exp(w)*dz &t dz + dw &t dw);

$g ≔ {&ExponentialE;}^{z} dx dx + {&ExponentialE;}^{x} dy dy + {&ExponentialE;}^{w} dz dz + dw dw$

(5.3.1)

Solution

M >	C := Christoffel(g);

$C ≔ \frac{dx D_x dz}{2} + \frac{dx D_y dy}{2} - \frac{1}{2} {&ExponentialE;}^{- w + z} dx D_z dx - \frac{1}{2} {&ExponentialE;}^{- z + x} dy D_x dy + \frac{dy D_y dx}{2} + \frac{dz D_x dx}{2} + \frac{dz D_z dw}{2} - \frac{1}{2} {&ExponentialE;}^{w} dz D_w dz + \frac{dw D_z dz}{2}$

(5.3.1.1)

M >	R0 := CurvatureTensor(C);

$R0 ≔ - \frac{D_x dz dw dx}{4} + \frac{D_y dx dy dz}{4} + \frac{D_y dx dx dy}{4} - \frac{1}{4} {&ExponentialE;}^{z} D_w dx dx dz + \frac{1}{4} {&ExponentialE;}^{z} D_w dx dz dx + \frac{D_y dz dy dx}{4} - \frac{D_z dw dz dw}{4} - \frac{D_x dw dz dx}{4} + \frac{D_x dw dx dz}{4} - \frac{D_y dx dz dy}{4} - \frac{D_x dz dx dz}{4} - \frac{1}{4} {&ExponentialE;}^{- w + x} D_z dy dy dx - \frac{D_y dz dx dy}{4} + \frac{D_x dz dx dw}{4} - \frac{D_y dx dy dx}{4} + \frac{D_z dw dw dz}{4} + \frac{D_x dz dz dx}{4} + \frac{1}{4} {&ExponentialE;}^{w} D_w dz dz dw + \frac{1}{4} {&ExponentialE;}^{- z + x} D_x dy dy dx - \frac{1}{4} {&ExponentialE;}^{- z + x} D_x dy dy dz - \frac{1}{4} {&ExponentialE;}^{- z + x} D_x dy dx dy - \frac{1}{4} {&ExponentialE;}^{w} D_w dz dw dz + \frac{1}{4} {&ExponentialE;}^{- w + z} D_z dx dw dx + \frac{1}{4} {&ExponentialE;}^{- w + x} D_z dy dx dy - \frac{1}{4} {&ExponentialE;}^{- w + z} D_z dx dx dw - \frac{1}{4} {&ExponentialE;}^{- w + z} D_z dx dz dx + \frac{1}{4} {&ExponentialE;}^{- z + x} D_x dy dz dy + \frac{1}{4} {&ExponentialE;}^{- w + z} D_z dx dx dz$

(5.3.1.2)

M >	R := RaiseLowerIndices(g, R0, [1]);

$R ≔ - \frac{1}{4} {&ExponentialE;}^{x} dx dy dx dy + \frac{1}{4} {&ExponentialE;}^{x} dx dy dy dx - \frac{1}{4} {&ExponentialE;}^{x} dz dy dy dx - \frac{1}{4} {&ExponentialE;}^{w} dz dw dz dw + \frac{1}{4} {&ExponentialE;}^{w} dz dw dw dz - \frac{1}{4} {&ExponentialE;}^{z} dw dx dx dz + \frac{1}{4} {&ExponentialE;}^{z} dw dx dz dx + \frac{1}{4} {&ExponentialE;}^{w} dw dz dz dw - \frac{1}{4} {&ExponentialE;}^{w} dw dz dw dz - \frac{1}{4} {&ExponentialE;}^{z} dz dx dz dx + \frac{1}{4} {&ExponentialE;}^{z} dz dx dw dx + \frac{1}{4} {&ExponentialE;}^{x} dz dy dx dy + \frac{1}{4} {&ExponentialE;}^{x} dy dz dy dx + \frac{1}{4} {&ExponentialE;}^{z} dz dx dx dz - \frac{1}{4} {&ExponentialE;}^{z} dz dx dx dw + \frac{1}{4} {&ExponentialE;}^{z} dx dz dx dw + \frac{1}{4} {&ExponentialE;}^{z} dx dz dz dx - \frac{1}{4} {&ExponentialE;}^{z} dx dz dw dx + \frac{1}{4} {&ExponentialE;}^{z} dx dw dx dz - \frac{1}{4} {&ExponentialE;}^{z} dx dw dz dx + \frac{1}{4} {&ExponentialE;}^{x} dy dx dx dy - \frac{1}{4} {&ExponentialE;}^{x} dy dx dy dx + \frac{1}{4} {&ExponentialE;}^{x} dy dx dy dz - \frac{1}{4} {&ExponentialE;}^{x} dy dx dz dy - \frac{1}{4} {&ExponentialE;}^{x} dy dz dx dy - \frac{1}{4} {&ExponentialE;}^{x} dx dy dy dz + \frac{1}{4} {&ExponentialE;}^{x} dx dy dz dy - \frac{1}{4} {&ExponentialE;}^{z} dx dz dx dz$

(5.3.1.3)

Part [i]

M >	SymmetrizeIndices(R, [1, 2], "Symmetric");

$0 dx dx dx dx$

(5.3.1.4)

Part [ii]

M >	SymmetrizeIndices(R, [3, 4], "Symmetric");

$0 dx dx dx dx$

(5.3.1.5)

Part [iii]

M >	SymmetrizeIndices(R, [2, 3, 4], "SkewSymmetric");

$0 dx dx dx dx$

(5.3.1.6)

Part [iv]

M >	R &minus RearrangeIndices(R, [[1, 3], [2, 4]]);

$0 dx dx dx dx$

(5.3.1.7)

Part [v]

M >	R1 := CovariantDerivative(R, C):

M >	SymmetrizeIndices(R1, [3, 4, 5], "SkewSymmetric");

$0 dx dx dx dx dx$

(5.3.1.8)

Exercise 4

The covariant divergence of the Einstein tensor is identically zero. Check this identity for the metric in Exercise 3.

M >	with(DifferentialGeometry): with(Tensor):

M >	DGsetup([x, y, z, w], M):

M >	g := evalDG(exp(z)dx &t dx + exp(x)dy &t dy + exp(w)*dz &t dz + dw &t dw);

$g ≔ {&ExponentialE;}^{z} dx dx + {&ExponentialE;}^{x} dy dy + {&ExponentialE;}^{w} dz dz + dw dw$

(5.4.1)

Solution

Calculate the Christoffel connection.

M >	C := Christoffel(g):

Calculate the curvature tensor.

M >	R0 := CurvatureTensor(C):

Calculate the Einstein tensor.

M >	E := EinsteinTensor(g, R0);

$E ≔ \frac{1}{4} {&ExponentialE;}^{- z} D_x D_x + \frac{1}{4} {&ExponentialE;}^{- z - w} D_x D_z + (\frac{1}{4} {&ExponentialE;}^{- x} + \frac{1}{4} {&ExponentialE;}^{- x - w}) D_y D_y + \frac{1}{4} {&ExponentialE;}^{- z - w} D_z D_x + \frac{1}{4} {&ExponentialE;}^{- z - w} D_z D_z + \frac{1}{4} {&ExponentialE;}^{- w} D_z D_w + \frac{1}{4} {&ExponentialE;}^{- w} D_w D_z + (\frac{1}{4} {&ExponentialE;}^{- w} + \frac{1}{4} {&ExponentialE;}^{- z}) D_w D_w$

(5.4.1.1)

Calculate the covariant derivative of the Einstein tensor.

M >	dE := CovariantDerivative(E, C);

$dE ≔ \frac{1}{4} {&ExponentialE;}^{- z - w} D_x D_x dx - \frac{1}{8} {&ExponentialE;}^{- z - w} D_x D_y dy + (\frac{1}{8} {&ExponentialE;}^{- z - w} - \frac{1}{8} {&ExponentialE;}^{- w}) D_x D_z dx - \frac{1}{8} {&ExponentialE;}^{- z - w} D_x D_z dz - \frac{1}{8} {&ExponentialE;}^{- z - w} D_x D_z dw + \frac{1}{8} {&ExponentialE;}^{- w} D_x D_w dx - \frac{1}{8} {&ExponentialE;}^{- z} D_x D_w dz - \frac{1}{8} {&ExponentialE;}^{- z - w} D_y D_x dy - \frac{1}{4} {&ExponentialE;}^{- x - w} D_y D_y dw + \frac{1}{8} {&ExponentialE;}^{- z - w} D_y D_z dy + (\frac{1}{8} {&ExponentialE;}^{- z - w} - \frac{1}{8} {&ExponentialE;}^{- w}) D_z D_x dx - \frac{1}{8} {&ExponentialE;}^{- z - w} D_z D_x dz - \frac{1}{8} {&ExponentialE;}^{- z - w} D_z D_x dw + \frac{1}{8} {&ExponentialE;}^{- z - w} D_z D_y dy - \frac{1}{4} {&ExponentialE;}^{- 2 w} D_z D_z dx + (\frac{1}{4} {&ExponentialE;}^{- w} - \frac{1}{4} {&ExponentialE;}^{- z - w}) D_z D_z dz + \frac{1}{8} {&ExponentialE;}^{- w} D_z D_w dz - \frac{1}{8} {&ExponentialE;}^{- w} D_z D_w dw + \frac{1}{8} {&ExponentialE;}^{- w} D_w D_x dx - \frac{1}{8} {&ExponentialE;}^{- z} D_w D_x dz + \frac{1}{8} {&ExponentialE;}^{- w} D_w D_z dz - \frac{1}{8} {&ExponentialE;}^{- w} D_w D_z dw + (- \frac{1}{4} - \frac{1}{4} {&ExponentialE;}^{- z}) D_w D_w dz - \frac{1}{4} {&ExponentialE;}^{- w} D_w D_w dw$

(5.4.1.2)

Contract the 2nd and 3rd indices of dE.

M >	ContractIndices(dE, [[2, 3]]);

$0 D_x$

(5.4.1.3)

Exercise 5

For what values of a1, a2, a3, a4 does the metric g have vanishing Ricci tensor. (See Stephani, Kramer et. al., page 197.)

M >	with(DifferentialGeometry): with(Tensor):

M >	DGsetup([x1, x2, x3, x4], M):

M >	G := LinearAlgebra:-DiagonalMatrix([x4^(2a1), x4^(2a2), x4^(2a3), x4^(2a4)]);

M >	g := convert(G, DGtensor, [["cov_bas", "cov_bas"], []]);

$g ≔ {x4}^{2 a1} dx1 dx1 + {x4}^{2 a2} dx2 dx2 + {x4}^{2 a3} dx3 dx3 + {x4}^{2 a4} dx4 dx4$

(5.5.1)

Solution

M >	C := Christoffel(g);

$C ≔ \frac{a1 dx1 D_x1 dx4}{x4} - {x4}^{- 2 a4 + 2 a1 - 1} a1 dx1 D_x4 dx1 + \frac{a2 dx2 D_x2 dx4}{x4} - {x4}^{- 2 a4 + 2 a2 - 1} a2 dx2 D_x4 dx2 + \frac{a3 dx3 D_x3 dx4}{x4} - {x4}^{- 2 a4 + 2 a3 - 1} a3 dx3 D_x4 dx3 + \frac{a1 dx4 D_x1 dx1}{x4} + \frac{a2 dx4 D_x2 dx2}{x4} + \frac{a3 dx4 D_x3 dx3}{x4} + \frac{a4 dx4 D_x4 dx4}{x4}$

(5.5.1.1)

M >	R := CurvatureTensor(C);

$R ≔ - a1 {x4}^{- 2 a4 + 2 a2 - 2} a2 D_x1 dx2 dx1 dx2 + a1 {x4}^{- 2 a4 + 2 a2 - 2} a2 D_x1 dx2 dx2 dx1 - a1 {x4}^{- 2 a4 + 2 a3 - 2} a3 D_x1 dx3 dx1 dx3 + a1 {x4}^{- 2 a4 + 2 a3 - 2} a3 D_x1 dx3 dx3 dx1 - \frac{a1 (- a4 + a1 - 1) D_x1 dx4 dx1 dx4}{{x4}^{2}} + \frac{a1 (- a4 + a1 - 1) D_x1 dx4 dx4 dx1}{{x4}^{2}} + a2 {x4}^{- 2 a4 + 2 a1 - 2} a1 D_x2 dx1 dx1 dx2 - a2 {x4}^{- 2 a4 + 2 a1 - 2} a1 D_x2 dx1 dx2 dx1 - a2 {x4}^{- 2 a4 + 2 a3 - 2} a3 D_x2 dx3 dx2 dx3 + a2 {x4}^{- 2 a4 + 2 a3 - 2} a3 D_x2 dx3 dx3 dx2 - \frac{a2 (- a4 + a2 - 1) D_x2 dx4 dx2 dx4}{{x4}^{2}} + \frac{a2 (- a4 + a2 - 1) D_x2 dx4 dx4 dx2}{{x4}^{2}} + a3 {x4}^{- 2 a4 + 2 a1 - 2} a1 D_x3 dx1 dx1 dx3 - a3 {x4}^{- 2 a4 + 2 a1 - 2} a1 D_x3 dx1 dx3 dx1 + a3 {x4}^{- 2 a4 + 2 a2 - 2} a2 D_x3 dx2 dx2 dx3 - a3 {x4}^{- 2 a4 + 2 a2 - 2} a2 D_x3 dx2 dx3 dx2 - \frac{a3 (- a4 + a3 - 1) D_x3 dx4 dx3 dx4}{{x4}^{2}} + \frac{a3 (- a4 + a3 - 1) D_x3 dx4 dx4 dx3}{{x4}^{2}} + {x4}^{- 2 a4 + 2 a1 - 2} a1 (- a4 + a1 - 1) D_x4 dx1 dx1 dx4 - {x4}^{- 2 a4 + 2 a1 - 2} a1 (- a4 + a1 - 1) D_x4 dx1 dx4 dx1 + {x4}^{- 2 a4 + 2 a2 - 2} a2 (- a4 + a2 - 1) D_x4 dx2 dx2 dx4 - {x4}^{- 2 a4 + 2 a2 - 2} a2 (- a4 + a2 - 1) D_x4 dx2 dx4 dx2 + {x4}^{- 2 a4 + 2 a3 - 2} a3 (- a4 + a3 - 1) D_x4 dx3 dx3 dx4 - {x4}^{- 2 a4 + 2 a3 - 2} a3 (- a4 + a3 - 1) D_x4 dx3 dx4 dx3$

(5.5.1.2)

M >	Ric := RicciTensor(R);

$Ric ≔ - {x4}^{- 2 a4 + 2 a1 - 2} a1 (- a4 + a1 - 1 + a3 + a2) dx1 dx1 - {x4}^{- 2 a4 + 2 a2 - 2} a2 (- a4 + a1 - 1 + a3 + a2) dx2 dx2 - {x4}^{- 2 a4 + 2 a3 - 2} a3 (- a4 + a1 - 1 + a3 + a2) dx3 dx3 - \frac{(- a3 a4 + {a3}^{2} - a3 - a2 a4 + {a2}^{2} - a2 - a1 a4 + {a1}^{2} - a1) dx4 dx4}{{x4}^{2}}$

(5.5.1.3)

M >	Constraints := [a1 + a2 + a3 = a4 + 1, a1^2 + a2^2 + a3^2 = (a4 + 1)^2];

$Constraints ≔ [a1 + a2 + a3 = a4 + 1, {a1}^{2} + {a2}^{2} + {a3}^{2} = {(a4 + 1)}^{2}]$

(5.5.1.4)

M >	Tools:-DGmap(1, simplify, Ric, Constraints);

$0 dx1 dx1$

(5.5.1.5)

Exercise 6

A vector field is parallel with respect to a connection C if and only if covariant derivative vanishes. The integrability conditions which insure the existence of a basis of parallel vector fields is given by the vanishing of the curvature tensor.

[i] Check that the curvature tensor of the symmetric connection C vanishes.

[ii] Then use the Maple pdsolve command to find a set of 3 vector fields X1, X2, X3 which are parallel with respect to C and satisfy X1(p) = D_x, X2(p) = D_y, and X3(p) = D_z, where p = [1, 1, 1].

M >	with(DifferentialGeometry): with(Tensor):

E3 >	DGsetup([x, y, z], E3):

E3 >	C := Connection((1/y)dx &t D_x &t dy - (1/z)dx &t D_x &t dz + (1/y)dy &t D_x &t dx - (1/z)dy &t D_y &t dz - (1/z)dz &t D_x &t dx - (1/z)dz &t D_y &t dy - (2/z)*dz &t D_z &t dz);

$C ≔ \frac{dx D_x dy}{y} - \frac{dx D_x dz}{z} + \frac{dy D_x dx}{y} - \frac{dy D_y dz}{z} - \frac{dz D_x dx}{z} - \frac{dz D_y dy}{z} - \frac{2 dz D_z dz}{z}$

(5.6.1)

Solution

Part [i]

E3 >	CurvatureTensor(C);

$0 D_x dx dx dx$

(5.6.1.1)

Part [ii]

First create a vector field on E3 with arbitrary coefficients.

E3 >	PDEtools:-declare([a, b, c](x, y, z), quiet);

E3 >	U0 := evalDG(a(x, y, z)D_x + b(x, y, z)D_y + c(x, y, z)*D_z);

$U0 ≔ a D_x + b D_y + c D_z$

(5.6.1.2)

Calculate the covariant derivative of the vector field U0 with respect to the connection C.

E3 >	V := CovariantDerivative(U0, C);

$V ≔ \frac{(- c y + z b + z a_{x} y) D_x dx}{y z} + \frac{(a + a_{y} y) D_x dy}{y} - \frac{(a - a_{z} z) D_x dz}{z} + b_{x} D_y dx + \frac{(- c + b_{y} z) D_y dy}{z} - \frac{(b - b_{z} z) D_y dz}{z} + c_{x} D_z dx + c_{y} D_z dy - \frac{(2 c - c_{z} z) D_z dz}{z}$

(5.6.1.3)

Solve the partial differential equations obtained by setting the coefficients of the covariant derivatives to 0.

E3 >	Eq := Tools:-DGinfo(V, "CoefficientSet");

$Eq ≔ \{b_{x}, c_{x}, c_{y}, \frac{a + a_{y} y}{y}, \frac{- c + b_{y} z}{z}, \frac{- c y + z b + z a_{x} y}{y z}, - \frac{a - a_{z} z}{z}, - \frac{b - b_{z} z}{z}, - \frac{2 c - c_{z} z}{z}\}$

(5.6.1.4)

E3 >	soln := pdsolve(Eq);

$soln ≔ \{a = \frac{(_C2 x +_C3) z}{y}, b = z (_C1 y -_C2), c =_C1 z^{2}\}$

(5.6.1.5)

Back substitute the solution to the equations Eq into the vector field U0.

E3 >	U1 := eval(U0, soln);

$U1 ≔ \frac{(_C2 x +_C3) z D_x}{y} + z (_C1 y -_C2) D_y +_C1 z^{2} D_z$

(5.6.1.6)

E3 >	U2 := eval(U1, [x = 1, y = 1, z = 1]);

$U2 ≔ (_C2 +_C3) D_x + (_C1 -_C2) D_y +_C1 D_z$

(5.6.1.7)

Determine the values for _C1, _C2, _C3 to match the initial values specified in the problem.

E3 >	X := Tools:-DGsimplify(eval(U1, {_C1 = 0, _C2 = 0, _C3 = 1}));

$X ≔ \frac{z D_x}{y}$

(5.6.1.8)

E3 >	Y := Tools:-DGsimplify(eval(U1, {_C1 = 0, _C2 = -1, _C3 = 1}));

$Y ≔ - \frac{(x - 1) z D_x}{y} + z D_y$

(5.6.1.9)

E3 >	Z := Tools:-DGsimplify(eval(U1, {_C1 = 1, _C2 = 1, _C3 = -1}));

$Z ≔ \frac{(x - 1) z D_x}{y} + z (y - 1) D_y + z^{2} D_z$

(5.6.1.10)

Remark. The Lie brackets of X, Y, and Z all vanish.

E3 >	LieBracket(X, Y), LieBracket(X, Z), LieBracket(Y, Z);

$0 D_x, 0 D_x, 0 D_x$

(5.6.1.11)

Exercise 7

The following exercise appears in Lovelock and Rund, page 178, and also Spivak, page 320.

Let A be a symmetric rank 2 covariant tensor on R^n. Let nabla denote covariant differentiation with respect to the zero connection on R^n and consider the system of PDEs

A = SymmetrizeIndices(nabla(U), [1, 2], symmetric) (*)

The integrability conditions for the equations (*) are

SymmetrizeIndices(nabla(nabla(A), [[1, 3], [2, 4]], skewsymmetric) = 0 (**)

[i] Write a program which checks these integrability conditions.

[ii] Integrate the equations (*) by using two applications of the homotopy operator for the exterior derivative operator.

Use the following tensors to check your programs.

E3 >	with(DifferentialGeometry): with(Tensor):

E3 >	DGsetup([x, y, z], M3):

M3 >	DGsetup([x, y, z, w], M4):

M4 >	ChangeFrame(M3):

M3 >	A1 := evalDG((y + z)dx &t dz + xdy &t dz + (y + z)dz &t dx + xdz &t dy);

$A1 ≔ (y + z) dx dz + x dy dz + (y + z) dz dx + x dz dy$

(5.7.1)

M3 >	A2 := evalDG(-2/(x^2 + y^2 + z^2)^2xdx &t dx - 1/(x^2 + y^2 + z^2)^2ydx &t dy - 1/(x^2 + y^2 + z^2)^2zdx &t dz - 1/(x^2 + y^2 + z^2)^2ydy &t dx - 1/(x^2 + y^2 + z^2)^2zdz &t dx);

$A2 ≔ - \frac{2 x dx dx}{{(x^{2} + y^{2} + z^{2})}^{2}} - \frac{y dx dy}{{(x^{2} + y^{2} + z^{2})}^{2}} - \frac{z dx dz}{{(x^{2} + y^{2} + z^{2})}^{2}} - \frac{y dy dx}{{(x^{2} + y^{2} + z^{2})}^{2}} - \frac{z dz dx}{{(x^{2} + y^{2} + z^{2})}^{2}}$

(5.7.2)

M3 >	ChangeFrame(M4):

M4 >	A3 := evalDG(1/2cos(x)sin(y)sin(z)dx &t dw + 1/2sin(x)cos(y)sin(z)dy &t dw + 1/2sin(x)sin(y)cos(z)dz &t dw + 1/2cos(x)sin(y)sin(z)dw &t dx + 1/2sin(x)cos(y)sin(z)dw &t dy + 1/2sin(x)sin(y)cos(z)dw &t dz);

$A3 ≔ \frac{1}{2} \cos (x) \sin (y) \sin (z) dx dw + \frac{1}{2} \sin (x) \cos (y) \sin (z) dy dw + \frac{1}{2} \sin (x) \sin (y) \cos (z) dz dw + \frac{1}{2} \cos (x) \sin (y) \sin (z) dw dx + \frac{1}{2} \sin (x) \cos (y) \sin (z) dw dy + \frac{1}{2} \sin (x) \sin (y) \cos (z) dw dz$

(5.7.3)

Hint: Here is a program which computes the right-hand side of (*).

M4 >	Delta:= (U,C) -> SymmetrizeIndices(CovariantDerivative(U, C), [1, 2], "Symmetric"):

Solution

M3 >	CheckIntegrability := proc(A, C)

M3 >

local T;

M3 >	T := CovariantDerivative(CovariantDerivative(A, C), C):

M3 >	SymmetrizeIndices(SymmetrizeIndices(T, [1, 3], "SkewSymmetric"), [2, 4], "SkewSymmetric");

M4 >

end:

M4 >

M3 >	Solve := proc(A, C)

M3 >	local Fr, n, B, Omega, T, i, j, alpha, beta, omega, theta, S, U;

M3 >	Fr := Tools:-DGinfo(A, "ObjectFrame");

M3 >	n := Tools:-DGinfo(Fr, "FrameBaseDimension");

M3 >	B := Tools:-DGinfo(Fr, "FrameBaseVectors");

M3 >	Omega := Tools:-DGinfo(Fr, "FrameBaseForms");

M3 >	T := CovariantDerivative(A, C);

M3 >	omega := Tools:-DGzero("form", 2);

M3 >	for i to n do for j to n do

M3 >	alpha := ContractIndices(B[i] &tensor B[j], T, [[1, 2], [2, 3]]) &minus ContractIndices(B[j] &tensor B[i], T, [[1, 2], [2, 3]]);

M3 >	beta := convert(alpha, DGform);

M3 >	theta := DeRhamHomotopy(beta, args[3 .. -1]);

M3 >	omega := omega &plus (theta &mult (Omega[i] &wedge Omega[j]));

M3 >

od;

M3 >

od;

M3 >	S := A &plus ((1/2) &mult (convert(omega, DGtensor)));

M3 >	U := Tools:-DGzero("form", 1);

M3 >	for i to n do

M3 >	alpha := ContractIndices(convert(B[i], DGtensor), S, [[1, 1]]);

M3 >	beta := convert(alpha, DGform);

M3 >	theta := DeRhamHomotopy(beta, args[3 .. -1]);

M3 >	U := U &plus (theta &mult (Omega[i]));

M3 >

od:

M3 >	convert(U, DGtensor):

M4 >

end:

Part [i]

M4 >	ChangeFrame(M3):

M3 >	C := Connection(0 &mult dx &t D_x &t dx);

$C ≔ 0 dx D_x dx$

(5.7.1.1)

M3 >	CheckIntegrability(A1, C);

$0 dx dx dx dx$

(5.7.1.2)

M3 >	U1 := Solve(A1, C);

$U1 ≔ z^{2} dx + 2 x y dz$

(5.7.1.3)

M3 >	A1 &minus Delta(U1, C);

$0 dx dx$

(5.7.1.4)

Part [ii]

M3 >	CheckIntegrability(A2, C);

$0 dx dx dx dx$

(5.7.1.5)

M3 >	U2 := Solve(A2, C, integrationlimits = [infinity, 1]);

$U2 ≔ \frac{dx}{x^{2} + y^{2} + z^{2}}$

(5.7.1.6)

M3 >	A2 &minus Delta(U2, C);

$0 dx dx$

(5.7.1.7)

Part [iii]

M3 >	ChangeFrame(M4):

M4 >	C := Connection(0 &mult dx &t D_x &t dx);

$C ≔ 0 dx D_x dx$

(5.7.1.8)

M4 >	U3 := Solve(A3, C);

$U3 ≔ (\frac{1}{4} \sin (- z + x + y) + \frac{1}{4} \sin (z + x - y) - \frac{1}{4} \sin (- z + x - y) - \frac{1}{4} \sin (z + x + y)) dw$

(5.7.1.9)

M4 >	U3 := map(expand, U3);

$U3 ≔ \sin (x) \sin (y) \sin (z) dw$

(5.7.1.10)

M4 >	A3 &minus Delta(U3, C);

$0 dx dx$

(5.7.1.11)

Exercise 8

Use the Maple pdsolve command to determine which of the following connections C1, C2, C3 are the Christoffel symbols of a metric.

M4 >	with(DifferentialGeometry): with(Tensor):

M4 >	DGsetup([x, y], E2);

$frame name: E2$

(5.8.1)

E2 >	C1 := Connection(x*dx &t D_y &t dx);

$C1 ≔ x dx D_y dx$

(5.8.2)

E2 >	C2 := Connection(y^2*dx &t D_y &t dx);

$C2 ≔ y^{2} dx D_y dx$

(5.8.3)

E2 >	DGsetup([x, y, z], E3);

$frame name: E3$

(5.8.4)

E3 >	C3 := Connection((-1/x)dx &t D_x &t dx - (1/2/x)dx &t D_y &t dy - (1/2/z)dy &t D_x &t dy - (1/2/x)dy &t D_y &t dx - (1/2/z)dy &t D_y &t dz - (1/2/x)dy &t D_z &t dy - (1/2/z)dz &t D_y &t dy - (1/z)dz &t D_z &t dz);

$C3 ≔ - \frac{dx D_x dx}{x} - \frac{dx D_y dy}{2 x} - \frac{dy D_x dy}{2 z} - \frac{dy D_y dx}{2 x} - \frac{dy D_y dz}{2 z} - \frac{dy D_z dy}{2 x} - \frac{dz D_y dy}{2 z} - \frac{dz D_z dz}{z}$

(5.8.5)

Solution

E3 >	PDEtools:-declare([a, b, c](x, y), quiet);

E3 >	ChangeFrame(E2):

E2 >	g := evalDG(a(x, y)dx &t dx + 2b(x, y)dx &s dy + c(x, y)dy &t dy);

$g ≔ a dx dx + 2 b dx dy + 2 b dy dx + c dy dy$

(5.8.1.1)

Part 1.

E2 >	k1 := CovariantDerivative(g, C1);

$k1 ≔ (- 4 x b + a_{x}) dx dx dx + a_{y} dx dx dy + (- x c + 2 b_{x}) dx dy dx + 2 b_{y} dx dy dy + (- x c + 2 b_{x}) dy dx dx + 2 b_{y} dy dx dy + c_{x} dy dy dx + c_{y} dy dy dy$

(5.8.1.2)

E2 >	Eq1 := Tools:-DGinfo(k1, "CoefficientSet");

$Eq1 ≔ \{a_{y}, c_{x}, c_{y}, 2 b_{y}, - 4 x b + a_{x}, - x c + 2 b_{x}\}$

(5.8.1.3)

E2 >	soln1 := pdsolve(Eq1);

$soln1 ≔ \{a = \frac{_C1 x^{4}}{4} + \frac{_C2 x^{2}}{2} +_C3, b = \frac{x^{2}_C1}{4} + \frac{_C2}{4}, c =_C1\}$

(5.8.1.4)

E2 >	g1 := eval(g, soln1);

$g1 ≔ (\frac{_C1 x^{4}}{4} + \frac{_C2 x^{2}}{2} +_C3) dx dx + (\frac{x^{2}_C1}{2} + \frac{_C2}{2}) dx dy + (\frac{x^{2}_C1}{2} + \frac{_C2}{2}) dy dx +_C1 dy dy$

(5.8.1.5)

E2 >	Christoffel(g1);

$x dx D_y dx$

(5.8.1.6)

Part 2.

E2 >	k2 := CovariantDerivative(g, C2);

$k2 ≔ (- 4 y^{2} b + a_{x}) dx dx dx + a_{y} dx dx dy + (- y^{2} c + 2 b_{x}) dx dy dx + 2 b_{y} dx dy dy + (- y^{2} c + 2 b_{x}) dy dx dx + 2 b_{y} dy dx dy + c_{x} dy dy dx + c_{y} dy dy dy$

(5.8.1.7)

E2 >	Eq2 := Tools:-DGinfo(k2, "CoefficientSet");

$Eq2 ≔ \{a_{y}, c_{x}, c_{y}, 2 b_{y}, - 4 y^{2} b + a_{x}, - y^{2} c + 2 b_{x}\}$

(5.8.1.8)

E2 >	soln2 := pdsolve(Eq2);

$soln2 ≔ \{a =_C1, b = 0, c = 0\}$

(5.8.1.9)

E2 >	Tools:-DGsimplify(eval(g, soln2));

$_C1 dx dx$

(5.8.1.10)

The metric is degenerate so that C2 is not a metric connection.

Part 3.

E2 >	vars := [seq(a\|\|i, i = 1 .. 6)](x, y, z):

E2 >	PDEtools:-declare(vars, quiet);

E2 >	ChangeFrame(E3):

E3 >	S := GenerateSymmetricTensors([dx, dy, dz], 2);

$S ≔ [dx dx, \frac{dx dy}{2} + \frac{dy dx}{2}, \frac{dx dz}{2} + \frac{dz dx}{2}, dy dy, \frac{dy dz}{2} + \frac{dz dy}{2}, dz dz]$

(5.8.1.11)

E3 >	g := DGzip(vars, S, "plus");

$g ≔ a1 dx dx + \frac{a2 dx dy}{2} + \frac{a3 dx dz}{2} + \frac{a2 dy dx}{2} + a4 dy dy + \frac{a5 dy dz}{2} + \frac{a3 dz dx}{2} + \frac{a5 dz dy}{2} + a6 dz dz$

(5.8.1.12)

E3 >	k3 := CovariantDerivative(g, C3);

$k3 ≔ \frac{1}{2} \frac{(a5 + 2 {a6}_{y} z) dz dz dy}{z} + \frac{(a4 + {a4}_{x} x) dy dy dx}{x} + \frac{1}{4} \frac{(2 a6 z + 2 x a4 + x a3 + 2 x {a5}_{y} z) dy dz dy}{x z} + \frac{(2 a6 + {a6}_{z} z) dz dz dz}{z} + \frac{1}{4} \frac{(3 a5 + 2 {a5}_{z} z) dy dz dz}{z} + \frac{1}{4} \frac{(a2 x + z a5 + 2 z {a3}_{y} x) dx dz dy}{x z} + \frac{1}{4} \frac{(3 a2 + 2 {a2}_{x} x) dx dy dx}{x} + \frac{1}{2} \frac{(z a5 + a2 x + 2 x {a4}_{y} z) dy dy dy}{x z} + \frac{1}{2} \frac{(a3 + {a3}_{x} x) dz dx dx}{x} + \frac{1}{4} \frac{(a3 z + 2 a4 z + 2 x a1 + 2 x {a2}_{y} z) dx dy dy}{x z} + \frac{1}{4} \frac{(a2 x + z a5 + 2 z {a3}_{y} x) dz dx dy}{x z} + \frac{1}{2} \frac{(a3 + {a3}_{z} z) dx dz dz}{z} + \frac{1}{2} \frac{(a3 + {a3}_{z} z) dz dx dz}{z} + \frac{(a4 + {a4}_{z} z) dy dy dz}{z} + {a6}_{x} dz dz dx + \frac{1}{4} \frac{(a5 + 2 {a5}_{x} x) dz dy dx}{x} + \frac{1}{4} \frac{(3 a2 + 2 {a2}_{x} x) dy dx dx}{x} + \frac{1}{4} \frac{(a2 + 2 {a2}_{z} z) dx dy dz}{z} + \frac{1}{4} \frac{(a5 + 2 {a5}_{x} x) dy dz dx}{x} + \frac{(2 a1 + {a1}_{x} x) dx dx dx}{x} + \frac{1}{4} \frac{(2 a6 z + 2 x a4 + x a3 + 2 x {a5}_{y} z) dz dy dy}{x z} + \frac{1}{4} \frac{(3 a5 + 2 {a5}_{z} z) dz dy dz}{z} + \frac{1}{2} \frac{(a2 + 2 {a1}_{y} x) dx dx dy}{x} + \frac{1}{2} \frac{(a3 + {a3}_{x} x) dx dz dx}{x} + \frac{1}{4} \frac{(a3 z + 2 a4 z + 2 x a1 + 2 x {a2}_{y} z) dy dx dy}{x z} + \frac{1}{4} \frac{(a2 + 2 {a2}_{z} z) dy dx dz}{z} + {a1}_{z} dx dx dz$

(5.8.1.13)

$Eq1 ≔ \{- x c + 2 b_{x}, - 4 x b + a_{x}, a_{y}, 2 b_{y}, c_{x}, c_{y}\}$

(5.8.1.14)

E3 >	Eq3 := Tools:-DGinfo(k3, "CoefficientSet");

$Eq3 ≔ \{{a1}_{z}, {a6}_{x}, \frac{2 a1 + {a1}_{x} x}{x}, \frac{a4 + {a4}_{x} x}{x}, \frac{a4 + {a4}_{z} z}{z}, \frac{2 a6 + {a6}_{z} z}{z}, \frac{1}{2} \frac{a2 + 2 {a1}_{y} x}{x}, \frac{1}{4} \frac{a2 + 2 {a2}_{z} z}{z}, \frac{1}{4} \frac{3 a2 + 2 {a2}_{x} x}{x}, \frac{1}{2} \frac{a3 + {a3}_{x} x}{x}, \frac{1}{2} \frac{a3 + {a3}_{z} z}{z}, \frac{1}{4} \frac{a5 + 2 {a5}_{x} x}{x}, \frac{1}{2} \frac{a5 + 2 {a6}_{y} z}{z}, \frac{1}{4} \frac{3 a5 + 2 {a5}_{z} z}{z}, \frac{1}{4} \frac{a2 x + z a5 + 2 z {a3}_{y} x}{x z}, \frac{1}{2} \frac{z a5 + a2 x + 2 x {a4}_{y} z}{x z}, \frac{1}{4} \frac{a3 z + 2 a4 z + 2 x a1 + 2 x {a2}_{y} z}{x z}, \frac{1}{4} \frac{2 a6 z + 2 x a4 + x a3 + 2 x {a5}_{y} z}{x z}\}$

(5.8.1.15)

E3 >	soln3 := pdsolve(Eq3);

$soln3 ≔ \{a1 = \frac{_C1}{x^{2}}, a2 = 0, a3 = \frac{_C2}{z x}, a4 = \frac{-_C2 - 2_C1}{2 x z}, a5 = 0, a6 = \frac{_C1}{z^{2}}\}$

(5.8.1.16)

E3 >	g3 := Tools:-DGsimplify(eval(g, soln3));

$g3 ≔ \frac{_C1 dx dx}{x^{2}} + \frac{_C2 dx dz}{2 z x} - \frac{(_C2 + 2_C1) dy dy}{2 x z} + \frac{_C2 dz dx}{2 z x} + \frac{_C1 dz dz}{z^{2}}$

(5.8.1.17)

E3 >	Christoffel(g3);

$- \frac{dx D_x dx}{x} - \frac{dx D_y dy}{2 x} - \frac{dy D_x dy}{2 z} - \frac{dy D_y dx}{2 x} - \frac{dy D_y dz}{2 z} - \frac{dy D_z dy}{2 x} - \frac{dz D_y dy}{2 z} - \frac{dz D_z dz}{z}$

(5.8.1.18)

Exercise 9

Check that the metric g is conformally flat. Use pdsolve to find a function sigma such that sigma*g is flat.

M >	with(DifferentialGeometry): with(Tensor):

M >	DGsetup([x, y, z, w], M):

M >	g := evalDG(dx &t dy + exp(-y)(dx &s dz) + dy &t dx - dy &t dz - dz &t dy + 1/4exp(y)*dw &t dw);

$g ≔ dx dy + {&ExponentialE;}^{- y} dx dz + dy dx - dy dz + {&ExponentialE;}^{- y} dz dx - dz dy + \frac{1}{4} {&ExponentialE;}^{y} dw dw$

(5.9.1)

Solution

M >	with(Tools):

M >	C := Christoffel(g):

M >	R := CurvatureTensor(C):

M >	DGinfo(R, "CoefficientList", [dx &t D_y &t dy &t dz]);

$[\frac{1}{8}]$

(5.9.1.1)

M >	WeylTensor(g, R);

$0 dx dx dx dx$

(5.9.1.2)

M >	PDEtools:-declare(sigma(x, y, z, w));

$σ (x, y, z, w) will now be displayed as σ$

(5.9.1.3)

M >	k := sigma(x, y, z, w) &mult g;

$k ≔ σ dx dy + σ {&ExponentialE;}^{- y} dx dz + σ dy dx - σ dy dz + σ {&ExponentialE;}^{- y} dz dx - σ dz dy + \frac{1}{4} σ {&ExponentialE;}^{y} dw dw$

(5.9.1.4)

M >	C := Christoffel(k):

M >	R := CurvatureTensor(C):

M >	Eq := simplify(DGinfo(R, "CoefficientSet")):

M >

nops(Eq);

$114$

(5.9.1.5)

M >	soln := pdsolve(Eq);

$soln ≔ \{σ = \frac{4}{{(- {&ExponentialE;}^{\frac{y}{2}} \sqrt{2} \tan (\frac{(- w +_C5) \sqrt{2}}{4}) \sqrt{\frac{- 2_C1_C3 + 2_C2_C4}{1 + {\tan (\frac{(- w +_C5) \sqrt{2}}{4})}^{2}}} + (x z_C2 +_C1 x - z {&ExponentialE;}^{y}_C2 + z_C3 +_C4) {&ExponentialE;}^{- \frac{y}{2}} + {&ExponentialE;}^{\frac{y}{2}} (_C2 x -_C1 +_C3))}^{2}}\}$

(5.9.1.6)

M >	pdetest(sigma(x, y, z, w) = exp(y), Eq);

$\{0\}$

(5.9.1.7)

M >	gFlat := eval(k, sigma(x, y, z, w) = exp(y));

$gFlat ≔ {&ExponentialE;}^{y} dx dy + {&ExponentialE;}^{- y} {&ExponentialE;}^{y} dx dz + {&ExponentialE;}^{y} dy dx - {&ExponentialE;}^{y} dy dz + {&ExponentialE;}^{- y} {&ExponentialE;}^{y} dz dx - {&ExponentialE;}^{y} dz dy + \frac{1}{4} {({&ExponentialE;}^{y})}^{2} dw dw$

(5.9.1.8)

M >	C := Christoffel(gFlat);

$C ≔ dy D_y dy + dy D_w dw - \frac{1}{8} {&ExponentialE;}^{y} dw D_x dw - \frac{dw D_y dw}{8} + \frac{1}{8} {&ExponentialE;}^{y} dw D_z dw + dw D_w dy$

(5.9.1.9)

M >	CurvatureTensor(C);

$0 D_x dx dx dx$

(5.9.1.10)

M >

Download Help Document

Maple

Erweiterungen für Maple

Student Success Platform

Verbesserung der Studienerfolgsquote

MapleSim

Erweiterungen für MapleSim

Systementwicklung

Beratende Dienstleistungen

Produkte zur Online-Ausbildung

Ausbildung

Industrie

Automobil und Luftfahrt

Robotik

Maschinendesign & industrielle Automation

Andere

Lösungen für die Industrie

Kaufen: Einzelheiten und Preise

Kaufen

Institutionelle Studentenlizenzierung

Elite-Wartungsprogramm

Support

Produktschulung

Online Hilfe zu Produkten

Webinare und Veranstaltungen

Veröffentlichungen

Content Hubs

Anwendungsbeispiele

Community

Über Maplesoft

Pressezentrum

User Community

Kontakt

Online Help

All Products Maple MapleSim

Maple

Leistungsfähige intuitive Mathematiksoftware

Erweiterungen für Maple

Student Success Platform

Verbesserung der Studienerfolgsquote

MapleSim

Modellierung auf Systemebene

Erweiterungen für MapleSim

Systementwicklung

Beratende Dienstleistungen

Produkte zur Online-Ausbildung

Ausbildung

Industrie

Automobil und Luftfahrt

Robotik

Maschinendesign & industrielle Automation

Andere

Lösungen für die Industrie

Kaufen: Einzelheiten und Preise

Kaufen

Institutionelle Studentenlizenzierung

Elite-Wartungsprogramm

Support

Produktschulung

Online Hilfe zu Produkten

Webinare und Veranstaltungen

Veröffentlichungen

Content Hubs

Anwendungsbeispiele

Community

Über Maplesoft

Pressezentrum

User Community

Kontakt

Online Help

All Products Maple MapleSim