Build and Share Interactive Content

All Products Maple MapleSim

Home : Support : Online Help : System : Information : Updates : Maple 2022 : Build and Share Interactive Content

Build and Share Interactive Content

Maple 2022 provides additional tools for creating documents and interactive applications programmatically. These tools can be used to develop Maple Learn content or to create applications to be used in Maple. Maple Learn is a new online environment designed specifically for teaching and learning mathematics.

Canvas Scripting

Help with Math Problems

Canvas-based Quizzes

Canvas Scripting

Maple 2022 greatly extends the tools for creating Canvas-based documents and interactive applications programmatically.

The Canvas package provides a framework for Maple users to easily build applications that can be used both in Maple and also shared on the web through Maple Learn. These applications can gather user input and compute using standard Maple commands in either environment.

Canvas Package

The DocumentTools[Canvas] package builds on DocumentTools component primitives to provide a simple way to generate a grid layout of text and math. It provides an easy mechanism to programmatically generate a page of math text and other elements. New in Maple 2022 is the ability to add Sliders, 3-D Plots, Images, Hyperlinks, Line-Drawings, and many new options for controlling the display of math and text.

3-D Plot Example

>	with(DocumentTools:-Canvas):

cv := NewCanvas([
     Text("Volume of Revolution",fontsize=24),
     "This solid of revolution is created by rotating",
     f(x) = cos(x) + 1,
     Text("about the y=0 axis on the interval %1",(0 <= x) and (x <= 4*Pi)),
     Plot3D( "Student:-Calculus1:-VolumeOfRevolution(cos(x) + 1, x = 0 .. 4*Pi, output = plot, caption=``)" )
]):

>	ShowCanvas(cv);

Image Example

In this example we embed an image in the canvas.
Note: To execute this code you must be logged into the MapleCloud; see the Image command's help page for details.

>	$with (DocumentTools :- Canvas) &colon;$

>	$file ≔ cat (kernelopts (datadir), /images/antennas.jpg) &colon;$

>	$cv ≔ NewCanvas ([Sample Image, Image (file)]) &colon;$

>	$ShowCanvas (cv)$

The ShareCanvas command sends the canvas to Maple Learn and gives you a link to your document.

>	$ShareCanvas (cv)$

https://learn.maplesoft.com/#/?d=OTCKBNLTJUKMAKLMCLFIDMBFMJLKJPDQCGJIOMPJCPIOAOFQHNNHERHGFUIRNOBNEKOMGSMTIGCNKHETLJOLPIITMGKFMUMTONNN

Interactive Example

In this example, we will define an application that allows user input and provides feedback. The UpdateStats procedure will run when a button is pressed. It will use the new GetElements command to extract specific pieces of the canvas, including an array of points as input to analyze, and named elements so they can be replaced with updated values.

with(Statistics):
with(DocumentTools:-Canvas):

UpdateStats := proc( canvas )
    local data := GetElements(canvas,'custom'="Grades")[1]:-math;
    local data_mean := Statistics:-Mean(data);
    local data_variance := Statistics:-Variance(data);
    local X := RandomVariable(Normal(data_mean, sqrt(data_variance)));
    local P := DensityPlot(X, range = 0..100, thickness = 3, color=red):
    local Q := Histogram(data, range = 0..100):

    local sc := Script();
    SetActive(sc,GetElements(canvas,"plot")[1]);
    SetPlot(sc, plots[display](P, Q) );

    SetActive(sc,GetElements(canvas,'custom'="mean")[1]);
    SetMath(sc,'mu'=data_mean);
    Annotate(sc,"mean");

    SetActive(sc,GetElements(canvas,'custom'="std")[1]);
    SetMath(sc,'sigma'=sqrt(data_variance));
    Annotate(sc,"standard deviation");
    ToString(sc);
end proc:

SampleGrades := [65, 68, 70, 97, 64, 73, 39, 69, 70, 65, 82, 71, 76, 60, 77, 86, 69, 71, 90, 74, 66, 75, 70, 80, 72, 82, 80, 79, 56, 74]:

cv := NewCanvas( ["Normal Distribution of Grades", 
                  "Grades:", 
                  Math(SampleGrades,'custom'="Grades"), 
                  StaticPlot(), 
                  Math(sigma = sigma,'custom'="std"), 
                  Math(mu = mu,'custom'="mean"),
                  ScriptButton("Calculate",UpdateStats,position=[500,50]) 
  ] ):

>	$ShowCanvas (cv)$

To try this on the web using Maple Learn, execute:

>	ShareCanvas(cv);

https://learn.maplesoft.com/#/?d=BNMSGTBOPRITAPETOFHTHSLKMKFQANDSKGBRBUOTCPNKDQJKAMOSNPHUHNIKEGHQDJCPEPCLFOMOPUIUNKPGCPMRDQHKNHMLCOBU

On-Click Events

The Plot element has a new "onclick" option, and the Button element has a new "onmoved" option. These can be used to react to events such as clicking on a plot or moving an image on a canvas. There is also a new hidden State element, which can be used to record behind the scenes values that don't need to be visible in the canvas.

In this example the user is asked to click on a plot to add points. When 2 or more points are set, the application will find a polynomial curve fit approximation and draw that on the plot too.

with(DocumentTools:-Canvas):

myView := [-10..10,-10..10]:

clickplot := proc( canvas ) 
    # append to the list of points
    global _location;
    local state := GetElements(canvas,"state")[1];
    local points := state:-value;
    if assigned('_location') then
        points := [op(points), _location];
    end if;

    # generate a new plot of the points
    local plt := (
       if points <> [] then
           plots[pointplot](points,view=myView);
       else
           plots[textplot]([5,5,"click on plot"],view=myView);
       end if);

    # fit the curve if there are 2 or more points
    local f := NULL;
    if numelems(points) > 1 then
        local a1, b1, c1, d1;
        local eq := 
            if numelems(points) = 2 then
                a1+b1*x;
            elif numelems(points) = 3 then
                a1+b1*x+c1*x^2;
            else
                a1+b1*x+c1*x^2+d1*x^3;
            end if;
        f := CurveFitting:-LeastSquares( points, x, 'curve' = eq );
        plt := plots:-display({plt,plot(f,'view'=myView)});
    end if;

    # create the script to update the canvas
    local plotelem := GetElements(canvas,"plot")[1];
    local sc := Script();
    SetActive(sc,plotelem);
    SetPlot(sc,plt);

    # display the fit equation
    if f <> NULL then
        f := subsindets(f,float,x->.001*round(1000*x));
        SetActive(sc,GetElements(canvas,'custom'="EQ")[1]);
        SetText(sc,"Your curve looks like: ");
        SetMath(sc,f,'where'="below");
    end if;

    SetState(sc,points);
    ToString(sc);
end proc:

cv := NewCanvas(["Curve Fitting - click on the plot to add points", 
            ScriptButton("Click",clickplot,'include'=['myView'], 'visible'=false),
            Group([
                  StaticPlot(plots[textplot]([5,5,"click on plot"],view=myView),'onclick'="Click"),
                  Text("",custom="EQ", 'container'="group")],
                  'active'=true),
            State([])
]):

>	$ShowCanvas (cv, entrybox = false) &semi;$

>	ShareCanvas(cv);

https://learn.maplesoft.com/#/?d=JOESANAGLRBIJUFMNQPRKGBMGKPIEODNBGGSCSEGOINMOIMFOOMODLILPIASNREKAKERCTHSEPIOIRGUAQCTIKLSCMCTOIAUFOJP

Help with Math Problems

The new IntPractice and DiffPractice commands extend the algorithm behind SolveFeedback to handle integrals and derivatives.

>	$with (Grading) &colon;$

>	$IntPractice (\int x^{} \cdot \sin (x) &DifferentialD; x)$

This interactive example can also be shared via Maple Learn:

$IntPractice (\int x^{} \cdot \sin (x) &DifferentialD; x,' output' =' link') &colon;$ https://learn.maplesoft.com/#/?d=ITFOMGBOPTOMCGMGLPBNLLKPHFEJERLHLOAJBOGMGKNGHLBQPLDLNIKQPSELBIJNKPLHLQKGFSLFKTGJIPKQIPMRDGOLHPKTDKFG

Canvas-based Quizzes

The Quiz command now has an option to supply a solution. The quiz question, verifier, new-problem generator and solution can return a canvas, which can be deployed to Maple Learn.

with(Grading):
cv := Quiz("How many ways are there to choose $B balls from a sack containing $A different colored balls?",
    proc() evalb(Quiz:-Get(`$RESPONSE`) = binomial(Quiz:-Get(`$A`),Quiz:-Get(`$B`)) ) 
    end proc,
    proc() Quiz:-Set(`$A`=rand(5..10)());
           Quiz:-Set(`$B`=rand(1..4)());
           1;
    end proc,
    'solution' = proc() 
          local a := Quiz:-Get(`$A`);
          local b := Quiz:-Get(`$B`);
          [["Compute the Binomial Coefficient", %binomial(a,b) = `%/`(%factorial(a),`%*`(%factorial(b), `%+`(a,-b)!))],
           ["Result:", binomial(a,b)]]
    end,
    'output'='canvas'
):

>	$with (DocumentTools :- Canvas) &colon;$

>	$ShowCanvas (cv, entrybox = false) &semi;$

>	$ShareCanvas (cv) &semi;$

https://learn.maplesoft.com/#/?d=LOJKCGMHBIMFJHPGPFANCRFGLRDGLHGODFDMIHGNAPBHLNLRGJGUFUMMPRJQJNAFNJGRBPMKEGKUAUOKAOKRINEPNNPNCIFULMIF

Download Help Document

Maple

Erweiterungen für Maple

Student Success Platform

Verbesserung der Studienerfolgsquote

MapleSim

Erweiterungen für MapleSim

Beratende Dienstleistungen

Produkte zur Online-Ausbildung

Ausbildung

Industrie

Automobil und Luftfahrt

Robotik

Maschinendesign & industrielle Automation

Andere

Lösungen für die Industrie

Kaufen: Einzelheiten und Preise

Kaufen

Institutionelle Studentenlizenzierung

Elite-Wartungsprogramm

Support

Produktschulung

Online Hilfe zu Produkten

Webinare und Veranstaltungen

Veröffentlichungen

Content Hubs

Anwendungsbeispiele

Community

Über Maplesoft

Pressezentrum

User Community

Kontakt

Online Help

All Products Maple MapleSim

Maple

Leistungsfähige intuitive Mathematiksoftware

Erweiterungen für Maple

Student Success Platform

Verbesserung der Studienerfolgsquote

MapleSim

Modellierung auf Systemebene

Erweiterungen für MapleSim

Beratende Dienstleistungen

Produkte zur Online-Ausbildung

Ausbildung

Industrie

Automobil und Luftfahrt

Robotik

Maschinendesign & industrielle Automation

Andere

Lösungen für die Industrie

Kaufen: Einzelheiten und Preise

Kaufen

Institutionelle Studentenlizenzierung

Elite-Wartungsprogramm

Support

Produktschulung

Online Hilfe zu Produkten

Webinare und Veranstaltungen

Veröffentlichungen

Content Hubs

Anwendungsbeispiele

Community

Über Maplesoft

Pressezentrum

User Community

Kontakt

Online Help

All Products Maple MapleSim