 apply the Hodge star operator to a differential form - Maple Programming Help

Home : Support : Online Help : Mathematics : DifferentialGeometry : Tensor : DifferentialGeometry/Tensor/HodgeStar

Tensor[HodgeStar] - apply the Hodge star operator to a differential form

Calling Sequences

HodgeStar(g, omega)

Parameters

g      - a metric tensor

omega  - a differential form

option - (optional) the keyword argument detmetric

Examples

 > with(DifferentialGeometry): with(Tensor):

Example 1.

First create a 5-dimensional manifold $M$ and define a metric tensor $g$ on the tangent space of $M$.

 E > DGsetup([x1, x2, x3, x4, x5], M1):
 M1 > g := evalDG(dx1 &t dx1 + dx2 &t dx2 + dx3 &t dx3 + dx4 &t dx4 + dx5 &t dx5);
 ${g}{:=}{\mathrm{dx1}}{}{\mathrm{dx1}}{+}{\mathrm{dx2}}{}{\mathrm{dx2}}{+}{\mathrm{dx3}}{}{\mathrm{dx3}}{+}{\mathrm{dx4}}{}{\mathrm{dx4}}{+}{\mathrm{dx5}}{}{\mathrm{dx5}}$ (1.1)

The standard basis  is an orthonormal basis for $g$ and therefore the Hodge star is easily computed.

 M1 > HodgeStar(g, dx1);
 ${\mathrm{dx2}}{}{\bigwedge }{}{\mathrm{dx3}}{}{\bigwedge }{}{\mathrm{dx4}}{}{\bigwedge }{}{\mathrm{dx5}}$ (1.2)
 M1 > HodgeStar(g, dx2);
 ${-}{\mathrm{dx1}}{}{\bigwedge }{}{\mathrm{dx3}}{}{\bigwedge }{}{\mathrm{dx4}}{}{\bigwedge }{}{\mathrm{dx5}}$ (1.3)
 M1 > HodgeStar(g, dx2 &w dx3);
 ${\mathrm{dx1}}{}{\bigwedge }{}{\mathrm{dx4}}{}{\bigwedge }{}{\mathrm{dx5}}$ (1.4)
 M1 > HodgeStar(g, dx2 &w dx4);
 ${-}{\mathrm{dx1}}{}{\bigwedge }{}{\mathrm{dx3}}{}{\bigwedge }{}{\mathrm{dx5}}$ (1.5)
 M1 > HodgeStar(g, dx2 &w dx3 &w dx4);
 ${-}{\mathrm{dx1}}{}{\bigwedge }{}{\mathrm{dx5}}$ (1.6)

Example 2.

To show the dependence of the Hodge star upon the metric, we consider a general metric $g$ on a 2-dimensional manifold.

 M1 > DGsetup([x, y], M2):
 M2 > g := evalDG(a*dx &t dx + b*(dx &t dy + dy &t dx) + c*dy &t dy);
 ${g}{:=}{a}{}{\mathrm{dx}}{}{\mathrm{dx}}{+}{b}{}{\mathrm{dx}}{}{\mathrm{dy}}{+}{b}{}{\mathrm{dy}}{}{\mathrm{dx}}{+}{c}{}{\mathrm{dy}}{}{\mathrm{dy}}$ (1.7)
 M2 > HodgeStar(g, dx);
 $\sqrt{\frac{{1}}{{a}{}{c}{-}{{b}}^{{2}}}}{}{b}{}{\mathrm{dx}}{+}\sqrt{\frac{{1}}{{a}{}{c}{-}{{b}}^{{2}}}}{}{c}{}{\mathrm{dy}}$ (1.8)
 M2 > HodgeStar(g, dy);
 ${-}\sqrt{\frac{{1}}{{a}{}{c}{-}{{b}}^{{2}}}}{}{a}{}{\mathrm{dx}}{-}\sqrt{\frac{{1}}{{a}{}{c}{-}{{b}}^{{2}}}}{}{b}{}{\mathrm{dy}}$ (1.9)
 M2 > f := HodgeStar(g, dx &w dy);
 ${f}{:=}\sqrt{\frac{{1}}{{a}{}{c}{-}{{b}}^{{2}}}}$ (1.10)
 M2 > HodgeStar(g, f);
 ${\mathrm{dx}}{}{\bigwedge }{}{\mathrm{dy}}$ (1.11)

Example 3.

The Laplacian of a function with respect to a metric $g$ can be calculated using the exterior derivative operation and the Hodge star operator.

To illustrate this result, we use the Euclidean metric in polar coordinates $\left(r,\mathrm{ϑ}\right)$.

 M2 > DGsetup([r, theta], M3):
 M3 > g := evalDG(dr &t dr + r^2*dtheta &t dtheta);
 ${g}{:=}{\mathrm{dr}}{}{\mathrm{dr}}{+}{{r}}^{{2}}{}{\mathrm{dtheta}}{}{\mathrm{dtheta}}$ (1.12)

To simplify the definition of the Laplacian, we define the Hodge operator with $g$ fixed.

 M3 > Hodge := f -> (HodgeStar(g, f) assuming r > 0);
 ${\mathrm{Hodge}}{:=}{f}{→}{\mathrm{DifferentialGeometry:-Tensor}}{:-}{\mathrm{HodgeStar}}{}\left({g}{,}{f}\right)\phantom{\rule[-0.0ex]{0.5em}{0.0ex}}{assuming}\phantom{\rule[-0.0ex]{0.5em}{0.0ex}}{0}{<}{r}$ (1.13)

To display the Laplacian of $\mathrm{φ}$ in compact form we invoke the PDEtools[declare] command.

 M3 > PDEtools[declare](phi(r, theta));
 ${\mathrm{φ}}{}\left({r}{,}{\mathrm{θ}}\right){}{\mathrm{will now be displayed as}}{}{\mathrm{φ}}$ (1.14)

Here is the formula for the Laplacian in terms of HodgeStar and ExteriorDerivative.  Recall that @ is the composition of functions.

 M3 > Delta := (Hodge @ ExteriorDerivative @ Hodge @ ExteriorDerivative)(phi(r, theta));
 ${\mathrm{Δ}}{:=}\frac{{r}{}{{\mathrm{φ}}}_{{r}}{+}{{r}}^{{2}}{}{{\mathrm{φ}}}_{{r}{,}{r}}{+}{{\mathrm{φ}}}_{{\mathrm{θ}}{,}{\mathrm{θ}}}}{{{r}}^{{2}}}$ (1.15)

Example 4.

The HodgeStar program also works in the more general context of a vector bundle $E\to M$.

 M3 > DGsetup([x, y], [u, v, w], E);
 ${\mathrm{frame name: E}}$ (1.16)
 E > g := evalDG(du &t du + dv &t dv + dw &t dw);
 ${g}{:=}{\mathrm{du}}{}{\mathrm{du}}{+}{\mathrm{dv}}{}{\mathrm{dv}}{+}{\mathrm{dw}}{}{\mathrm{dw}}$ (1.17)
 E > HodgeStar(g, du &w dv - 3*du &w dw + 2*dv &w dw);
 ${2}{}{\mathrm{du}}{+}{3}{}{\mathrm{dv}}{+}{\mathrm{dw}}$ (1.18)

Example 5.

The HodgeStar operation can also be performed using an indefinite metric. The keyword argument detmetric = -1 must be used when the metric has negative determinant.

 E > DGsetup([x1, x2, x3, x4], M5):
 M1 > g := evalDG(dx1 &t dx1 + dx2 &t dx2 + dx3 &t dx3 - dx4 &t dx4);
 ${g}{:=}{\mathrm{dx1}}{}{\mathrm{dx1}}{+}{\mathrm{dx2}}{}{\mathrm{dx2}}{+}{\mathrm{dx3}}{}{\mathrm{dx3}}{-}{\mathrm{dx4}}{}{\mathrm{dx4}}$ (1.19)

 M1 > HodgeStar(g, dx1, detmetric = -1);
 ${\mathrm{dx2}}{}{\bigwedge }{}{\mathrm{dx3}}{}{\bigwedge }{}{\mathrm{dx4}}$ (1.20)
 M5 > HodgeStar(g, dx3 &w dx4, detmetric = -1);
 ${-}{\mathrm{dx1}}{}{\bigwedge }{}{\mathrm{dx2}}$ (1.21)

 Description