boundary conditions - Maple Help

All Products Maple MapleSim

Home : Support : Online Help : Mathematics : Differential Equations : pdsolve : boundary conditions

pdsolve/boundaryconditions

find solutions for partial differential equations (PDEs) with boundary and/or initial conditions

	Calling Sequence
	pdsolve([PDE, conds], f, hint)

Parameters

PDE	-	a partial differential equation or system thereof
conds	-	initial or boundary conditions
f	-	indeterminate function or its name; or a set or list of them, required when there is more than one differentiated function
hint	-	(optional): HINT = `+`, HINT = `*`, HINT = boundedseries, HINT = boundedseries(variable = value), HINT = boundedseries(variable = [values])
method	-	(optional): method = method1, method = [method1, method2, ...], exclude = method1, exclude = [method1, method2, ...]
option	-	(optional): degree = positive integer

Description

•

Given one or more PDE with boundary and/or initial conditions, pdsolve works to find an analytical solution satisfying all of the given equations and conditions. There are no restrictions as to the type, differential order, or number of dependent or independent variables of the PDEs or PDE systems that pdsolve can try to solve, although the solving methods are limited in scope.

•	Several solution methods are used, depending on the order of the PDE, on whether they are linear, on the domain for the variables of the problem, and on whether the PDE or the boundary conditions, or both, are homogeneous.

•	Changes of variables in PDE and conditions are used as necessary in order to make problems solvable by pdsolve.

•	To see what method is being used to solve a given problem, you can assign the following (see infolevel):

>	$infolevel [pdsolve] ≔ 2 &colon;$

•

The solving methods can be indicated, either to be used for solving, as in $methods = [method__1, method__2, .. &period;]$ , to be tried in the order indicated, or to be excluded, as in $exclude = [method__1, method__2, .. &period;]$ . The methods and sub-methods available are organized in a table, $`pdsolve/BC/methods` &colon;$

>	$indices (`pdsolve/BC/methods`)$

$[1], [2], [3], [2, Series], [2, Wave], [high_order], [system], [2, Heat], [2, SpecializeArbitraryFunctions]$

(1)

So, for example, the methods for PDEs of first order and second order are, respectively,

>	$`pdsolve/BC/methods` [1]$

$[SpecializeArbitraryFunctions, Fourier, Laplace, Generic, PolynomialSolutions, LinearDifferentialOperator]$

(2)

>	$`pdsolve/BC/methods` [2]$

$[SpecializeArbitraryFunctions, SpecializeArbitraryConstants, Wave, Heat, Series, Laplace, Fourier, Generic, PolynomialSolutions, LinearDifferentialOperator, Superposition]$

(3)

Some methods have sub-methods:

>	$`pdsolve/BC/methods` [2, Series]$

$[TwoBC, ThreeBCsincos, FourBC, ThreeBC, ThreeBCPeriodic, WithSourceTerm, ThreeVariables]$

(4)

>	$`pdsolve/BC/methods` [2, Heat]$

$[SemiInfiniteDomain, WithSourceTerm]$

(5)

About the Arguments

•	When the given PDE contains derivatives of more than one function, the function(s) which should be considered the indeterminate function(s), or its name, must be given as an extra argument.

•	The PDE (or system thereof) and boundary and/or initial conditions should all be given together as a list.

•	You can give a HINT indicating a method of solution or a form for the indeterminate function. When given, the hint is taken by pdsolve as the departure point in looking for the solution.

•	The following arguments can be used with the HINT option.

HINT = `+`

This option forces pdsolve to begin by trying to separate the variables by sum.

HINT = `*`

This option forces pdsolve to begin by trying to separate the variables by product.

HINT = boundedseries

This option tells pdsolve that the solution is bounded (pdsolve will choose an appropriate boundary).

HINT = boundedseries(variable = value), HINT = boundedseries(variable = [values])

This option tells pdsolve that the solution is bounded (using the given value(s) for the given variable).

•	You can specify one or more solving methods to be used or not used (excluded), from: Laplace, Fourier, Series, Generic, PolynomialSolutions, LinearDifferentialOperator, Wave, Heat, Superposition, SpecializeArbitraryFunctions, SpecializeArbitraryConstants.

•	When using the method PolynomialSolutions, a degree can be specified for the solution. Note that for linear PDE, the maximum degree used by pdsolve by default is 10; for nonlinear PDE, it is 4. You can override these default values by using the degree =... option.

Conventions

•	Any arbitrary constants introduced during the solution process are represented as ${_C}_{1}$ , ${_C}_{2}$ ,..., and are global.

•	Any functions introduced by pdsolve beginning with $_F$ and followed by a number are assumed to be arbitrary, sufficiently differentiable functions of their arguments.

•	When pdsolve fails, it returns NULL.

Examples

The following illustrate some of the strategies and solution methods used by pdsolve to solve problems involving PDE with boundary conditions, initial conditions, or both. The HINT and method = ... options are illustrated in several different examples below. Click on the arrow to the left of each section name to view the examples for that section.

Linear change of variables

PDE and BC problems often require that the boundary and initial conditions be given at certain evaluation points (usually in which one of the variables is equal to zero). With linear changes of variables, it is possible to change the evaluation points of the given conditions, obtaining the solution for the new variables, and then changing back to the original variables.

An example of a heat PDE & BC problem in a semi-infinite domain. Note the conditions are at $x = A$ and $t = B$ .

>	$pde__1 ≔ diff (u (x, t), t) = \frac{diff (u (x, t), x, x)}{4}$

$pde__1 ≔ \frac{\partial}{\partial t} u (x, t) = \frac{\frac{\partial^{2}}{\partial x^{2}} u (x, t)}{4}$

(6)

>	$conds__1 ≔ u (A, t) = 0, u (x, B) = 10 &colon;$

Note the assumptions placed below; depending on the problem, they may be required for it to be solvable. In this case, the assumptions are that x and t are, respectively, greater than the absolute value of the evaluation points of the conditions, in this case A and B.

>	$pdsolve ([pde__1, conds__1]) assuming abs (A) < x, abs (B) < t$

$u (x, t) = - 10 \erf (\frac{- x + A}{\sqrt{t - B}})$

(7)

A wave PDE with a source. Note that the conditions are at $t = 1$ .

>	$pde__2 ≔ diff (u (x, t), t, t) - c^{2} \cdot diff (u (x, t), x, x) = f (x, t)$

$pde__2 ≔ \frac{\partial^{2}}{\partial t^{2}} u (x, t) - c^{2} (\frac{\partial^{2}}{\partial x^{2}} u (x, t)) = f (x, t)$

(8)

>	$conds__2 ≔ u (x, 1) = g (x), D_{2} (u) (x, 1) = h (x) &colon;$

>	$pdsolve ([pde__2, conds__2], u (x, t))$

$u (x, t) = \frac{\int_{0}^{t - 1} \int_{(- t + τ + 1) c + x}^{x + c (t - 1 - τ)} ((\frac{{&DifferentialD;}^{2}}{&DifferentialD; ζ^{2}} h (ζ)) c^{2} τ + (\frac{{&DifferentialD;}^{2}}{&DifferentialD; ζ^{2}} g (ζ)) c^{2} + f (ζ, τ + 1)) &DifferentialD; ζ &DifferentialD; τ + (2 t - 2) c h (x) + 2 g (x) c}{2 c}$

(9)

You can ask pdetest to test the solution against the original problem, if desired:

>	$pdetest (, [pde__2, conds__2])$

$[0, 0, 0]$

(10)

Fourier Series method

This method, for single linear second-order PDEs in two or three independent variables, uses separation of variables by product to identify one or two Sturm-Liouville problems, depending on the number of variables. These problems are solved by finding eigenvalues with corresponding eigenfunctions, by using orthogonality properties of these eigenfunctions, and by then superimposing solutions (since the PDE is linear) to create an infinite series.

An example with the Schrodinger PDE with zero potential (Planck's constant, Z, is entered from the palettes):

>	$pde__3 ≔ I \cdot &hslash; \cdot diff (f (x, t), t) = - \frac{{&hslash;}^{2}}{2 m} \cdot diff (f (x, t), x, x)$

$pde__3 ≔ I ℏ (\frac{\partial}{\partial t} f (x, t)) = - \frac{ℏ^{2} (\frac{\partial^{2}}{\partial x^{2}} f (x, t))}{2 m}$

(11)

>	$conds__3 ≔ f (0, t) = 0, f (L, t) = 0 &colon;$

>	$pdsolve ([pde__3, conds__3], f (x, t)) assuming L > 0$

$f (x, t) = \sum_{n = 1}^{\infty}_C1 (n) \sin (\frac{n π x}{L}) {&ExponentialE;}^{\frac{- \frac{I}{2} ℏ π^{2} n^{2} t}{m L^{2}}}$

(12)

An example with the wave PDE:

>	$pde__4 ≔ diff (u (x, t), t, t) = c^{2} diff (u (x, t), x, x)$

$pde__4 ≔ \frac{\partial^{2}}{\partial t^{2}} u (x, t) = c^{2} (\frac{\partial^{2}}{\partial x^{2}} u (x, t))$

(13)

>	$conds__4 ≔ u (0, t) = 0, D [1] (u) (L, t) = 0, D [2] (u) (x, 0) = 0, u (x, 0) = f (x) &colon;$

>	$pdsolve ([pde__4, conds__4], u (x, t)) assuming 0 < x \leq L$

$u (x, t) = \sum_{n = 0}^{\infty} \frac{2 \sin (\frac{(1 + 2 n) π x}{2 L}) \cos (\frac{c (1 + 2 n) π t}{2 L}) (\int_{0}^{L} \sin (\frac{(1 + 2 n) π x}{2 L}) f (x) &DifferentialD; x)}{L}$

(14)

An example that represents the temperature distribution in a thin circular plate whose lateral surfaces are insulated:

>	$pde__5 ≔ diff (u (r, theta, t), t) = \frac{1}{25 r} (diff (u (r, theta, t), r) + r diff (u (r, theta, t), r, r) + \frac{diff (u (r, theta, t), theta, theta)}{r})$

$pde__5 ≔ \frac{\partial}{\partial t} u (r, θ, t) = \frac{\frac{\partial}{\partial r} u (r, θ, t) + r (\frac{\partial^{2}}{\partial r^{2}} u (r, θ, t)) + \frac{\frac{\partial^{2}}{\partial θ^{2}} u (r, θ, t)}{r}}{25 r}$

(15)

>	$conds__5 ≔ D_{1} (u) (1, θ, t) = 0, u (r, 0, t) = 0, u (r, π, t) = 0, u (r, θ, 0) = (r - \frac{1}{3} r^{3}) \sin (θ) &colon;$

>	$pdsolve ([pde__5, conds__5])$

$u (r, θ, t) = casesplit/ans (Sum (- \frac{4}{3} \frac{BesselJ (1, λ_{n} r) \sin (θ) \exp (- \frac{1}{25} λ_{n}^{2} t) (BesselJ (0, λ_{n}) λ_{n}^{3} - BesselJ (1, λ_{n}) λ_{n}^{2} + 4 λ_{n} BesselJ (0, λ_{n}) - 8 BesselJ (1, λ_{n}))}{λ_{n}^{3} ({BesselJ (0, λ_{n})}^{2} λ_{n} + {BesselJ (1, λ_{n})}^{2} λ_{n} - 2 BesselJ (0, λ_{n}) BesselJ (1, λ_{n}))}, n = 0 .. \infty), \{And (- BesselJ (1, λ_{n}) + BesselJ (2, λ_{n}) λ_{n} = 0, 0 < λ_{n})\})$

(16)

In the above we see that the eigenvalue $λ__n$ satisfies $- J_{1} (λ_{n}) + J_{2} (λ_{n}) λ_{n} = 0$ . When $λ__n$ is the root of one single BesselJ or BesselY function of integer order, the Maple functions BesselJZeros and BesselYZeros are used instead. That is the case, for instance, if we slightly modify this problem changing the first boundary condition to be $u (1, θ, t) = 0$ instead of $D_{1} (u) (1, θ, t) = 0$

>	$conds__5.1 ≔ u (1, θ, t) = 0, u (r, 0, t) = 0, u (r, π, t) = 0, u (r, θ, 0) = (r - \frac{1}{3} r^{3}) \sin (θ) &colon;$

>	$pdsolve ([pde__5, conds__5.1])$

$u (r, θ, t) = casesplit/ans (Sum (- \frac{4}{3} \frac{BesselJ (1, λ_{n} r) \sin (θ) \exp (- \frac{1}{25} λ_{n}^{2} t) (λ_{n}^{2} + 4)}{BesselJ (0, λ_{n}) λ_{n}^{3}}, n = 1 .. \infty), \{And (λ_{n} = BesselJZeros (1, n), 0 < λ_{n})\})$

(17)

An example with the Laplace PDE, requesting a solution outside a disk of radius one via HINT = boundedseries(r = infinity):

>	$pde__6 ≔ \frac{diff (r \cdot diff (u (r, θ), r), r)}{r} + \frac{diff (u (r, θ), θ, θ)}{r^{2}} = 0$

$pde__6 ≔ \frac{\frac{\partial}{\partial r} u (r, θ) + r (\frac{\partial^{2}}{\partial r^{2}} u (r, θ))}{r} + \frac{\frac{\partial^{2}}{\partial θ^{2}} u (r, θ)}{r^{2}} = 0$

(18)

>	$conds__6 ≔ u (1, θ) = f (θ), u (r, - π) = u (r, π), D_{2} (u) (r, - π) = D_{2} (u) (r, π) &colon;$

>	$pdsolve ([pde__6, conds__6], u (r, theta), HINT = boundedseries (r = infinity))$

$u (r, θ) = \frac{2 (\sum_{n = 1}^{\infty} \frac{((\int_{- π}^{π} f (θ) \sin (n θ) &DifferentialD; θ) \sin (n θ) + (\int_{- π}^{π} f (θ) \cos (n θ) &DifferentialD; θ) \cos (n θ)) r^{- n}}{π}) π + \int_{- π}^{π} f (θ) &DifferentialD; θ}{2 π}$

(19)

To obtain the solution inside the disk of radius one, we use HINT = boundedseries(r = 0):

>	$pdsolve ([pde__6, conds__6], u (r, theta), HINT = boundedseries (r = 0))$

$u (r, θ) = \frac{2 (\sum_{n = 1}^{\infty} \frac{r^{n} ((\int_{- π}^{π} f (θ) \sin (n θ) &DifferentialD; θ) \sin (n θ) + (\int_{- π}^{π} f (θ) \cos (n θ) &DifferentialD; θ) \cos (n θ))}{π}) π + \int_{- π}^{π} f (θ) &DifferentialD; θ}{2 π}$

(20)

Generic method

Here, pdsolve first calculates the PDE's general solution, and then works to fit any initial or boundary conditions to it. Both examples below also illustrate that the method chosen can make a difference in the solution pdsolve returns:

>	$pde__7 ≔ diff (u (x, y), x, x) + diff (u (x, y), y, y) = 0$

$pde__7 ≔ \frac{\partial^{2}}{\partial x^{2}} u (x, y) + \frac{\partial^{2}}{\partial y^{2}} u (x, y) = 0$

(21)

>	$conds__7 ≔ u (x, 0) = Dirac (x) &colon;$

When the Fourier method is specified, pdsolve returns:

>	$pdsolve ([pde__7, conds__7], method = Fourier)$

$u (x, y) = invfourier ({&ExponentialE;}^{- s y}, s, x)$

(22)

which we can convert to integral form:

>	$convert (, Int) &semi;$

$u (x, y) = \frac{\int_{- \infty}^{\infty} {&ExponentialE;}^{- s y + I s x} &DifferentialD; s}{2 π}$

(23)

When method = Generic is specified, pdsolve's solution includes an arbitrary function _F2:

>	$pdsolve ([pde__7, conds__7], method = Generic)$

$u (x, y) = -_F2 (- y + I x) + δ (x + I y) +_F2 (y + I x)$

(24)

Here is another example in which the method that is chosen makes a difference in the solution obtained:

>	$pde__8 ≔ diff (u (r, θ), r, r) + diff (u (r, θ), θ, θ) = 0$

$pde__8 ≔ \frac{\partial^{2}}{\partial r^{2}} u (r, θ) + \frac{\partial^{2}}{\partial θ^{2}} u (r, θ) = 0$

(25)

>	$conds__8 ≔ u (2, θ) = 3 \sin (2 θ) + 1 &colon;$

With method = Generic, pdsolve returns:

>	$pdsolve ([pde__8, conds__8], method = Generic)$

$u (r, θ) = 1 -_F2 (θ - I r + 4 I) - 3 \sin (- 2 θ + 2 I r - 4 I) +_F2 (θ + I r)$

(26)

With method = Fourier, pdsolve uses a Fourier transform to obtain:

>	$pdsolve ([pde__8, conds__8], method = Fourier)$

$u (r, θ) = \frac{3 I {&ExponentialE;}^{2 r - 4 - 2 I θ}}{2} - \frac{3 I {&ExponentialE;}^{- 2 r + 4 + 2 I θ}}{2} + 1$

(27)

Integral Transforms (Laplace method, Fourier method)

Integral Transforms are used in infinite or semi-infinite spatial domain problems.

Laplace transforms act to change derivatives with respect to one of the independent variables of the domain into multiplication operations in the transformed domain. After applying a Laplace transform to the original problem, we can simplify the problem using the transformed BC, then solve the problem in the transformed domain, and finally apply the inverse Laplace transform to arrive at the final solution. It is important to remember to give pdsolve any necessary restrictions on the variables and constants of the problem, by means of the assuming command.

We can also tell pdsolve that the dependent variable is bounded, by means of the optional argument HINT = boundedseries.

Consider the problem of a falling cable lying on a table that is suddenly removed.

>	$pde__9 ≔ diff (u (x, t), t, t) = c^{2} \cdot diff (u (x, t), x, x) - g$

$pde__9 ≔ \frac{\partial^{2}}{\partial t^{2}} u (x, t) = c^{2} (\frac{\partial^{2}}{\partial x^{2}} u (x, t)) - g$

(28)

>	$conds__9 ≔ u (x, 0) = 0, u (0, t) = 0, D [2] (u) (x, 0) = 0 &colon;$

To display special functions using textbook notation, enable the typesetting of mathematical functions:

>	$Typesetting :- EnableTypesetRule (Typesetting :- SpecialFunctionRules) &colon;$

If we ask pdsolve to solve this problem without the condition of boundedness of the solution, we obtain:

>	$pdsolve ([pde__9, conds__9], u (x, t)) assuming 0 < t, 0 < x, 0 < c$

$u (x, t) = - \frac{g (- x^{2} + (\{\begin{array}{c} 2 c t x & x < c t \\ c^{2} t^{2} + x^{2} & c t < x \end{array}))}{2 c^{2}}$

(29)

If we now ask for a bounded solution, by means of the option HINT = boundedseries, pdsolve simplifies the problem accordingly.

>	$pdsolve ([pde__9, conds__9], HINT = boundedseries) assuming 0 < t, 0 < x, 0 < c$

$u (x, t) = \frac{g (θ (t - \frac{x}{c}) {(c t - x)}^{2} - c^{2} t^{2})}{2 c^{2}}$

(30)

For Fourier transforms, the process is similar to that used in the Laplace transform method.

>	$pde__10 ≔ diff (u (x, t), t) = diff (u (x, t), x, x) + m$

$pde__10 ≔ \frac{\partial}{\partial t} u (x, t) = \frac{\partial^{2}}{\partial x^{2}} u (x, t) + m$

(31)

>	$conds__10 ≔ u (x, 0) = \sin (x) &colon;$

>	$pdsolve ([pde__10, conds__10])$

$u (x, t) = \sin (x) {&ExponentialE;}^{- t} + m t$

(32)

A third order PDE problem:

>	$pde__11 ≔ diff (u (x, t), t) = - diff (u (x, t), x, x, x)$

$pde__11 ≔ \frac{\partial}{\partial t} u (x, t) = - \frac{\partial^{3}}{\partial x^{3}} u (x, t)$

(33)

>	$conds__11 ≔ u (x, 0) = f (x) &colon;$

>	$pdsolve ([pde__11, conds__11])$

$u (x, t) = \frac{\int_{- \infty}^{\infty} \frac{4 π f (- ζ) \sqrt{- \frac{x + ζ}{{(- t)}^{\frac{1}{3}}}} K_{\frac{1}{3}} (- \frac{2 \sqrt{3} (x + ζ) \sqrt{- \frac{x + ζ}{{(- t)}^{\frac{1}{3}}}}}{9 {(- t)}^{\frac{1}{3}}})}{3 {(- t)}^{\frac{1}{3}}} &DifferentialD; ζ}{4 π^{2}}$

(34)

Linear Differential Operator method

This method is for problems of the form

$\frac{\partial}{\partial t} w = M_{w}, w (x__i, 0) = f (x__i)$

$\frac{\partial^{2}}{\partial t^{2}} w = M_{w}, w (x__i, 0) = f (x__i), \binom{(\frac{\partial}{\partial t} w)}{} | \binom{}{t = 0} = g (x__i)$

where M is an arbitrary linear differential operator of any order which only depends on the spatial variables $(x__i)$ .

>	$pde__12 ≔ diff (w (x1, x2, x3, t), t, t) = diff (w (x1, x2, x3, t), x2, x1) + diff (w (x1, x2, x3, t), x3, x1) + diff (w (x1, x2, x3, t), x3, x3) - diff (w (x1, x2, x3, t), x3, x2)$

$pde__12 ≔ \frac{\partial^{2}}{\partial t^{2}} w (x1, x2, x3, t) = \frac{\partial^{2}}{\partial x1 \partial x2} w (x1, x2, x3, t) + \frac{\partial^{2}}{\partial x1 \partial x3} w (x1, x2, x3, t) + \frac{\partial^{2}}{\partial {x3}^{2}} w (x1, x2, x3, t) - \frac{\partial^{2}}{\partial x2 \partial x3} w (x1, x2, x3, t)$

(35)

>	$conds__12 ≔ w (x1, x2, x3, 0) = {x1}^{3} \cdot {x3}^{2} + \sin (x1), D [4] (w) (x1, x2, x3, 0) = \cos (x1) - x2 \cdot x3 &colon;$

>	$pdsolve ([pde__12, conds__12])$

$w (x1, x2, x3, t) = \frac{t^{4} x1}{2} + t^{2} {x1}^{3} + 3 t^{2} {x1}^{2} x3 + {x1}^{3} {x3}^{2} + \frac{t^{3}}{6} - x2 x3 t + \cos (x1) t + \sin (x1)$

(36)

SpecializeArbitraryFunctions method

This method is for solving the Cauchy problem for hyperbolic PDE in unbounded domains, including cases where there are different types of sources as well as functions in the initial conditions.

>	$pde__13 ≔ diff (u (x, t), t, t) - 4 \cdot diff (u (x, t), x, x) = f (a)$

$pde__13 ≔ \frac{\partial^{2}}{\partial t^{2}} u (x, t) - 4 \frac{\partial^{2}}{\partial x^{2}} u (x, t) = f (a)$

(37)

>	$conds__13 ≔ u (x, 0) = 0, D [2] (u) (x, 0) = x^{2} &colon;$

>	$pdsolve ([pde__13, conds__13]) &semi;$

$u (x, t) = \frac{f (a) t^{2}}{2} + \frac{4 t^{3}}{3} + t x^{2}$

(38)

Polynomial Solutions method

This method gives pdsolve better performance to find polynomial solutions to PDE & BC problems when they exist.

>	$pde__14 ≔ diff (u (x, y), x, x) + y \cdot diff (u (x, y), y, y) = 0$

$pde__14 ≔ \frac{\partial^{2}}{\partial x^{2}} u (x, y) + y (\frac{\partial^{2}}{\partial y^{2}} u (x, y)) = 0$

(39)

>	$conds__14 ≔ u (x, 0) = 0, D_{2} (u) (x, 0) = x^{2} &colon;$

>	$pdsolve ([pde__14, conds__14], u (x, y))$

$u (x, y) = y (x^{2} - y)$

(40)

An example with a system of PDE & BC for which pdsolve does not find a solution using the default maximum degree 10 for linear PDE.

>	$sys__15 ≔ diff (u (x, y), y) = - diff (v (x, y), x), diff (u (x, y), x) = diff (v (x, y), y)$

$sys__15 ≔ \frac{\partial}{\partial y} u (x, y) = - \frac{\partial}{\partial x} v (x, y), \frac{\partial}{\partial x} u (x, y) = \frac{\partial}{\partial y} v (x, y)$

(41)

>	$conds__15 ≔ u (x, 0) = x^{11}, v (x, 0) = 0 &colon;$

>	$pdsolve ([sys__15, conds__15], method = PolynomialSolutions)$

The degree seen in the initial conditions is given below to find a solution:

>	$pdsolve ([sys__15, conds__15], \{u (x, y), v (x, y)\}, method = PolynomialSolutions, degree = 11)$

$\{u (x, y) = x^{11} - 55 y^{2} x^{9} + 330 y^{4} x^{7} - 462 y^{6} x^{5} + 165 y^{8} x^{3} - 11 y^{10} x, v (x, y) = 11 y x^{10} - 165 y^{3} x^{8} + 462 y^{5} x^{6} - 330 y^{7} x^{4} + 55 y^{9} x^{2} - y^{11}\}$

(42)

Superposition method

This method is for linear homogeneous PDE problems with non-periodic initial and boundary conditions, more than one of which is non-homogeneous.

The superposition method works by taking advantage of the linearity of the problem and the fact that the solution to such a problem in which two or more of the BC are non-homogeneous can be given as

u = $u__1 + u__2$ + ..., where each $u__i$ is a solution of the PDE with all but one of the BC homogenized.

A Laplace PDE with one homogeneous and three non-homogeneous conditions:

>	$pde__16 ≔ diff (u (x, y), x, x) + diff (u (x, y), y, y) = 0$

$pde__16 ≔ \frac{\partial^{2}}{\partial x^{2}} u (x, y) + \frac{\partial^{2}}{\partial y^{2}} u (x, y) = 0$

(43)

>	$conds__16 ≔ u (0, y) = 0, u (π, y) = \sinh (π) \cos (y), u (x, 0) = \sin (x), u (x, π) = - \sinh (x) &colon;$

>	$pdsolve ([pde__16, conds__16])$

$u (x, y) = \frac{({&ExponentialE;}^{2 π} - 1) (\sum_{n = 1}^{\infty} \frac{{(−1)}^{n} n ({&ExponentialE;}^{2 π} - 1) {&ExponentialE;}^{n (π - y) - π} \sin (n x) ({&ExponentialE;}^{2 n y} - 1)}{π (n^{2} + 1) ({&ExponentialE;}^{2 π n} - 1)}) + ({&ExponentialE;}^{2 π} - 1) (\sum_{n = 2}^{\infty} \frac{2 \sin (n y) {&ExponentialE;}^{n (π - x)} \sinh (π) n ({(−1)}^{n} + 1) ({&ExponentialE;}^{2 n x} - 1)}{π ({&ExponentialE;}^{2 π n} - 1) (n^{2} - 1)}) + \sin (x) (- {&ExponentialE;}^{y} + {&ExponentialE;}^{- y + 2 π})}{{&ExponentialE;}^{2 π} - 1}$

(44)

Heat method

This method applies to heat PDE, with or without a source, in semi-infinite domains.

A heat PDE in a semi-bounded domain; note the conditions require a linear change of variables before the method can be applied.

>	$pde__17 ≔ diff (u (x, t), t) = \frac{1}{4} \cdot diff (u (x, t), x, x)$

$pde__17 ≔ \frac{\partial}{\partial t} u (x, t) = \frac{\frac{\partial^{2}}{\partial x^{2}} u (x, t)}{4}$

(45)

>	$conds__17 ≔ D_{1} (u) (α, t) = 0, u (x, β) = 10 \exp (- x^{2}) &colon;$

>	$pdsolve ([pde__17, conds__17], u (x, t)) assuming 0 < x, 0 < t$

$u (x, t) = - \frac{5 ((\erf (\frac{(t - β - 1) α + x}{\sqrt{t - β} \sqrt{t - β + 1}}) - 1) {&ExponentialE;}^{\frac{4 α (- x + α)}{- t + β - 1}} + \erf (\frac{(t - β + 1) α - x}{\sqrt{t - β} \sqrt{t - β + 1}}) - 1) {&ExponentialE;}^{\frac{x^{2}}{- t + β - 1}}}{\sqrt{t - β + 1}}$

(46)

Wave method

This method applies to wave PDE, with or without a source, in semi-infinite domains.

A wave PDE in a semi-bounded domain:

>	$pde__18 ≔ diff (u (x, t), t, t) - 9 \cdot diff (u (x, t), x, x) = 0$

$pde__18 ≔ \frac{\partial^{2}}{\partial t^{2}} u (x, t) - 9 \frac{\partial^{2}}{\partial x^{2}} u (x, t) = 0$

(47)

>	$conds__18 ≔ D_{1} (u) (0, t) = 0, u (x, 0) = 0, D_{2} (u) (x, 0) = x^{3} &colon;$

>	$pdsolve ([pde__18, conds__18]) assuming 0 < x, 0 < t$

$u (x, t) = \frac{(\{\begin{array}{c} 108 t^{3} x + 12 t x^{3} & 3 t < x \\ 81 t^{4} + 54 t^{2} x^{2} + x^{4} & x < 3 t \end{array})}{12}$

(48)

A wave PDE in a semi-bounded domain with non-homogeneous conditions:

>	$pde__19 ≔ \frac{\partial^{2}}{\partial t^{2}} u (x, t) = c^{2} (\frac{\partial^{2}}{\partial x^{2}} u (x, t))$

$pde__19 ≔ \frac{\partial^{2}}{\partial t^{2}} u (x, t) = c^{2} (\frac{\partial^{2}}{\partial x^{2}} u (x, t))$

(49)

>	$conds__19 ≔ u (x, 0) = {\sin (x)}^{3}, D_{2} (u) (x, 0) = 1 - {&ExponentialE;}^{- \frac{1}{10} x}, D_{1} (u) (0, t) = 1 &colon;$

>	$pdsolve ([pde__19, conds__19], u (x, t)) assuming t > 0 and x > 0 &semi;$

$u (x, t) = \frac{\{\begin{array}{c} {\sin (c t + x)}^{3} c - {\sin (c t - x)}^{3} c + 2 c t - 10 {&ExponentialE;}^{\frac{c t}{10} - \frac{x}{10}} + 10 {&ExponentialE;}^{- \frac{c t}{10} - \frac{x}{10}} & c t < x \\ 10 {&ExponentialE;}^{- \frac{c t}{10} - \frac{x}{10}} + 10 {&ExponentialE;}^{- \frac{c t}{10} + \frac{x}{10}} + {\sin (c t - x)}^{3} c + {\sin (c t + x)}^{3} c - 20 - 2 c^{2} t + (2 t + 2 x) c & x < c t \end{array}}{2 c}$

(50)

Sturm-Liouville problem with eigenvalues that are the roots of algebraic expressions which cannot be inverted

When using the Fourier Series method, explained above, there are times when the eigenvalue(s) are roots of an algebraic expression whose inversion cannot be expressed using known mathematical functions.

As an example, consider a problem representing the temperature distribution in a thin rod whose lateral surface is insulated over the interval $0 < x < 1$ , with the left end of the rod insulated and the right end experiencing a convection heat loss, as explained in Articolo's example 3.6.4 (see References below)

>	$pde__20 ≔ diff (u (x, t), t) = k \cdot diff (u (x, t), x, x)$

$pde__20 ≔ \frac{\partial}{\partial t} u (x, t) = k (\frac{\partial^{2}}{\partial x^{2}} u (x, t))$

(51)

>	$conds__20 ≔ u (x, 0) = 1 - \frac{1}{4} x^{3}, D_{1} (u) (0, t) = 0, D_{1} (u) (1, t) + u (1, t) = 0 &colon;$

>	$pdsolve ([pde__20, conds__20])$

$u (x, t) = casesplit/ans (Sum (\frac{3 \exp (- k λ_{n}^{2} t) ((- λ_{n}^{2} + 2) \cos (λ_{n}) - 2 + (λ_{n}^{3} + 2 λ_{n}) \sin (λ_{n})) \cos (λ_{n} x)}{λ_{n}^{3} (\sin (2 λ_{n}) + 2 λ_{n})}, n = 0 .. \infty), \{And (\tan (λ_{n}) λ_{n} - 1 = 0, 0 < λ_{n})\})$

(52)

To test and plot the solution, we start with

>	$solution ≔ lhs () = op (1, rhs ())$

$solution ≔ u (x, t) = \sum_{n = 0}^{\infty} \frac{3 {&ExponentialE;}^{- k λ_{n}^{2} t} ((- λ_{n}^{2} + 2) \cos (λ_{n}) - 2 + (λ_{n}^{3} + 2 λ_{n}) \sin (λ_{n})) \cos (λ_{n} x)}{λ_{n}^{3} (\sin (2 λ_{n}) + 2 λ_{n})}$

(53)

>	$op ([2, 2, 1, 1],)$

$\tan (λ_{n}) λ_{n} - 1 = 0$

(54)

By inspection, solution has $\sin (λ_{n})$ and $\cos (λ_{n})$ , not $\tan (λ_{n})$ ; we rewrite equation (54) and isolate $\cos (λ_{n})$ :

>	$condition ≔ isolate (convert (, sincos), \cos (λ_{n}))$

$condition ≔ \cos (λ_{n}) = \sin (λ_{n}) λ_{n}$

(55)

Substitute now this condition in the solution and start by pdetesting

>	$pdetest (subs (condition, solution), [pde__20, conds__20])$

$[0, (\sum_{n = 0}^{\infty} \frac{(12 \sin (λ_{n}) λ_{n} - 6) \cos (λ_{n} x)}{λ_{n}^{3} (\sin (2 λ_{n}) + 2 λ_{n})}) - 1 + \frac{x^{3}}{4}, 0, (\sum_{n = 0}^{\infty} \frac{(- 12 λ_{n} {\sin (λ_{n})}^{2} + 6 \sin (λ_{n})) {&ExponentialE;}^{- k λ_{n}^{2} t}}{λ_{n}^{2} (\sin (2 λ_{n}) + 2 λ_{n})}) + (\sum_{n = 0}^{\infty} \frac{(12 \sin (λ_{n}) λ_{n} - 6) \cos (λ_{n}) {&ExponentialE;}^{- k λ_{n}^{2} t}}{λ_{n}^{3} (\sin (2 λ_{n}) + 2 λ_{n})})]$

(56)

A further manipulation, substituting condition and combining the sums, results in

>	$simplify (combine (subs (condition,), Sum))$

$[0, (\sum_{n = 0}^{\infty} \frac{(12 \sin (λ_{n}) λ_{n} - 6) \cos (λ_{n} x)}{λ_{n}^{3} (\sin (2 λ_{n}) + 2 λ_{n})}) - 1 + \frac{x^{3}}{4}, 0, 0]$

(57)

So the PDE and two of the conditions are satisfied without having to specify who is $λ__n$ - it sufficed to use $\cos (λ_{n}) = \sin (λ_{n}) λ_{n}$ , and this is the case of most of the problems we analyzed: the exact closed form of $λ__n$ is really not needed in these examples.

For the one expression which remains to be proved equal to zero, there is no clear way to perform the sum and show that it is equal to $(1 - \frac{x^{3}}{4})$ without further information on the value of $λ__n$ . So this part must be tested using a plot.

Now, perform the summation using, say, the first 100 terms of the series; for that purpose, the first 100 positive values of $λ__n$ are needed. These values can be obtained using fsolve. Increase Digits to get a better approximation:

>	$Digits ≔ 20 &colon;$

>	$L ≔ [fsolve (condition, lambda [n], 0 .. 10^{10}, maxsols = 100)] &colon;$

For convenience, construct a procedure, as a function of n, that returns each of these values:

>	$Lambda ≔ n \to if n ∷ nonnegint then L [n + 1] else' Lambda (args)' fi &semi;$

$Λ ≔ n \mapsto if n ::' nonnegint' then L_{n + 1} else'Λ (args)' end if$

(58)

Replace $λ__n$ by $Λ (n),$ infinity by 99 and the expression to be plotted is

>	$remain ≔ subs (lambda [n] = Lambda (n), infinity = 99, [2])$

$remain ≔ (\sum_{n = 0}^{99} \frac{(12 \sin (Λ (n)) Λ (n) - 6) \cos (Λ (n) x)}{{Λ (n)}^{3} (\sin (2 Λ (n)) + 2 Λ (n))}) - 1 + \frac{x^{3}}{4}$

(59)

Perform the sum and plot. The plotting range is the one present in the $conds__20$ , x from 0 to 1:

>	$R ≔ eval (remain, Sum = add) &colon;$

>	$plot (R, x = 0 .. 1)$

With the first 100 terms (constructed using the first 100 roots of $\tan (λ_{n}) λ_{n} - 1 = 0$ ) we verified that the last of the four testing conditions is sufficiently close to zero, and this concludes the verification.

To plot the solution, the idea is the same: in solution, give a value to k, say k = 1/5, and then construct the sum of the first 100 terms as done in remain, but this time using solution instead of the pdetest result.

>	$subs (k = \frac{1}{5}, lambda [n] = Lambda (n), infinity = 99, solution)$

$u (x, t) = \sum_{n = 0}^{99} \frac{3 {&ExponentialE;}^{- \frac{{Λ (n)}^{2} t}{5}} ((- {Λ (n)}^{2} + 2) \cos (Λ (n)) - 2 + ({Λ (n)}^{3} + 2 Λ (n)) \sin (Λ (n))) \cos (Λ (n) x)}{{Λ (n)}^{3} (\sin (2 Λ (n)) + 2 Λ (n))}$

(60)

>	$S ≔ eval (, Sum = add) &colon;$

>	$plot3d (rhs (S), x = 0 .. 1, t = 0 .. 1)$

Compare with the numerical solution one could obtain using pdsolve with the numeric option. Substitute $k = \frac{1}{5}$ in $pde__20$ , and construct the corresponding plot:

>	$numerical_solution ≔ pdsolve (subs (k = \frac{1}{5}, pde__20), \{conds__20\}, numeric, time = t, range = 0 .. 1)$

$numerical_solution ≔ module () ... end$

(61)

>	$numerical_solution :- plot3d (t = 0 .. 1, x = 0 .. 1)$

References

•	Articolo, George A. Partial Differential Equations and Boundary Value Problems with Maple. 2nd ed., Elsevier Academic Press, 2009.

•	Logan, David J. Applied Partial Differential Equations. 3rd ed., Springer, 2015.

•	Pinchover, Y. and Rubinstein, J.. An Introduction to Partial Differential Equations. Cambridge UP, 2005.

•	Polyanin, Andrei D. Handbook of Linear Partial Differential Equations for Engineers and Scientists. Chapman & Hall/CRC, 2002.

	Compatibility
	For more information on Maple 2019 changes, see Updates in Maple 2019.

Maple

Erweiterungen für Maple

MapleSim

Erweiterungen für MapleSim

Systementwicklung

Beratende Dienstleistungen

Produkte zur Online-Ausbildung

Ausbildung

Industrie

Automobil und Luftfahrt

Robotik

Maschinendesign & industrielle Automation

Andere

Lösungen für die Industrie

Kaufen: Einzelheiten und Preise

Kaufen

Institutionelle Studentenlizenzierung

Elite-Wartungsprogramm

Support

Produktschulung

Online Hilfe zu Produkten

Webinare und Veranstaltungen

Veröffentlichungen

Content Hubs

Anwendungsbeispiele

Community

Über Maplesoft

Pressezentrum

User Community

Kontakt

Online Help

All Products Maple MapleSim

Maple

Leistungsfähige intuitive Mathematiksoftware

Erweiterungen für Maple

MapleSim

Modellierung auf Systemebene

Erweiterungen für MapleSim

Systementwicklung

Beratende Dienstleistungen

Produkte zur Online-Ausbildung

Ausbildung

Industrie

Automobil und Luftfahrt

Robotik

Maschinendesign & industrielle Automation

Andere

Lösungen für die Industrie

Kaufen: Einzelheiten und Preise

Kaufen

Institutionelle Studentenlizenzierung

Elite-Wartungsprogramm

Support

Produktschulung

Online Hilfe zu Produkten

Webinare und Veranstaltungen

Veröffentlichungen

Content Hubs

Anwendungsbeispiele

Community

Über Maplesoft

Pressezentrum

User Community

Kontakt

Online Help

All Products Maple MapleSim