In some cases, a nonlinear ODE that cannot be solved using standard methods can still be multiplied by an appropriate factor so that after differentiation (one or two times), the resulting expression contains a linear ODE of higher order as a factor. Solving this linear ODE permits expressing the solution to the original problem explicitly and in rather compact manner.

Examples

PDEtools:-declare(y(x), prime=x);

$y\left(x\right)\mathrm{will\; now\; be\; displayed\; as}y$

$\mathrm{derivatives\; with\; respect\; to}x\mathrm{of\; functions\; of\; one\; variable\; will\; now\; be\; displayed\; with\; \text{'}}$

The following shows a first order ODE nonlinear in $\mathrm{y\text{'}}$, as an arbitrary function $G$ of two arguments, and its corresponding new solution.

ode[1] := G((2*y(x)-2+diff(y(x),x)*x)*x^3/(3*x^4+2*x^3),-x^3*(-y(x)+1+(x+1)*diff(y(x),x))/(3*x+2)) = 0;

${\mathrm{ode}}_1≔G\left(\frac{\left(2y-2+\mathrm{y\text{'}}x\right)x^3}{3x^4+2x^3}\,-\frac{x^3\left(-y+1+\left(x+1\right)\mathrm{y\text{'}}\right)}{3x+2}\right)=0$

sol[1] := dsolve(ode[1], implicit);

${\mathrm{sol}}_1≔G\left(-\frac{-y+\frac{\mathrm{c\_\_1}}{x^2}+1}{x+1}\,\mathrm{c\_\_1}\right)=0$

So, for any form of $G$ in ode[1], the same $G$ in the output above solves the problem. ODE solutions can be verified as usual with odetest.

odetest(sol[1], ode[1]);

$0$

Here are two nonlinear ODE examples, of third and fourth order, extracted from scientific publications related to applications, and their new solutions computed quickly and in compact manner using linearization by differentiation.

ode[2] := diff(y(x),x,x,x) = 1/8*(-8*x*diff(y(x),x,x)*diff(y(x),x) + 4*x^2*diff(y(x),x,x)^2 + diff(y(x),x)^2 + 12*y(x))/x^2/diff(y(x),x);

${\mathrm{ode}}_2≔\mathrm{y\text{'}\text{'}\text{'}}=\frac{-8x\mathrm{y\text{'}\text{'}}\mathrm{y\text{'}}+4x^2{\mathrm{y\text{'}\text{'}}}^2+{\mathrm{y\text{'}}}^2+12y}{8x^2\mathrm{y\text{'}}}$

dsolve(ode[2]);

$y=x^2+\frac{4x^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}\mathrm{c\_\_1}}{3}-4\sqrt{x}\mathrm{c\_\_2}+\mathrm{c\_\_3}x-\frac{4\mathrm{c\_\_1}\mathrm{c\_\_2}}{3}-\frac{{\mathrm{c\_\_3}}^2}{12}$

ode[3] := diff(y(x),x,x,x,x) = 1/2*(2*diff(y(x),x,x,x)*diff(y(x),x)-diff(y(x),x,x)^2+c^4*y(x)^2)/y(x);

${\mathrm{ode}}_3≔\mathrm{y\text{'}\text{'}\text{'}\text{'}}=\frac{2\mathrm{y\text{'}\text{'}\text{'}}\mathrm{y\text{'}}-{\mathrm{y\text{'}\text{'}}}^2+c^4{y}^2}{2y}$

dsolve(ode[3]);

For various nonlinear ODE initial value problems (ODE-IVP), a rational solution exists, but the general ODE solution involves elliptic or special functions, making it difficult to compute the simpler form when adjusting the integration constants to match the initial conditions. In Maple 13, dsolve automatically explores the ODE symmetries to compute an ODE-IVP solution in its simpler rational form directly, even if the general solution is entirely out of reach.

Examples

ode[4] := diff(y(x), x, x) + 3*(diff(y(x), x))/x - 8*y(x)^3/x^6 = 0;

${\mathrm{ode}}_4≔\mathrm{y\text{'}\text{'}}+\frac{3\mathrm{y\text{'}}}{x}-\frac{8y^3}{x^6}=0$

ic[4] := y(1) = -1/2, D(y)(1) = -1/2;

${\mathrm{ic}}_4≔y\left(1\right)=-\frac{1}{2},\mathrm{D}\left(y\right)\left(1\right)=-\frac{1}{2}$

The general solution of ode[4] involves the inverse of an elliptic integral, represented by the elliptic function JacobiSN.

dsolve(ode[4]);

$y=\mathrm{c\_\_2}\mathrm{JacobiSN}\left(\left(-\frac{\mathrm{I}}{x^2}+\mathrm{c\_\_1}\right)\mathrm{c\_\_2}\,\mathrm{I}\right)$

It is not easy to adjust the integration constants $\mathrm{C1}$, $\mathrm{C2}$ so that the preceding solution satisfies the conditions y(1) = -1/2, D(y)(1) = -1/2. However, by exploring the ODE symmetries,

DEtools[symgen](ode[4]);

$\left[\mathrm{\_\ξ}=x^3\,\mathrm{\_\η}=0\right],\left[\mathrm{\_\ξ}=\frac{x}{2}\,\mathrm{\_\η}=y\right]$

dsolve can compute directly the following simple solution to the whole ODE initial value problem.

sol_ic[4] := dsolve([ode[4], ic[4]]);

${\mathrm{sol\_ic}}_4≔y=-\frac{x^2}{x^2+1}$

You can use odetest to test solutions against the initial conditions.

odetest(sol_ic[4], [ode[4], ic[4]]);

$\left[0\,0\,0\right]$

ode[5] := diff(y(x), x,x,x) - diff(y(x), x,x)*y(x) + diff(y(x),x)^2 = 0;

${\mathrm{ode}}_5≔\mathrm{y\text{'}\text{'}\text{'}}-\mathrm{y\text{'}\text{'}}y+{\mathrm{y\text{'}}}^2=0$

ic[5] := y(0) = 1, D(y)(0) = 1/6;

${\mathrm{ic}}_5≔y\left(0\right)=1,\mathrm{D}\left(y\right)\left(0\right)=\frac{1}{6}$

For ode[5] alone dsolve obtains only a reduction of order, which contains an ODE of Abel type for _g(_f) whose solution is not known.

dsolve(ode[5]);

$y=\left({\ⅇ}^{\int \mathrm{\_g}\left(\mathrm{\_f}\right)\ⅆ\mathrm{\_f}+\mathrm{c\_\_2}}\right)\mathbf{where}\left[\left\{{\mathrm{\_g}}_{\mathrm{\_f}}=\left(6\mathrm{\_f}-1\right){\mathrm{\_g}\left(\mathrm{\_f}\right)}^3+\frac{\left(7\mathrm{\_f}-1\right){\mathrm{\_g}\left(\mathrm{\_f}\right)}^2}{\mathrm{\_f}}+\frac{\mathrm{\_g}\left(\mathrm{\_f}\right)}{\mathrm{\_f}}\right\}\,\left\{\mathrm{\_f}=\frac{\mathrm{y\text{'}}}{y^2}\,\mathrm{\_g}\left(\mathrm{\_f}\right)=\frac{y^2}{\frac{y\mathrm{y\text{'}\text{'}}}{\mathrm{y\text{'}}}-2\mathrm{y\text{'}}}\right\}\,\left\{x=\int \frac{\mathrm{\_g}\left(\mathrm{\_f}\right)}{\mathrm{\_f}{\ⅇ}^{\int \mathrm{\_g}\left(\mathrm{\_f}\right)\ⅆ\mathrm{\_f}+\mathrm{c\_\_2}}}\ⅆ\mathrm{\_f}+\mathrm{c\_\_1}\,y={\ⅇ}^{\int \mathrm{\_g}\left(\mathrm{\_f}\right)\ⅆ\mathrm{\_f}+\mathrm{c\_\_2}}\right\}\right]$

This result is the best one achievable at present but there is no useful way to adjust it to match the conditions y(0) = 1, D(y)(0) = 1/6. In Maple 13, however, dsolve first detects the symmetries of ode[5] and instead of just failing to compute the general solution, it explores these symmetries, solving the problem as a whole.

sol_ic[5] := dsolve([ode[5], ic[5]]);

${\mathrm{sol\_ic}}_5≔y=-\frac{6}{x-6}$

map(odetest, [sol_ic[5]], [ode[5], ic[5]]);

$\left[\left[0\,0\,0\right]\right]$

The existing routines in dsolve for this problem were optimized to solve more complicated problems and in simpler form, or using simpler special functions.

Example

ode[6] := diff(y(x),x,x) + tan(x)*diff(y(x),x) + a^2*cos(x)^2*sin(x)^(2*n-2)*y(x) = 0;

${\mathrm{ode}}_6≔\mathrm{y\text{'}\text{'}}+\tan \left(x\right)\mathrm{y\text{'}}+a^2{\cos \left(x\right)}^2{\sin \left(x\right)}^{2n-2}y=0$

For the ode[6], the solution in Maple 12 involves hypergeometric functions. In Maple 13, the solution is computed in terms of simpler Bessel functions.

dsolve(ode[6]);

$y=\mathrm{c\_\_1}\sqrt{\sin \left(x\right)}\mathrm{BesselJ}\left(\frac{1}{2n}\,\frac{{\sin \left(x\right)}^{n}a}{n}\right)+\mathrm{c\_\_2}\sqrt{\sin \left(x\right)}\mathrm{BesselY}\left(\frac{1}{2n}\,\frac{{\sin \left(x\right)}^{n}a}{n}\right)$

Maple's dsolve started exploring dynamical symmetries in 1997. The related solving approach, however, is algebraically complicated. For Maple 13, corresponding routines were enhanced substantially to handle these kinds of problems, taking advantage of the properties of subfamilies of these symmetries (for example, self-invariant contact symmetries). In this way, new or concretely simpler solutions can now be computed.

Example

ode[7] := diff(y(x), x,x) = diff(y(x), x)+(ln(diff(y(x), x))-x)*diff(y(x), x)^2/(y(x)-diff(y(x), x));

${\mathrm{ode}}_7≔\mathrm{y\text{'}\text{'}}=\mathrm{y\text{'}}+\frac{\left(\ln \left(\mathrm{y\text{'}}\right)-x\right){\mathrm{y\text{'}}}^2}{y-\mathrm{y\text{'}}}$

This ODE admits only one point symmetry, but in addition it has a computable self-invariant contact (dynamical) symmetry that involves $\mathrm{y\text{'}}$.

DEtools[symgen](ode[7]);

$\left[\mathrm{\_\ξ}=1\,\mathrm{\_\η}=y\right],\left[\mathrm{\_\ξ}=0\,\mathrm{\_\η}=-\ln \left(\mathrm{\_y1}\right)+x\right]$

Remarkably, the point symmetry (first one in the preceding output) is of no use to integrate the equation; it leads to an intractable first order ODE. The dynamical symmetry, on the other hand, results in the following new implicit solution, involving the Ei (exponential integral) composed with the LambertW function.

dsolve(ode[7], implicit);

${\mathrm{Ei}}_1\left(-1-\mathrm{c\_\_1}{\ⅇ}^{-x}-\mathrm{LambertW}\left(-y{\ⅇ}^{-x-\mathrm{c\_\_1}{\ⅇ}^{-x}-1}\right)\right)\mathrm{c\_\_1}-\frac{y}{\mathrm{LambertW}\left(-y{\ⅇ}^{-x-\mathrm{c\_\_1}{\ⅇ}^{-x}-1}\right)}-\mathrm{c\_\_2}=0$

For ODEs of all differential orders, dsolve can now compute parametric solutions directly from their symmetries. This is useful in various cases where the standard solution, of the form $y\left(x\right)\=\mathrm{...}$, involves the algebraic inversion of special functions or integrals, while the parametric solution is simpler.

Example

ode[8] := diff(y(x),x,x) = y(x)+_F1(diff(y(x),x)-y(x));

${\mathrm{ode}}_8≔\mathrm{y\text{'}\text{'}}=y+\mathrm{f\_\_1}\left(-y+\mathrm{y\text{'}}\right)$

dsolve(ode[8]);

$y=\left(\int \mathrm{RootOf}\left(-x-\left({\int }_{\phantom{\mathrm{`\; `}}}^{\mathrm{\_Z}}\frac{1}{-\mathrm{f\_\_1}\left(\mathrm{\_f}\right)+\mathrm{\_f}}\ⅆ\mathrm{\_f}\right)+\mathrm{c\_\_1}\right){\ⅇ}^{-x}\ⅆx+\mathrm{c\_\_2}\right){\ⅇ}^x$

This solution is the best that can be achieved but involves composite integrals where the inner one is algebraically solved with respect to the integration variable using RootOf. These solutions can frequently be re-expressed in parametric form, free of RootOf, which can now be computed directly by dsolve from the ODE symmetries.

dsolve(ode[8], parametric);

$\left[y\left(\mathrm{\_T}\right)=\left(\int \frac{{\ⅇ}^{\int -\frac{1}{\mathrm{f\_\_1}\left(\mathrm{\_T}\right)-\mathrm{\_T}}\ⅆ\mathrm{\_T}-\mathrm{c\_\_2}}\mathrm{\_T}}{\mathrm{f\_\_1}\left(\mathrm{\_T}\right)-\mathrm{\_T}}\ⅆ\mathrm{\_T}+\mathrm{c\_\_1}\right){\ⅇ}^{\int \frac{1}{\mathrm{f\_\_1}\left(\mathrm{\_T}\right)-\mathrm{\_T}}\ⅆ\mathrm{\_T}+\mathrm{c\_\_2}}\,x\left(\mathrm{\_T}\right)=\int \frac{1}{\mathrm{f\_\_1}\left(\mathrm{\_T}\right)-\mathrm{\_T}}\ⅆ\mathrm{\_T}+\mathrm{c\_\_2}\right]$

The standard process of solving an ODE-IVP consists of first computing a solution that is more general, which depends on arbitrary constants, and then adjusting these constants to match the initial or boundary conditions. The initial more general solution, however, can frequently be written in different ways, which can either facilitate or make more complicated the posterior adjustment of the solution.

To take advantage of this situation, a new command, IVPsol, has been added to the DEtools package, with the purpose of adjusting an ODE solution to given initial or boundary conditions. Also, related new flexibility has been added to dsolve: it now accepts a given solution to be used directly as a departure point to match the initial/boundary conditions.

Example

ode[9] := x*diff(y(x),x,x)+4*y(x)^2 = 0;

${\mathrm{ode}}_9≔x\mathrm{y\text{'}\text{'}}+4y^2=0$

A general solution for ode[9] is not known. So, in principle, it would not be possible to solve an initial value problem involving it, such as in the following example with these initial conditions.

ic[9] := y(1) = -1/2, D(y)(1) = 1/2;

${\mathrm{ic}}_9≔y\left(1\right)=-\frac{1}{2},\mathrm{D}\left(y\right)\left(1\right)=\frac{1}{2}$

But suppose you know a particular solution for ode[9] that you might have computed by any other means, for instance:

sol[9] := y(x) = _C1/(2*x);

${\mathrm{sol}}_9≔y=\frac{\mathrm{c\_\_1}}{2x}$

You can now pass this solution directly to dsolve so that it uses it to solve the problem instead of trying and failing to compute one itself.

dsolve([ode[9], ic[9]], usesolution = sol[9]);

$y=-\frac{1}{2x}$

Analogously, you can pass the initial conditions and the solution directly to DEtools[IVPsol].

DEtools[IVPsol]([ic[9]], sol[9]);

$y=-\frac{1}{2x}$

The DEtools commands particularsol and parametricsol can now solve a new range of higher order and nonlinear ODE problems by combining standard methods with alternative ways of using symmetries.

Example

ode[10] := diff(y(x), x,x,x) - diff(y(x), x,x)*y(x) + diff(y(x),x)^2 = 0;

${\mathrm{ode}}_{10}≔\mathrm{y\text{'}\text{'}\text{'}}-\mathrm{y\text{'}\text{'}}y+{\mathrm{y\text{'}}}^2=0$

No general solution is known for ode[10]. A particular solution for it, however, depending on one arbitrary constant, is now computable using the following.

DEtools[particularsol](ode[10]);

$y=0,y=\frac{6}{-x+\mathrm{c\_\_1}}$

For ode[8], introduced in a previous paragraph, a parametric solution is now computable using the following.

DEtools[parametricsol](ode[8]);

$\left\{\left[y\left(\mathrm{\_T}\right)=\left(\int \frac{{\ⅇ}^{\int -\frac{1}{\mathrm{f\_\_1}\left(\mathrm{\_T}\right)-\mathrm{\_T}}\ⅆ\mathrm{\_T}-\mathrm{c\_\_2}}\mathrm{\_T}}{\mathrm{f\_\_1}\left(\mathrm{\_T}\right)-\mathrm{\_T}}\ⅆ\mathrm{\_T}+\mathrm{c\_\_1}\right){\ⅇ}^{\int \frac{1}{\mathrm{f\_\_1}\left(\mathrm{\_T}\right)-\mathrm{\_T}}\ⅆ\mathrm{\_T}+\mathrm{c\_\_2}}\,x\left(\mathrm{\_T}\right)=\int \frac{1}{\mathrm{f\_\_1}\left(\mathrm{\_T}\right)-\mathrm{\_T}}\ⅆ\mathrm{\_T}+\mathrm{c\_\_2}\right]\right\}$

This functionality also has been added as an option to dsolve; see previous paragraphs.

Four new commands were added to PDEtools: CharacteristicQInvariants, ConsistencyTest, PolynomialSolutions, and SymmetrySolutions. As their names suggest, the new commands can perform fast consistency tests, compute polynomial solutions for PDE systems, transform given solutions into other different solutions exploring the symmetries of the problem, and can compute invariants of differential equation systems using a simpler approach, exploring the CharacteristicQ function of the system's symmetries.

Examples

with(PDEtools);

$\left[\mathrm{CanonicalCoordinates}\,\mathrm{ChangeSymmetry}\,\mathrm{CharacteristicQ}\,\mathrm{CharacteristicQInvariants}\,\mathrm{ConservedCurrentTest}\,\mathrm{ConservedCurrents}\,\mathrm{ConsistencyTest}\,\mathrm{D\_Dx}\,\mathrm{DeterminingPDE}\,\mathrm{Eta\_k}\,\mathrm{Euler}\,\mathrm{FirstIntegralSolver}\,\mathrm{FromJet}\,\mathrm{FunctionFieldSolutions}\,\mathrm{InfinitesimalGenerator}\,\mathrm{Infinitesimals}\,\mathrm{IntegratingFactorTest}\,\mathrm{IntegratingFactors}\,\mathrm{InvariantEquation}\,\mathrm{InvariantSolutions}\,\mathrm{InvariantTransformation}\,\mathrm{Invariants}\,\mathrm{Laplace}\,\mathrm{Library}\,\mathrm{PDEplot}\,\mathrm{PolynomialSolutions}\,\mathrm{ReducedForm}\,\mathrm{SimilaritySolutions}\,\mathrm{SimilarityTransformation}\,\mathrm{Solve}\,\mathrm{SymmetryCommutator}\,\mathrm{SymmetryGauge}\,\mathrm{SymmetrySolutions}\,\mathrm{SymmetryTest}\,\mathrm{SymmetryTransformation}\,\mathrm{TWSolutions}\,\mathrm{ToJet}\,\mathrm{ToMissingDependentVariable}\,\mathrm{build}\,\mathrm{casesplit}\,\mathrm{charstrip}\,\mathrm{dchange}\,\mathrm{dcoeffs}\,\mathrm{declare}\,\mathrm{diff\_table}\,\mathrm{difforder}\,\mathrm{dpolyform}\,\mathrm{dsubs}\,\mathrm{mapde}\,\mathrm{separability}\,\mathrm{splitstrip}\,\mathrm{splitsys}\,\mathrm{undeclare}\right]$

Polynomial solutions for PDE systems can now be computed using the new PolynomialSolutions command.

PDEtools:-declare((f, g)(x,y));

$f\left(x\,y\right)\mathrm{will\; now\; be\; displayed\; as}f$

$g\left(x\,y\right)\mathrm{will\; now\; be\; displayed\; as}g$

sys[1] := diff(f(x,y),x)*diff(g(x,y),x) + diff(f(x,y),y)*diff(g(x,y),y) + g(x,y)*(diff(f(x,y),x,x) + diff(f(x,y),y,y)) = -1;

${\mathrm{sys}}_1≔f_x{g}_x+f_y{g}_y+g\left(f_{x,x}+f_{y,y}\right)=\mathrm{-1}$

psol[1] := PolynomialSolutions(sys[1]);

${\mathrm{psol}}_1≔\left\{f=\frac{\left(\left(2x^2-y^2\right)\mathrm{c\_\_3}+2x\mathrm{c\_\_2}+2\mathrm{c\_\_1}\right)\mathrm{c\_\_5}-2\mathrm{c\_\_3}\mathrm{c\_\_4}y-2y}{2\mathrm{c\_\_5}}\,g=\mathrm{c\_\_5}y+\mathrm{c\_\_4}\right\},\left\{f=\frac{\left(-2\mathrm{c\_\_5}{y}^2+\left(2\mathrm{c\_\_4}x+2\mathrm{c\_\_2}\right)y+2x^2\mathrm{c\_\_5}+2\mathrm{c\_\_3}x+2\mathrm{c\_\_1}\right)\mathrm{c\_\_6}-y^2}{2\mathrm{c\_\_6}}\,g=\mathrm{c\_\_6}\right\},\left\{f=\frac{-2\left(y\mathrm{c\_\_3}+\frac{\mathrm{c\_\_2}}{4}\right)\mathrm{c\_\_5}x\sqrt{2}+\left(\mathrm{c\_\_3}{y}^2+\mathrm{c\_\_2}y+\mathrm{c\_\_1}\right)\mathrm{c\_\_5}+\left(-2\mathrm{c\_\_3}\mathrm{c\_\_4}-1\right)x}{\mathrm{c\_\_5}}\,g=\mathrm{c\_\_5}x+\frac{\sqrt{2}\mathrm{c\_\_5}y}{2}+\mathrm{c\_\_4}\right\},\left\{f=\frac{2\left(y\mathrm{c\_\_3}+\frac{\mathrm{c\_\_2}}{4}\right)\mathrm{c\_\_5}x\sqrt{2}+\left(\mathrm{c\_\_3}{y}^2+\mathrm{c\_\_2}y+\mathrm{c\_\_1}\right)\mathrm{c\_\_5}+\left(-2\mathrm{c\_\_3}\mathrm{c\_\_4}-1\right)x}{\mathrm{c\_\_5}}\,g=\mathrm{c\_\_5}x-\frac{\sqrt{2}\mathrm{c\_\_5}y}{2}+\mathrm{c\_\_4}\right\},\left\{f=\frac{\left(-x^2\mathrm{c\_\_3}+2\mathrm{c\_\_3}{y}^2-\mathrm{c\_\_2}y-\mathrm{c\_\_1}\right){\mathrm{c\_\_6}}^3-6\left(\left(y\mathrm{c\_\_3}-\frac{\mathrm{c\_\_2}}{6}\right)\mathrm{c\_\_5}+\frac{\mathrm{c\_\_3}\mathrm{c\_\_4}}{3}-\frac{1}{6}\right)x{\mathrm{c\_\_6}}^2+2\left(x^2\mathrm{c\_\_3}-\frac{1}{2}\mathrm{c\_\_3}{y}^2+\mathrm{c\_\_2}y+\mathrm{c\_\_1}\right){\mathrm{c\_\_5}}^2\mathrm{c\_\_6}-2x{\mathrm{c\_\_5}}^2\left(\mathrm{c\_\_2}\mathrm{c\_\_5}+\mathrm{c\_\_3}\mathrm{c\_\_4}+1\right)}{2{\mathrm{c\_\_5}}^2\mathrm{c\_\_6}-{\mathrm{c\_\_6}}^3}\,g=\mathrm{c\_\_5}y+\mathrm{c\_\_6}x+\mathrm{c\_\_4}\right\}$

map(pdetest, [psol[1]], sys[1]);

$\left[0\,0\,0\,0\,0\right]$

New different solutions for PDE systems can now be computed from old known solutions exploring their symmetries; consider, for example, the wave equation in two dimensions:

pde[2] := diff(u(x, t), x,x) - diff(u(x, t), t,t) = 0;

${\mathrm{pde}}_2≔u_{x,x}-u_{t,t}=0$

Here is a solution separable by product using pdsolve.

sol[2] := pdsolve(pde[2], HINT = `*`, build);

${\mathrm{sol}}_2≔u\left(x\,t\right)=\mathrm{c\_\_3}{\ⅇ}^{\sqrt{{\mathrm{\_c}}_1}t}\mathrm{c\_\_1}{\ⅇ}^{\sqrt{{\mathrm{\_c}}_1}x}+\frac{\mathrm{c\_\_3}{\ⅇ}^{\sqrt{{\mathrm{\_c}}_1}t}\mathrm{c\_\_2}}{{\ⅇ}^{\sqrt{{\mathrm{\_c}}_1}x}}+\frac{\mathrm{c\_\_4}\mathrm{c\_\_1}{\ⅇ}^{\sqrt{{\mathrm{\_c}}_1}x}}{{\ⅇ}^{\sqrt{{\mathrm{\_c}}_1}t}}+\frac{\mathrm{c\_\_4}\mathrm{c\_\_2}}{{\ⅇ}^{\sqrt{{\mathrm{\_c}}_1}t}{\ⅇ}^{\sqrt{{\mathrm{\_c}}_1}x}}$

Using a new feature, symmetries of polynomial type:

S[2] := Infinitesimals(pde[2], typeofsymmetry = polynomial)[-1..-1];

$S_2≔\left[{\mathrm{\_\ξ}}_x\left(x\,t\,u\right)=2xt\,{\mathrm{\_\ξ}}_t\left(x\,t\,u\right)=t^2+x^2\,{\mathrm{\_\η}}_u\left(x\,t\,u\right)=0\right]$

A new solution is obtained transforming sol[2] and exploring the symmetry S[2].

newsol[2] := SymmetrySolutions(sol[2], S[2]);

${\mathrm{newsol}}_2≔\left\{u\left(x\,t\right)=\left(\mathrm{c\_\_3}{\ⅇ}^{\frac{2\sqrt{{\mathrm{\_c}}_1}\left(\left(t^2-x^2\right)\mathrm{\_\ε}+t\right)}{1+\left(t^2-x^2\right){\mathrm{\_\ε}}^2+2t\mathrm{\_\ε}}}\mathrm{c\_\_2}+\mathrm{c\_\_3}\mathrm{c\_\_1}{\ⅇ}^{\frac{2\sqrt{{\mathrm{\_c}}_1}\left(t+x\right)\left(1+\left(t-x\right)\mathrm{\_\ε}\right)}{1+\left(t^2-x^2\right){\mathrm{\_\ε}}^2+2t\mathrm{\_\ε}}}+\mathrm{c\_\_4}\left({\ⅇ}^{\frac{2x\sqrt{{\mathrm{\_c}}_1}}{1+\left(t^2-x^2\right){\mathrm{\_\ε}}^2+2t\mathrm{\_\ε}}}\mathrm{c\_\_1}+\mathrm{c\_\_2}\right)\right){\ⅇ}^{-\frac{\sqrt{{\mathrm{\_c}}_1}\left(t+x\right)\left(1+\left(t-x\right)\mathrm{\_\ε}\right)}{1+\left(t^2-x^2\right){\mathrm{\_\ε}}^2+2t\mathrm{\_\ε}}}\right\}$

This new solution is verified using pdetest.

pdetest(newsol[2], pde[2]);

$0$

Most of the symmetry commands of PDEtools have had their functionality significantly expanded, providing enough flexibility to get a solution, or one of the necessary form, even for tough problems. New features that stand out are:

The main solver of the symmetry approach, InvariantSolutions has been packed with options to facilitate obtaining solutions of the most varied forms;

All of InvariantSolutions, SimilaritySolutions, and Infinitesimals can now solve problems faster, exploring symmetries of polynomial type or with restricted dependency, making solutions easier to compute;

InvariantSolutions and SimilaritySolutions automatically specialize arbitrary functions entering the infinitesimals of PDE systems, including an option to avoid this specialization when desired;

The key command of the symmetry approach, DeterminingPDE, can now compute the determining system also for integrating factors and conserved currents.

Examples

In many cases, a particular solution for a PDE system, which can also be computed faster than a more general solution, is enough to solve the problem. The new features permit searching for these particular solutions in varied manners. Recall, for example, the wave equation in two dimensions introduced in a previous section:

pde[2];

$u_{x,x}-u_{t,t}=0$

The following specifies that a solution depending only on $t$ would suffice.

InvariantSolutions(pde[2], numberofsolutions = 1, dependency = t);

$u\left(x\,t\right)=\mathrm{c\_\_1}t+\mathrm{c\_\_2}$

This other input specifies to construct a solution using infinitesimals only depending on one variable, either $x$ or $t$, which are easy to compute.

InvariantSolutions(pde[2], dependencyofinfinitesimals = {x, t});

$u\left(x\,t\right)=\mathrm{c\_\_1}t+\mathrm{c\_\_2},u\left(x\,t\right)=\mathrm{c\_\_1}x+\mathrm{c\_\_2}$

With this input, you specify the use of infinitesimals of polynomial type, linear in the jet variables (almost the simplest ones that can be computed, requiring only inverting a matrix); note the display option to show the corresponding invariants and solution.

InvariantSolutions(pde[2], degreeofinfinitesimals = 1, display);

$\mathrm{invariants}=\left[\frac{t}{x}\,u\left(x\,t\right)\right]$

$\mathrm{solutions}=\left[\left\{u\left(x\,t\right)=\mathrm{c\_\_1}-\frac{\mathrm{c\_\_2}\ln \left(\frac{t+x}{x}\right)}{2}+\frac{\mathrm{c\_\_2}\ln \left(\frac{t-x}{x}\right)}{2}\right\}\right]$

$\mathrm{\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_}$

$\mathrm{invariants}=\left[t^2-x^2\,u\left(x\,t\right)\right]$

$\mathrm{solutions}=\left[\left\{u\left(x\,t\right)=\mathrm{c\_\_4}\ln \left(t^2-x^2\right)+\mathrm{c\_\_3}\right\}\right]$

$\mathrm{\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_}$

$\mathrm{invariants}=\left[t\,u\left(x\,t\right)\right]$

$\mathrm{solutions}=\left[\left\{u\left(x\,t\right)=\mathrm{c\_\_5}t+\mathrm{c\_\_6}\right\}\right]$

$\mathrm{\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_}$

$\mathrm{invariants}=\left[x\,u\left(x\,t\right)\right]$

$\mathrm{solutions}=\left[\left\{u\left(x\,t\right)=\mathrm{c\_\_7}x+\mathrm{c\_\_8}\right\}\right]$

$\mathrm{\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_}$

$u\left(x\,t\right)=\mathrm{c\_\_1}t+\mathrm{c\_\_2},u\left(x\,t\right)=\mathrm{c\_\_1}x+\mathrm{c\_\_2},u\left(x\,t\right)=\mathrm{c\_\_2}\ln \left(t^2-x^2\right)+\mathrm{c\_\_1},u\left(x\,t\right)=\mathrm{c\_\_1}-\frac{\mathrm{c\_\_2}\ln \left(\frac{t+x}{x}\right)}{2}+\frac{\mathrm{c\_\_2}\ln \left(\frac{t-x}{x}\right)}{2}$

These invariants shown are a fingerprint of each solution; they can now be copied directly from the screen and pasted in the call to InvariantSolutions to reproduce precisely the corresponding solution.

InvariantSolutions(pde[2], invariants = [t/x, u(x,t)]);

$u\left(x\,t\right)=\mathrm{c\_\_1}-\frac{\mathrm{c\_\_2}\ln \left(\frac{t+x}{x}\right)}{2}+\frac{\mathrm{c\_\_2}\ln \left(\frac{t-x}{x}\right)}{2}$

The general form of Infinitesimals for pde[2] involves arbitrary functions $\mathrm{\_Fn}\left(t+x\right)$ and $\mathrm{\_Fm}\left(x-t\right)$.

Infinitesimals(pde[2]);

$\left[{\mathrm{\_\ξ}}_x\left(x\,t\,u\right)=\mathrm{f\_\_1}\left(t+x\right)+\mathrm{f\_\_2}\left(t-x\right)\,{\mathrm{\_\ξ}}_t\left(x\,t\,u\right)=-\mathrm{f\_\_2}\left(t-x\right)+\mathrm{f\_\_1}\left(t+x\right)+1\,{\mathrm{\_\η}}_u\left(x\,t\,u\right)=\mathrm{f\_\_3}\left(t+x\right)+\mathrm{f\_\_4}\left(t-x\right)\right],\left[{\mathrm{\_\ξ}}_x\left(x\,t\,u\right)=\mathrm{f\_\_5}\left(t+x\right)+\mathrm{f\_\_6}\left(t-x\right)\,{\mathrm{\_\ξ}}_t\left(x\,t\,u\right)=-\mathrm{f\_\_6}\left(t-x\right)+\mathrm{f\_\_5}\left(t+x\right)\,{\mathrm{\_\η}}_u\left(x\,t\,u\right)=u+\mathrm{f\_\_7}\left(t+x\right)+\mathrm{f\_\_8}\left(t-x\right)\right]$

It is not possible to compute a SimilarityTransformation or, for that matter, any symmetry related transformation with them because of the arbitrary functions. In order to use these infinitesimals, the arbitrary functions are now automatically specialized by all the symmetry commands (except for Infinitesimals), as you could see by interactively using the new specialize_Fn option of Infinitesimals.

S := Infinitesimals(pde[2], specialize_Fn, displayfunctionality = false);

$S≔\left[{\mathrm{\_\ξ}}_x=1\,{\mathrm{\_\ξ}}_t=0\,{\mathrm{\_\η}}_u=0\right],\left[{\mathrm{\_\ξ}}_x=1\,{\mathrm{\_\ξ}}_t=2\,{\mathrm{\_\η}}_u=0\right],\left[{\mathrm{\_\ξ}}_x=0\,{\mathrm{\_\ξ}}_t=1\,{\mathrm{\_\η}}_u=1\right],\left[{\mathrm{\_\ξ}}_x=1\,{\mathrm{\_\ξ}}_t=1\,{\mathrm{\_\η}}_u=u\right],\left[{\mathrm{\_\ξ}}_x=1\,{\mathrm{\_\ξ}}_t=\mathrm{-1}\,{\mathrm{\_\η}}_u=u\right],\left[{\mathrm{\_\ξ}}_x=0\,{\mathrm{\_\ξ}}_t=1\,{\mathrm{\_\η}}_u=t+x\right],\left[{\mathrm{\_\ξ}}_x=0\,{\mathrm{\_\ξ}}_t=1\,{\mathrm{\_\η}}_u=t-x\right],\left[{\mathrm{\_\ξ}}_x=0\,{\mathrm{\_\ξ}}_t=0\,{\mathrm{\_\η}}_u=u+1\right],\left[{\mathrm{\_\ξ}}_x=0\,{\mathrm{\_\ξ}}_t=0\,{\mathrm{\_\η}}_u=u+t+x\right],\left[{\mathrm{\_\ξ}}_x=0\,{\mathrm{\_\ξ}}_t=0\,{\mathrm{\_\η}}_u=u+t-x\right],\left[{\mathrm{\_\ξ}}_x=t+x\,{\mathrm{\_\ξ}}_t=1+t+x\,{\mathrm{\_\η}}_u=0\right],\left[{\mathrm{\_\ξ}}_x=t-x\,{\mathrm{\_\ξ}}_t=-t+x+1\,{\mathrm{\_\η}}_u=0\right],\left[{\mathrm{\_\ξ}}_x=t+x\,{\mathrm{\_\ξ}}_t=t+x\,{\mathrm{\_\η}}_u=u\right],\left[{\mathrm{\_\ξ}}_x=t-x\,{\mathrm{\_\ξ}}_t=x-t\,{\mathrm{\_\η}}_u=u\right]$

In this way, all these commands can deal with the symmetries of pde[2] properly.

SymmetryTransformation(S[5], u(x, t), v(r, s));

$\left\{r=x+\mathrm{\_\ε}\,s=-\mathrm{\_\ε}+t\,v\left(r\,s\right)=u\left(x\,t\right){\ⅇ}^{\mathrm{\_\ε}}\right\}$

Invariant solutions can then be computed automatically because this specialization of arbitrary functions is now automatic.

InvariantSolutions(pde[2]);

$u\left(x\,t\right)=\mathrm{c\_\_1}\sqrt{t+x},u\left(x\,t\right)=\frac{\mathrm{c\_\_1}}{\sqrt{t-x}},u\left(x\,t\right)=\mathrm{c\_\_1}x+\mathrm{c\_\_2}+t,u\left(x\,t\right)=\mathrm{c\_\_1}\left(-2x+t\right)+\mathrm{c\_\_2},u\left(x\,t\right)=\frac{\mathrm{c\_\_1}{\ⅇ}^{\frac{t}{2}-\frac{x}{2}}}{{\ⅇ}^{-x}},u\left(x\,t\right)=\frac{\mathrm{c\_\_1}{\ⅇ}^{-\frac{t}{2}-\frac{x}{2}}}{{\ⅇ}^{-x}},u\left(x\,t\right)=\frac{x^2}{2}+\left(t+\mathrm{c\_\_1}\right)x+\frac{t^2}{2}+\mathrm{c\_\_2},u\left(x\,t\right)=\frac{x^2}{2}+\left(-t+\mathrm{c\_\_2}\right)x+\frac{t^2}{2}+\mathrm{c\_\_1},u\left(x\,t\right)=\mathrm{c\_\_2}\ln \left({\ⅇ}^{2x-2t}\left(1+2t+2x\right)\right)+\mathrm{c\_\_1},u\left(x\,t\right)=\mathrm{c\_\_2}\ln \left({\ⅇ}^{2t+2x}\left(2t-2x-1\right)\right)+\mathrm{c\_\_1}$

The PDEtools internal library for manipulating and programming with differential equations is now available, starting in Maple 13 with 45 subroutines.

Example

The PDEtools Library of routines is made available mainly for programming purposes. Some of these routines, however, are valuable for mathematical reasons. For example, the result previously obtained using the new PolynomialSolutions command for sys[1] is computed by first estimating upper bounds for the degree of the solution.

sys[1];

$f_x{g}_x+f_y{g}_y+g\left(f_{x,x}+f_{y,y}\right)=\mathrm{-1}$

Describe(PDEtools:-Library:-UpperBounds);

#
# Parameters
# * PDESYS - a PDE system; it can contain PDEs, ODEs, and also non-differential equations
# * F - a list of the unknown functions of PDESYS
# * increasefornonautonomous - optional, can be true (default) or false, to increase the upper bounds by 1 in the presence of nonautonomous equations in PDESYS
# Description: UpperBounds returns a sequence of sets of equations, where the lhs is a function of F and the rhs is an upper bound for the degree of a solution polynomial in the independent variables.
# Example
# > sys := diff(f(x,y),x)*diff(g(y),y) + diff(f(x,y),y)*diff(g(y),y) + f(x,y)*(diff(f(x,y),x,x) + diff(f(x,y),y,y)) = x*y:
# > PDEtools:-Library:-UpperBounds(sys, [f(x,y), g(y)]);
# {f(x, y) = 3, g(y) = 2}
# > PDEtools:-Library:-UpperBounds(sys, [f(x,y), g(y)], increasefornonautonomous = false);
# {f(x, y) = 2, g(y) = 1}
#
UpperBounds( PDESYS, F, X::list(name) := _GetIndepVars(F),
             { increasefornonautonomous::truefalse := true } )

PDEtools:-Library:-UpperBounds(sys[1], [f, g](x,y));

$\left\{f=2\,g=1\right\}$

The casesplit and dpolyform commands can now compute with arbitrary functions of algebraic expressions (not symbol variables). In other words, given an expression for some unknowns (that is, non-rational in arbitrary functions whose arguments are non-rational in the independent variables), compute a differential polynomial representation (PDE system), solved by the given expression, where the PDE system is rational in the unknowns and its derivatives, and has rational coefficients.

Motivation: arbitrary functions of algebraic expressions (typically differential invariants) appear frequently when solving intermediary PDE problems that enter the formulation of applications or larger PDE problems. The new ability permits doing differential elimination with these objects and so uncoupling nonlinear PDE systems that involve them, extending in significant ways what can now be done with PDE systems and their solutions.

Examples

Consider the following expression for some $g\left(x\,t\right)$ that involves the arbitrary functions $\mathrm{f\_\_1}\left(t+x\right)+\mathrm{f\_\_2}\left(x-t\right)$.

sol[3] := g(x,t) = _F1(x+t) + _F2(x-t);

${\mathrm{sol}}_3≔g\left(x\,t\right)=\mathrm{f\_\_1}\left(t+x\right)+\mathrm{f\_\_2}\left(x-t\right)$

What is the PDE satisfied by this expression? It can now be computed: it is the wave equation in two dimensions.

pde[3] := dpolyform(sol[3], no_Fn);

${\mathrm{pde}}_3≔\left[g_{x,x}=g_{t,t}\right]\mathbf{where}\left[\right]$

The ability to compute differential polynomial representations for some mapping of variables $x,t,\mathrm{...}$ is old, based on the knowledge of the mathematical properties of the mapping applied to the variables (for example, $\sin \left(t+x\right)$). The ability to compute these PDE representations with arbitrary mappings (for example, $\mathrm{f\_\_1}\left(t+x\right)$) that have no particular mathematical properties is new in Maple 13. Derivatives of arbitrary mappings evaluated at expressions can also be represented in rational PDE form.

sol[4] := g(x,t) = D(_F1)(ln(x*t) + _F2(1/exp(t)));

${\mathrm{sol}}_4≔g\left(x\,t\right)=\mathrm{D}\left(\mathrm{f\_\_1}\right)\left(\ln \left(xt\right)+\mathrm{f\_\_2}\left(\frac{1}{{\ⅇ}^t}\right)\right)$

pde[4] := dpolyform(sol[4], no_Fn);

${\mathrm{pde}}_4≔\left[g_{t,x}=\frac{g_t{g}_{x,x}}{g_x}+\frac{g_t}{x}\right]\mathbf{where}\left[g_t\ne 0\,g_x\ne 0\right]$

These results can be verified as usual using pdetest.

pdetest(sol[4], pde[4]);

$\left[0\right]$

The casesplit command also accepts a new optional argument, caseplot, so that in addition to the splitting into cases, it also produces a plot with a graphical representation of the splitting.

ode[11] := diff(y(t),t,t)^2 + 2*diff(y(t),t,t)*y(t)^3*diff(y(t),t) - 4*y(t)^2*diff(y(t),t)^3;

${\mathrm{ode}}_{11}≔{y_{t,t}}^2+2y_{t,t}{y\left(t\right)}^3{y}_t-4{y\left(t\right)}^2{y_t}^3$

casesplit(ode[11], caseplot);

$\mathrm{=========\; Pivots\; Legend\; =========}$

$\mathrm{p1}={y\left(t\right)}^3{y}_t+y_{t,t}$

$\mathrm{p2}=y\left(t\right)$

$\mathrm{p3}=y_t$

$\mathrm{PLOT}\left(\mathrm{...}\right)$

$\left[{y_{t,t}}^2=-2y_{t,t}{y\left(t\right)}^3{y}_t+4{y\left(t\right)}^2{y_t}^3\right]\mathbf{where}\left[{y\left(t\right)}^3{y}_t+y_{t,t}\ne 0\right],\left[y_t=-\frac{{y\left(t\right)}^4}{4}\right]\mathbf{where}\left[y\left(t\right)\ne 0\right],\left[y_t=0\right]\mathbf{where}\left[y\left(t\right)\ne 0\right],\left[y\left(t\right)=0\right]\mathbf{where}\left[\right]$

The pdetest command can now test solutions for correctness regarding boundary conditions.

Examples

Consider the following PDE, boundary condition, and solution.

pde[3] := diff(u(x,t),t) = k*diff(diff(u(x,t),x),x)+Q;

${\mathrm{pde}}_3≔u_t=k{u}_{x,x}+Q$

bc[3] := u(0,t) = 2*exp(k*t)-1/k*Q;

${\mathrm{bc}}_3≔u\left(0\,t\right)=2{\ⅇ}^{kt}-\frac{Q}{k}$

sol[3] := u(x,t) = _C1^2*exp(x+k*t)-(_C1^2-2)*exp(-x+k*t)-1/2/k*Q*x^2+1/_C1^2/k*Q*(_C1^2-2)*x-1/k*Q;

${\mathrm{sol}}_3≔u\left(x\,t\right)={\mathrm{c\_\_1}}^2{\ⅇ}^{kt+x}-\left({\mathrm{c\_\_1}}^2-2\right){\ⅇ}^{kt-x}-\frac{Q{x}^2}{2k}+\frac{Q\left({\mathrm{c\_\_1}}^2-2\right)x}{{\mathrm{c\_\_1}}^{2}k}-\frac{Q}{k}$

You can test whether the sol[1] solves pde[1] using pdetest; the new functionality is that you can now test whether it solves the boundary condition bc[1].