Calculate the exterior derivative of a differential p-form or a matrix of p-forms.

Check that a Pfaffian system of 1-forms is integrable.

Calculate the Maurer Cartan forms for a matrix group.

Apply the homotopy operator for the exterior derivative.

with(DifferentialGeometry):

DGsetup([x, y, z, w], E3);

$\mathrm{frame\; name:\; E3}$

vars := x, y, z, w:

PDEtools[declare](M(vars), N(vars), P(vars), Q(vars), quiet);

f := M(vars);

$f≔M$

ExteriorDerivative(f);

$M_x\mathrm{dx}\+M_y\mathrm{dy}\+M_z\mathrm{dz}\+M_w\mathrm{dw}$

alpha1 := evalDG(M(vars)*dx + N(vars)*dy + P(vars)*dz + Q(vars)*dw);

$\mathrm{\α1}≔M\mathrm{dx}\+N\mathrm{dy}\+P\mathrm{dz}\+Q\mathrm{dw}$

ExteriorDerivative(alpha1);

$\left(N_x-M_y\right)\mathrm{dx}\mathrm{`^`}\mathrm{dy}\+\left(P_x-M_z\right)\mathrm{dx}\mathrm{`^`}\mathrm{dz}\+\left(Q_x-M_w\right)\mathrm{dx}\mathrm{`^`}\mathrm{dw}\+\left(P_y-N_z\right)\mathrm{dy}\mathrm{`^`}\mathrm{dz}\+\left(Q_y-N_w\right)\mathrm{dy}\mathrm{`^`}\mathrm{dw}\+\left(Q_z-P_w\right)\mathrm{dz}\mathrm{`^`}\mathrm{dw}$

alpha2 := evalDG(M(vars)*dx &w dy + N(vars)*dz &w dw);

$\mathrm{\α2}≔M\mathrm{dx}\mathrm{`^`}\mathrm{dy}\+N\mathrm{dz}\mathrm{`^`}\mathrm{dw}$

ExteriorDerivative(alpha2);

$M_z\mathrm{dx}\mathrm{`^`}\mathrm{dy}\mathrm{`^`}\mathrm{dz}\+M_w\mathrm{dx}\mathrm{`^`}\mathrm{dy}\mathrm{`^`}\mathrm{dw}\+N_x\mathrm{dx}\mathrm{`^`}\mathrm{dz}\mathrm{`^`}\mathrm{dw}\+N_y\mathrm{dy}\mathrm{`^`}\mathrm{dz}\mathrm{`^`}\mathrm{dw}$

ExteriorDerivative(alpha3);

$0\mathrm{dx}$

A := Matrix([[x, y], [z, w]]):

Omega := ExteriorDerivative(A);

$\mathrm{\Omega }≔\left[\begin{array}{cc}\mathrm{dx}& \mathrm{dy}\\ \mathrm{dz}& \mathrm{dw}\end{array}\right]$

with(DifferentialGeometry):

LieDerivativeCartan := proc(X, omega)

local a, b1, b2, b, c, d;

a := LieDerivative(X, omega);

b1 := Hook(X, ExteriorDerivative(omega));

b2 := ExteriorDerivative(Hook(X,omega));

b := b1 &plus b2;

c := a &minus b;

d := Tools:-DGinfo(c, "CoefficientSet");

end:

DGsetup([x, y, z, w], M):

X := evalDG(x^2*D_x - x*z*D_y + w*z*D_w);

$X≔x^2\mathrm{D\_x}-xz\mathrm{D\_y}\+wz\mathrm{D\_w}$

alpha := evalDG(z &mult dx &w dy);

$\mathrm{\α}≔z\mathrm{dx}\mathrm{`^`}\mathrm{dy}$

beta := evalDG(y^2 *dy &w dz &w dw);

$\mathrm{\β}≔y^2\mathrm{dy}\mathrm{`^`}\mathrm{dz}\mathrm{`^`}\mathrm{dw}$

LieDerivativeCartan(X, alpha);

$\left\{0\right\}$

LieDerivativeCartan(X, beta);

$\left\{0\right\}$

with(DifferentialGeometry):

DGsetup([x, y, u, v], E4):

P := evalDG([(-y^2 + x^2)*dy + (-y*u - x*v)*du + (-y*v - x*u)*dv, (x*v + y*u)*dx + (y*v + x*u)*dy + (v^2 - u^2)*dv]);

$P≔\left[\left(-y^2\+x^2\right)\mathrm{dy}\+\left(-yu-xv\right)\mathrm{du}\+\left(-yv-xu\right)\mathrm{dv}\,\left(xv\+yu\right)\mathrm{dx}\+\left(yv\+xu\right)\mathrm{dy}\+\left(v^2-u^2\right)\mathrm{dv}\right]$

ExteriorDerivative(P[1]) &wedge P[1] &wedge P[2];

$0\mathrm{dx}\mathrm{`^`}\mathrm{dy}\mathrm{`^`}\mathrm{du}\mathrm{`^`}\mathrm{dv}$

ExteriorDerivative(P[2]) &wedge P[1] &wedge P[2];

$0\mathrm{dx}\mathrm{`^`}\mathrm{dy}\mathrm{`^`}\mathrm{du}\mathrm{`^`}\mathrm{dv}$

f1 := x*y - u*v;

$\mathrm{f1}≔xy-uv$

f2 := 1/2*(x^2 + y^2 + u^2 + v^2);

$\mathrm{f2}≔\frac{x^2}{2}\+\frac{y^2}{2}\+\frac{u^2}{2}\+\frac{v^2}{2}$

GetComponents(ExteriorDerivative(f1), P);

$\left[\frac{v}{xv\+yu}\,\frac{y}{xv\+yu}\right]$

GetComponents(ExteriorDerivative(f2), P);

$\left[-\frac{u}{xv\+yu}\,\frac{x}{xv\+yu}\right]$

For each admissible parameter value x = (x1, x2, ... xr) and y = (y1, y2, ... yr), there is a parameter value z = (z1, z2, ... zr) such that A(x)A(y) = A(z).

For some value x0, A(x0) = I, the n x n identity matrix.

For each admissible parameter value x, there is a parameter value y such that A(y) = [A(x)]^(-1).

with(DifferentialGeometry):

DGsetup([x1, x2, x3], G);

$\mathrm{frame\; name:\; G}$

A := Matrix([[exp(-x1), -x1*exp(-x1), x2], [0, exp(-x1), x3], [0, 0, 1]]);

$A≔\left[\begin{array}{ccc}{\ⅇ}^{-\mathrm{x1}}& -\mathrm{x1}{\ⅇ}^{-\mathrm{x1}}& \mathrm{x2}\\ 0& {\ⅇ}^{-\mathrm{x1}}& \mathrm{x3}\\ 0& 0& 1\end{array}\right]$

B := eval(A, [x1 = y1, x2 = y2, x3 = y3]); C := eval(A, [x1 = z1, x2 = z2, x3 = z3]);

$B≔\left[\begin{array}{ccc}{\ⅇ}^{-\mathrm{y1}}& -\mathrm{y1}{\ⅇ}^{-\mathrm{y1}}& \mathrm{y2}\\ 0& {\ⅇ}^{-\mathrm{y1}}& \mathrm{y3}\\ 0& 0& 1\end{array}\right]$

$C≔\left[\begin{array}{ccc}{\ⅇ}^{-\mathrm{z1}}& -\mathrm{z1}{\ⅇ}^{-\mathrm{z1}}& \mathrm{z2}\\ 0& {\ⅇ}^{-\mathrm{z1}}& \mathrm{z3}\\ 0& 0& 1\end{array}\right]$

eq1 := convert(A.B - C ,set);

$\mathrm{eq1}≔\left\{0\,-{\ⅇ}^{-\mathrm{x1}}\mathrm{y1}{\ⅇ}^{-\mathrm{y1}}-\mathrm{x1}{\ⅇ}^{-\mathrm{x1}}{\ⅇ}^{-\mathrm{y1}}\+\mathrm{z1}{\ⅇ}^{-\mathrm{z1}}\,{\ⅇ}^{-\mathrm{x1}}{\ⅇ}^{-\mathrm{y1}}-{\ⅇ}^{-\mathrm{z1}}\,{\ⅇ}^{-\mathrm{x1}}\mathrm{y2}-\mathrm{x1}{\ⅇ}^{-\mathrm{x1}}\mathrm{y3}\+\mathrm{x2}-\mathrm{z2}\,{\ⅇ}^{-\mathrm{x1}}\mathrm{y3}\+\mathrm{x3}-\mathrm{z3}\right\}$

MultiplicationRule := solve(eq1, {z1, z2, z3});

$\mathrm{MultiplicationRule}≔\left\{\mathrm{z3}\=\frac{\mathrm{y3}\+\mathrm{x3}{\ⅇ}^{\mathrm{x1}}}{{\ⅇ}^{\mathrm{x1}}}\,\mathrm{z1}\=\mathrm{x1}\+\mathrm{y1}\,\mathrm{z2}\=-\frac{-\mathrm{y2}\+\mathrm{x1}\mathrm{y3}-\mathrm{x2}{\ⅇ}^{\mathrm{x1}}}{{\ⅇ}^{\mathrm{x1}}}\right\}$

eq2 := convert(A^(-1)-B, set);

$\mathrm{eq2}≔\left\{0\,-\frac{\mathrm{x3}}{{\ⅇ}^{-\mathrm{x1}}}-\mathrm{y3}\,\frac{1}{{\ⅇ}^{-\mathrm{x1}}}-{\ⅇ}^{-\mathrm{y1}}\,\frac{\mathrm{x1}}{{\ⅇ}^{-\mathrm{x1}}}\+\mathrm{y1}{\ⅇ}^{-\mathrm{y1}}\,-\frac{\mathrm{x1}\mathrm{x3}\+\mathrm{x2}}{{\ⅇ}^{-\mathrm{x1}}}-\mathrm{y2}\right\}$

InverseFormula := solve(eq2, {y1,y2,y3});

$\mathrm{InverseFormula}≔\left\{\mathrm{y2}\=-\mathrm{x1}\mathrm{x3}{\ⅇ}^{\mathrm{x1}}-\mathrm{x2}{\ⅇ}^{\mathrm{x1}}\,\mathrm{y1}\=-\mathrm{x1}\,\mathrm{y3}\=-\mathrm{x3}{\ⅇ}^{\mathrm{x1}}\right\}$

with(Tools):

dA := ExteriorDerivative(A);

$\mathrm{dA}≔\left[\begin{array}{ccc}-{\ⅇ}^{-\mathrm{x1}}\mathrm{dx1}& {\ⅇ}^{-\mathrm{x1}}\left(-1\+\mathrm{x1}\right)\mathrm{dx1}& \mathrm{dx2}\\ 0\mathrm{dx1}& -{\ⅇ}^{-\mathrm{x1}}\mathrm{dx1}& \mathrm{dx3}\\ 0\mathrm{dx1}& 0\mathrm{dx1}& 0\mathrm{dx1}\end{array}\right]$

OmegaL0 := (A^(-1)) &MatrixMult dA;

$\mathrm{OmegaL0}≔\left[\begin{array}{ccc}-\mathrm{dx1}& -\mathrm{dx1}& {\ⅇ}^{\mathrm{x1}}\mathrm{dx2}\+\mathrm{x1}{\ⅇ}^{\mathrm{x1}}\mathrm{dx3}\\ 0\mathrm{dx1}& -\mathrm{dx1}& {\ⅇ}^{\mathrm{x1}}\mathrm{dx3}\\ 0\mathrm{dx1}& 0\mathrm{dx1}& 0\mathrm{dx1}\end{array}\right]$

OmegaR0 := dA &MatrixMult (A^(-1));

$\mathrm{OmegaR0}≔\left[\begin{array}{ccc}-\mathrm{dx1}& -\mathrm{dx1}& \left(\mathrm{x3}\+\mathrm{x2}\right)\mathrm{dx1}\+\mathrm{dx2}\\ 0\mathrm{dx1}& -\mathrm{dx1}& \mathrm{x3}\mathrm{dx1}\+\mathrm{dx3}\\ 0\mathrm{dx1}& 0\mathrm{dx1}& 0\mathrm{dx1}\end{array}\right]$

ExteriorDerivative(OmegaL0) &MatrixPlus (OmegaL0 &MatrixWedge OmegaL0);

$\left[\begin{array}{ccc}0\mathrm{dx1}\mathrm{`^`}\mathrm{dx2}& 0\mathrm{dx1}\mathrm{`^`}\mathrm{dx2}& 0\mathrm{dx1}\mathrm{`^`}\mathrm{dx2}\\ 0\mathrm{dx1}\mathrm{`^`}\mathrm{dx2}& 0\mathrm{dx1}\mathrm{`^`}\mathrm{dx2}& 0\mathrm{dx1}\mathrm{`^`}\mathrm{dx2}\\ 0\mathrm{dx1}\mathrm{`^`}\mathrm{dx2}& 0\mathrm{dx1}\mathrm{`^`}\mathrm{dx2}& 0\mathrm{dx1}\mathrm{`^`}\mathrm{dx2}\end{array}\right]$

ExteriorDerivative(OmegaR0) &MatrixMinus (OmegaR0 &MatrixWedge OmegaR0);

$\left[\begin{array}{ccc}0\mathrm{dx1}\mathrm{`^`}\mathrm{dx2}& 0\mathrm{dx1}\mathrm{`^`}\mathrm{dx2}& 0\mathrm{dx1}\mathrm{`^`}\mathrm{dx2}\\ 0\mathrm{dx1}\mathrm{`^`}\mathrm{dx2}& 0\mathrm{dx1}\mathrm{`^`}\mathrm{dx2}& 0\mathrm{dx1}\mathrm{`^`}\mathrm{dx2}\\ 0\mathrm{dx1}\mathrm{`^`}\mathrm{dx2}& 0\mathrm{dx1}\mathrm{`^`}\mathrm{dx2}& 0\mathrm{dx1}\mathrm{`^`}\mathrm{dx2}\end{array}\right]$

OmegaL := [(-1) &mult OmegaL0[1, 1], OmegaL0[1, 3], OmegaL0[2, 3]];

$\mathrm{OmegaL}≔\left[\mathrm{dx1}\,{\ⅇ}^{\mathrm{x1}}\mathrm{dx2}\+\mathrm{x1}{\ⅇ}^{\mathrm{x1}}\mathrm{dx3}\,{\ⅇ}^{\mathrm{x1}}\mathrm{dx3}\right]$

OmegaR := [(-1) &mult OmegaR0[1, 1], OmegaR0[1, 3], OmegaR0[2, 3]];

$\mathrm{OmegaR}≔\left[\mathrm{dx1}\,\left(\mathrm{x3}\+\mathrm{x2}\right)\mathrm{dx1}\+\mathrm{dx2}\,\mathrm{x3}\mathrm{dx1}\+\mathrm{dx3}\right]$

XL := DualBasis(OmegaL);

$\mathrm{XL}≔\left[\mathrm{D\_x1}\,{\ⅇ}^{-\mathrm{x1}}\mathrm{D\_x2}\,-\mathrm{x1}{\ⅇ}^{-\mathrm{x1}}\mathrm{D\_x2}\+{\ⅇ}^{-\mathrm{x1}}\mathrm{D\_x3}\right]$

XR := DualBasis(OmegaR);

$\mathrm{XR}≔\left[\mathrm{D\_x1}\+\left(-\mathrm{x3}-\mathrm{x2}\right)\mathrm{D\_x2}-\mathrm{x3}\mathrm{D\_x3}\,\mathrm{D\_x2}\,\mathrm{D\_x3}\right]$

Matrix(3, 3, (i, j) -> LieDerivative(XR[i], OmegaL[j]));

$\left[\begin{array}{ccc}0\mathrm{dx1}& 0\mathrm{dx1}& 0\mathrm{dx1}\\ 0\mathrm{dx1}& 0\mathrm{dx1}& 0\mathrm{dx1}\\ 0\mathrm{dx1}& 0\mathrm{dx1}& 0\mathrm{dx1}\end{array}\right]$

Matrix(3, 3, (i, j) -> LieDerivative(XL[i], OmegaR[j]));

$\left[\begin{array}{ccc}0\mathrm{dx1}& 0\mathrm{dx1}& 0\mathrm{dx1}\\ 0\mathrm{dx1}& 0\mathrm{dx1}& 0\mathrm{dx1}\\ 0\mathrm{dx1}& 0\mathrm{dx1}& 0\mathrm{dx1}\end{array}\right]$

Matrix(3, 3, (i, j) -> LieBracket(XL[i], XR[j]));

$\left[\begin{array}{ccc}0\mathrm{D\_x1}& 0\mathrm{D\_x1}& 0\mathrm{D\_x1}\\ 0\mathrm{D\_x1}& 0\mathrm{D\_x1}& 0\mathrm{D\_x1}\\ 0\mathrm{D\_x1}& 0\mathrm{D\_x1}& 0\mathrm{D\_x1}\end{array}\right]$

with(DifferentialGeometry):

DGsetup([x, y, z, w], E4):

omega1 := evalDG(y*dx &w dz &w dw + x*dy &w dz &w dw);

$\mathrm{\ω1}≔y\mathrm{dx}\mathrm{`^`}\mathrm{dz}\mathrm{`^`}\mathrm{dw}\+x\mathrm{dy}\mathrm{`^`}\mathrm{dz}\mathrm{`^`}\mathrm{dw}$

ExteriorDerivative(omega1);

$0\mathrm{dx}\mathrm{`^`}\mathrm{dy}\mathrm{`^`}\mathrm{dz}\mathrm{`^`}\mathrm{dw}$

eta1 := DeRhamHomotopy(omega1);

$\mathrm{\η1}≔\frac{wy\mathrm{dx}\mathrm{`^`}\mathrm{dz}}{4}-\frac{yz\mathrm{dx}\mathrm{`^`}\mathrm{dw}}{4}\+\frac{wx\mathrm{dy}\mathrm{`^`}\mathrm{dz}}{4}-\frac{xz\mathrm{dy}\mathrm{`^`}\mathrm{dw}}{4}\+\frac{xy\mathrm{dz}\mathrm{`^`}\mathrm{dw}}{2}$

check := ExteriorDerivative(eta1) &minus omega1;

$\mathrm{check}≔0\mathrm{dx}\mathrm{`^`}\mathrm{dy}\mathrm{`^`}\mathrm{dz}$

The option initialpoint = x0 changes the default integration path tx (a straight line from the origin to x) to tx + (1 - t)x0 (a straight line from the point x0 to x).  This option is useful when the differential form is singular at the origin.

The option integrationlimits = [1, infinity] changes the integration path to tx, t = 1 .. infinity.  This option can be very useful when the coefficients of the differential form -> 0 as x-> infinity (more precisely, if F is any coefficient of the differential form, then it is necessary that tF(tx) ~ t^-(1 + epsilon) as t -> infinity for the integral in the homotopy formula to converge).

The option path = "zigzag" changes the integration path to a sequence of coordinates lines.  For example, if the coordinates are [x, y, z], the integration path is the sequence of 3 straight lines from [0, 0, 0] to [x, 0, 0], from [x, 0, 0] to [x, y, 0], and [x, y, 0] to [x, y, z].  The order in which these coordinates lines are chosen may be customized with the variableorder = [var1, var2, ... ] option.  The use of the path = "zigzag" option often results in a simpler output from the DeRhamHomotopy procedure.

omega2 := evalDG(x*dx &w dy);

$\mathrm{\ω2}≔x\mathrm{dx}\mathrm{`^`}\mathrm{dy}$

eta2a := DeRhamHomotopy(omega2);

$\mathrm{eta2a}≔-\frac{xy\mathrm{dx}}{3}\+\frac{x^2\mathrm{dy}}{3}$

eta2b := DeRhamHomotopy(omega2, initialpoint = [x = 1, y = 2]);

$\mathrm{eta2b}≔\left(-\frac{1}{6}y-\frac{1}{3}xy\+\frac{1}{3}\+\frac{2}{3}x\right)\mathrm{dx}\+\left(-\frac{1}{6}-\frac{1}{6}x\+\frac{1}{3}{x}^2\right)\mathrm{dy}$

eta2c := DeRhamHomotopy(omega2, path = "zigzag");

$\mathrm{eta2c}≔-xy\mathrm{dx}$

eta2d := DeRhamHomotopy(omega2, path = "zigzag", variableorder = [y, x, w, z]);

$\mathrm{eta2d}≔\frac{x^2\mathrm{dy}}{2}$

eta2e := DeRhamHomotopy(omega2, path = "zigzag", variableorder = [y, x, w, z], initialpoint = [x = 1, y = 2]);

$\mathrm{eta2e}≔\left(-\frac{1}{2}\+\frac{x^2}{2}\right)\mathrm{dy}$

ExteriorDerivative([eta2a, eta2b, eta2c, eta2d, eta2e]);

$\left[x\mathrm{dx}\mathrm{`^`}\mathrm{dy}\,x\mathrm{dx}\mathrm{`^`}\mathrm{dy}\,x\mathrm{dx}\mathrm{`^`}\mathrm{dy}\,x\mathrm{dx}\mathrm{`^`}\mathrm{dy}\,x\mathrm{dx}\mathrm{`^`}\mathrm{dy}\right]$

omega3 := evalDG(1/x^3 *dx &w dy);

$\mathrm{\ω3}≔\frac{\mathrm{dx}\mathrm{`^`}\mathrm{dy}}{x^3}$

eta3 := DeRhamHomotopy(omega3, integrationlimits = [1, infinity]);

$\mathrm{\η3}≔-\frac{y\mathrm{dx}}{x^3}\+\frac{\mathrm{dy}}{x^2}$

omega4 := evalDG(1/x *dx &w dy);

$\mathrm{\ω4}≔\frac{\mathrm{dx}\mathrm{`^`}\mathrm{dy}}{x}$

eta4a := DeRhamHomotopy(omega4, path = "zigzag");

$\mathrm{eta4a}≔-\frac{y\mathrm{dx}}{x}$

eta4b := DeRhamHomotopy(omega4, path = "zigzag", initialpoint = [x = 1], variableorder = [y, x, w, z]);

$\mathrm{eta4b}≔\ln \left(x\right)\mathrm{dy}$