IntegralManifold - Maple Help

All Products Maple MapleSim

Home : Support : Online Help : Mathematics : DifferentialGeometry : ExteriorDifferentialSystems : IntegralManifold

ExteriorDifferentialSystems[IntegralManifold] - find the integral manifolds for an exterior differential system

Calling Sequences

IntegralManifold(Omega, P, options)

IntegralManifold(Omega, phi, options)

Parameters

Omega - a list of differential forms on a manifold M

P - a name or string, the name of an initialized manifold to be used for the domain of the integral manifold

phi - a transformation, with range M, and depending upon a number of arbitrary functions

option - (optional keyword arguments) ansatz, unknowns, auxiliaryequations, output

Description

•

Let $&imagline;$ be an exterior differential system defined on a manifold $M$ . and let $P$ be a manifold. An integral manifold of $&imagline;$ is a smooth immersion $φ &colon; P \to M$ such that the pullback $φ^{*} (ω) = 0$ for all $ω \in &imagline;$ . These conditions translate into a system of first-order PDE for the components of the transformation $φ^{} &period;$ The command IntegralManifold uses pdsolve to integrate, if possible, this PDE system and return the integral manifold of $&imagline;$ as a transformation from $P$ to $M$ .

•

For the first calling sequence, general integral manifolds $φ &colon; P \to M$ are sought. Here it is often the case that Maple will be unable to find any integral manifolds. The keyword argument ansatz = list(equations) may be used to specify some of the components of $φ$ and thereby reduce the complexity of the PDE to be solved.

•

For the second calling sequence an integral manifold ansatz is specified explicitly by a transformation $φ &colon; P \to M$ . For this calling sequence the unknown functions appearing in $φ &colon; P \to M$ should be explicitly declared with the keyword argument unknowns. For the second calling sequence, additional constraints (equations or inequalities) may be imposed with the auxiliaryequations keyword.

•	For either calling sequence, with the keyword argument output = "equations", the determining PDE system for the integral manifolds is returned.

See Also

DifferentialGeometry

ExteriorDifferentialSystems

Examples

>	with(DifferentialGeometry): with(ExteriorDifferentialSystems):

Example 1.

In this example we find the integral curves (1-dimensional integral manifolds) for the Pfaffian system defined by a single 1-form in 2 variables. Define the manifold on which the Pfaffian system is defined.

>	DGsetup([x, y], M1);

$frame name: M1$

(1)

Define the parameter space for the integral manifolds.

M1 >	DGsetup([t], P1);

$frame name: P1$

(2)

The Pfaffian system $&imagline;$ is generated by the following 1-forms.

M1 >	Omega := [(x^2 + y^2)dx - 2xy dy];

$Ω := [(x^{2} + y^{2}) dx - 2 x y dy]$

(3)

Here are the integral manifolds for $ℐ$ found by the first calling sequence.

M1 >	Sigma := IntegralManifold(Omega, P1);

$Σ := [x = 0, y = 0], [x = I_C1, y =_C1], [x = - I_C1, y =_C1], [x = - \frac{1}{2}_C1 + \frac{1}{2} \sqrt{{_C1}^{2} + 4 {F2 (t)}^{2}}, y = F2 (t)], [x = - \frac{1}{2}_C1 - \frac{1}{2} \sqrt{{_C1}^{2} + 4 {F2 (t)}^{2}}, y = F2 (t)]$

(4)

Use the Pullback command to check that the third transformation is an integral manifold.

P1 >	Pullback(Sigma[3], Omega);

$[0 dt]$

(5)

We can specify that we want integral manifolds which are graphs of functions $y = F (x)$ using the keyword argument ansatz.

P1 >	IntegralManifold(Omega, P1, ansatz = [x = t]);

$[x = t, y = - \sqrt{t^{2} + t_C1}], [x = t, y = \sqrt{t^{2} + t_C1}]$

(6)

We calculate the integral manifolds of $&imagline;$ using the second calling sequence. First define a general transformation from P1 to M1.

P1 >	phi := Transformation(P1, M1, [x = f(t), y = g(t)]);

$φ := [x = f (t), y = g (t)]$

(7)

M1 >	IntegralManifold(Omega, phi);

$[x = 0, y = g (t)], [x =_C1, y = 0], [x = f (t), y = - \sqrt{{f (t)}^{2} + f (t)_C1}], [x = f (t), y = \sqrt{{f (t)}^{2} + f (t)_C1}]$

(8)

Here again are the integral manifolds which are graphs of functions $y = F (x)$ .

M1 >	phi := Transformation(P1, M1, [x = t, y = g(t)]);

$φ := [x = t, y = g (t)]$

(9)

P1 >	IntegralManifold(Omega, phi);

$[x = t, y = - \sqrt{t^{2} + t_C1}], [x = t, y = \sqrt{t^{2} + t_C1}]$

(10)

Let us use polar coordinates to parameterize the integral manifolds in terms of functions $r (t)$ and $θ (t)$ . We see that no solutions are found.

P1 >	phi2 := Transformation(P1, M1, [x = r(t)cos(theta(t)), y = r(t)sin(theta(t))]);

$φ2 := [x = r (t) \cos (θ (t)), y = r (t) \sin (θ (t))]$

(11)

P1 >	Sigma := IntegralManifold(Omega, phi2);

$Σ :=$

(12)

Simplify the defining equations for the integral manifolds by setting $θ (t) = t$ .

P1 >	phi3 := Transformation(P1, M1, [x = r(t)cos(t), y = r(t)sin(t)]);

$φ3 := [x = r (t) \cos (t), y = r (t) \sin (t)]$

(13)

P1 >	IntegralManifold(Omega, phi3);

$[x = 0, y = 0], [x = \frac{_C1 {\cos (t)}^{2}}{\cos (2 t)}, y = \frac{_C1 \cos (t) \sin (t)}{\cos (2 t)}]$

(14)

Use the keyword argument auxiliaryequations to find the integral manifold through the point $x = 0, y = 0$ .

P1 >	IntegralManifold(Omega, phi3, auxiliaryequations = {r(0) = 1});

$[x = \frac{{\cos (t)}^{2}}{\cos (2 t)}, y = \frac{\cos (t) \sin (t)}{\cos (2 t)}]$

(15)

Example 2.

In this example we look for integral manifolds of dimensions 1 and 2 for a Pfaffian system defined by a single 1 form in 3 variables. Define the spaces we need.

P1 >	DGsetup([x, y, z], M2);

$frame name: M2$

(16)

M >	DGsetup([t], P1);

$frame name: P1$

(17)

P1 >	DGsetup([s, t], P2);

$frame name: P2$

(18)

The Pfaffian system $&imagline;$ is generated by a single 1-form.

P2 >	Omega := [(y + z)dx + (x + z)dy + (x + y)*dz];

$Ω := [(y + z) dx + (x + z) dy + (x + y) dz]$

(19)

Here are the general 1-dimensional integral manifolds.

M >	phi1 := Transformation(P1, M2, [x = f(t), y = g(t), z = k(t)]);

$φ1 := [x = f (t), y = g (t), z = k (t)]$

(20)

P1 >	IntegralManifold(Omega, phi1);

$[x = 0, y = 0, z = k (t)], [x =_C1, y = -_C1, z = k (t)], [x = f (t), y = g (t), z = \frac{- g (t) f (t) +_C1}{f (t) + g (t)}]$

(21)

Here are the 2-dimensional integral manifolds which are given by graphs of functions $z = F (x, y)$ .

P1 >	phi2 := Transformation(P2, M2, [x = s, y = t, z = f(s, t)]);

$φ2 := [x = s, y = t, z = f (s, t)]$

(22)

P1 >	Sigma := IntegralManifold(Omega, phi2);

$Σ := [x = s, y = t, z = \frac{- t s +_C1}{s + t}]$

(23)

Check this last result.

P2 >	Pullback(Sigma, Omega);

$[0 ds]$

(24)

Example 3.

In this example we write the solutions for the linear 3rd order ODE $y''' - y' = 0$ as integral manifolds of a rank 3 Pfaffian system on a 4-dimensional manifold.

M3 >	DGsetup([x], P3);

$frame name: P3$

(25)

P3 >	DGsetup([x, y, y1, y2], M3);

$frame name: M3$

(26)

The Pfaffian system is

P3 >	Omega := evalDG([dy - y1dx, dy1- y2dx, dy2 - y1*dx]);

$Ω := [- y1 dx + dy, - y2 dx + dy1, - y1 dx + dy2]$

(27)

and the integral manifolds are

M3 >	IntegralManifold(Omega, P3, ansatz = [x = x]);

$[x = x, y =_C1 {&ExponentialE;}^{- x} +_C2 {&ExponentialE;}^{x} +_C3, y1 = -_C1 {&ExponentialE;}^{- x} +_C2 {&ExponentialE;}^{x}, y2 =_C1 {&ExponentialE;}^{- x} +_C2 {&ExponentialE;}^{x}]$

(28)

We remark that in the exterior differential system setting, a solution requires the specification of all the variables on the underlying manifold, and not solely the specification of the dependent variable.

Example 4.

Second order partial differential equations of the form $u_{xy} = f (x, y, u, u_{x}, u_{y})$ can always be re-formulated as a differential system generated by a 1-form and two 2-forms on a 5-dimensional manifold. We illustrate this using the equation $u_{xy} = \frac{2 u}{{(x + y)}^{2}}$ .

P3 >	DGsetup([x, y], P4);

$frame name: P4$

(29)

P4 >	DGsetup([x, y, u, p, q], M4);

$frame name: M4$

(30)

Here are the generators of the differential system $&imagline;$ . Since there are 2-form generators the EDS $ℐ$ is not a Pfaffian system.

M4 >	Omega := evalDG([du -pdx -qdy, (dp - 2u/(x+y)^2dy) &w dx , (dq - 2u/(x+y)^2dx) &w dy]);

$Ω := [- p dx - q dy + du, \frac{2 u dx ⋀ dy}{{(x + y)}^{2}} - dx ⋀ dp, - \frac{2 u dx ⋀ dy}{{(x + y)}^{2}} - dy ⋀ dq]$

(31)

We look for integral manifolds which define graphs of functions $u = U (x, y)$ .

M4 >	Sigma := IntegralManifold(Omega, P4, ansatz = [x = x, y = y]);

$Σ := [x = x, y = y, u = \frac{(x + y) (\frac{&DifferentialD;}{&DifferentialD; x}_F1 (x)) + (x + y) (\frac{&DifferentialD;}{&DifferentialD; y}_F2 (y)) - 2_F2 (y) - 2_F1 (x)}{2 x + 2 y}, p = \frac{1}{2} \frac{{(x + y)}^{2} (\frac{&DifferentialD;}{&DifferentialD; x} (\frac{&DifferentialD;}{&DifferentialD; x}_F1 (x))) + (- 2 x - 2 y) (\frac{&DifferentialD;}{&DifferentialD; x}_F1 (x)) + 2_F2 (y) + 2_F1 (x)}{{(x + y)}^{2}}, q = \frac{1}{2} \frac{{(x + y)}^{2} (\frac{&DifferentialD;}{&DifferentialD; y} (\frac{&DifferentialD;}{&DifferentialD; y}_F2 (y))) + (- 2 x - 2 y) (\frac{&DifferentialD;}{&DifferentialD; y}_F2 (y)) + 2_F2 (y) + 2_F1 (x)}{{(x + y)}^{2}}]$

(32)

Check this solution.

P4 >	Pullback(Sigma, Omega);

$[0 dx, 0 dx ⋀ dy, 0 dx ⋀ dy]$

(33)

Download Help Document

Maple

Erweiterungen für Maple

Student Success Platform

Verbesserung der Studienerfolgsquote

Maple Flow

MapleSim

Beratende Dienstleistungen

Produkte zur Online-Ausbildung

Ausbildung

Industrie

Automobil und Luftfahrt

Robotik

Maschinendesign & industrielle Automation

Andere

Lösungen für die Industrie

Kaufen: Einzelheiten und Preise

Kaufen

Institutionelle Studentenlizenzierung

Elite-Wartungsprogramm

Support

Produktschulung

Online Hilfe zu Produkten

Webinare und Veranstaltungen

Veröffentlichungen

Content Hubs

Anwendungsbeispiele

Community

Über Maplesoft

Pressezentrum

User Community

Kontakt