Lie Algebra Isomorphism Theorems - Maple Help

LieAlgebra Tutorial

The Lie Algebra Isomorphism Theorems

 Overview The quotient or factor construction for groups rings and algebras leads to three fundament isomorphism theorems. In this tutorial we construct each of these isomorphisms explicitly for an example.
 Procedures Illustrated In this tutorial we shall make use of the following packages and commands:

The First Isomorphism Theorem

The First Isomorphism Theorem states that if phi: g -> k is a Lie algebra homomorphism, then phi induces a isomorphism  psi : g/kernel(phi) -> image(phi).  We shall verify this theorem for the homomorphism phi defined below.

 Alg1 > with(DifferentialGeometry): with(LieAlgebras):

First define and initialize the Lie algebras Alg1 and Alg2.

 > L1 := _DG([["LieAlgebra", Alg1, [6]], [[[1, 2, 3], -1], [[1, 2, 5], -1], [[1, 3, 1], -4], [[1, 3, 2], -1], [[1, 3, 4], 3], [[1, 5, 1], 3], [[1, 5, 2], 1], [[1, 5, 4], -2], [[1, 6, 3], -1], [[1, 6, 5], -1], [[2, 3, 2], -2], [[2, 3, 6], 1], [[2, 4, 3], 1], [[2, 4, 5], 1], [[2, 5, 2], 2], [[2, 5, 6], -1], [[3, 4, 1], 1], [[3, 4, 2], 1], [[3, 5, 3], 2], [[3, 5, 5], 2], [[3, 6, 6], 1], [[4, 5, 2], 1], [[4, 5, 4], 1], [[4, 6, 3], -1], [[4, 6, 5], -1], [[5, 6, 6], -1]]]):
 > L2 := _DG([["LieAlgebra", Alg2, [5]], [[[1, 2, 1], 2], [[1, 3, 1], 2], [[2, 3, 1], 1], [[2, 3, 2], 1], [[2, 3, 3], -1], [[1, 2, 4], -1], [[1, 3, 4], -1], [[2, 4, 4], -1], [[3, 4, 4], -1], [[2, 5, 4], 1], [[3, 5, 4], -1]]]):
 > DGsetup(L1, [e], [theta]):
 Alg1 > DGsetup(L2, [f], [omega]):

Here are the multiplication tables for the Lie algebras g = Alg1 and k = Alg2.

 Alg2 > MultiplicationTable(Alg1, "LieTable");
 Alg1 > MultiplicationTable(Alg2, "LieTable");

Here is the homomorphism phi from Alg1 to Alg2.

 Alg2 > phi := Transformation([[e1, f2 &minus f3], [e2, f1], [e3, (-1) &mult f3], [e4, f2 &minus f3], [e5, f3], [e6, f4]]);
 ${\mathrm{φ}}{≔}\left[\left[{\mathrm{e1}}{,}{\mathrm{f2}}{-}{\mathrm{f3}}\right]{,}\left[{\mathrm{e2}}{,}{\mathrm{f1}}\right]{,}\left[{\mathrm{e3}}{,}{-}{\mathrm{f3}}\right]{,}\left[{\mathrm{e4}}{,}{\mathrm{f2}}{-}{\mathrm{f3}}\right]{,}\left[{\mathrm{e5}}{,}{\mathrm{f3}}\right]{,}\left[{\mathrm{e6}}{,}{\mathrm{f4}}\right]\right]$ (3.1)
 Alg2 > Query(Alg1, Alg2, phi, "Homomorphism");
 ${\mathrm{true}}$ (3.2)

Let h be the kernel of phi and let m be the image of phi. In accordance with the standard proof of the First Isomorphism Theorem, the isomorphism psi : g/h -->m can be defined as the composition of 3 maps g/h -->h -->k -->m. The  first map is any vector space map Sigma: g/h -> g such that pi  o Sigma = identity on g/h. The second map is the given Lie algebra homomorphism phi.  The third map is any vector space projection from k onto m In Step 1, we calculate the kernel of phi, find the structure equations for the quotient of Alg1 by the kernel of phi, and initialize the quotient algebra as Alg3. We also define the map Sigma. In Step 2 we calculate the image of phi and initialize this subalgebra of Alg2 as Alg4.  In Step 3 we define a projection map rho : k --> m.  In Step 4 we compute the composition of psi =Sigma o phi o rho from g/h (Alg3) to m (Alg4) and verify that psi is a Lie algebra isomorphism.

Step 1. Calculate the kernel of phi.

 Alg2 > kernel := HomomorphismSubalgebras(phi,"Kernel");
 ${\mathrm{kernel}}{≔}\left[{\mathrm{e3}}{+}{\mathrm{e5}}{,}{-}{\mathrm{e1}}{+}{\mathrm{e4}}\right]$ (3.3)

Calculate the structure equations for the quotient of Alg1 by the kernel. Calculate the matrix of the canonical projection map from Alg1 to Alg1/kernel

 Alg1 > L3, P3 := QuotientAlgebra(kernel, [e2, e4, e5, e6], Alg3, "Matrix");

Initialize the quotient g/h as Alg3 and label the basis vectors for this Lie algebra by E1, E2, E3, E4.

 Alg1 > DGsetup(L3, [E], [omega]);
 ${\mathrm{Lie algebra: Alg3}}$ (3.4)

Use the Matrix P3 to define the project map pi : g(Alg1)-> g/h(Alg3).

 Alg3 > pi := Transformation(Alg1, Alg3, P3);
 ${\mathrm{π}}{≔}\left[\left[{\mathrm{e1}}{,}{\mathrm{E2}}\right]{,}\left[{\mathrm{e2}}{,}{\mathrm{E1}}\right]{,}\left[{\mathrm{e3}}{,}{-}{\mathrm{E3}}\right]{,}\left[{\mathrm{e4}}{,}{\mathrm{E2}}\right]{,}\left[{\mathrm{e5}}{,}{\mathrm{E3}}\right]{,}\left[{\mathrm{e6}}{,}{\mathrm{E4}}\right]\right]$ (3.5)

Define the vector space map Sigma : g/h(Alg3) -> g(Alg1).

 Alg3 > Sigma := Transformation([[E1, e2],[E2, e4],[E3, e5],[E4, e6]]);
 ${\mathrm{Σ}}{≔}\left[\left[{\mathrm{E1}}{,}{\mathrm{e2}}\right]{,}\left[{\mathrm{E2}}{,}{\mathrm{e4}}\right]{,}\left[{\mathrm{E3}}{,}{\mathrm{e5}}\right]{,}\left[{\mathrm{E4}}{,}{\mathrm{e6}}\right]\right]$ (3.6)

Check that Sigma is a right inverse to pi.

 Alg1 > ComposeTransformations(pi, Sigma);
 $\left[\left[{\mathrm{E1}}{,}{\mathrm{E1}}\right]{,}\left[{\mathrm{E2}}{,}{\mathrm{E2}}\right]{,}\left[{\mathrm{E3}}{,}{\mathrm{E3}}\right]{,}\left[{\mathrm{E4}}{,}{\mathrm{E4}}\right]\right]$ (3.7)

Note that Sigma is not a Lie algebra homomorphism.

 Alg3 > Query(Alg3, Alg1, Sigma, "Homomorphism");
 ${\mathrm{false}}$ (3.8)

Step 2. Calculate the image of phi. Initialize this subalgebra of Alg2 as Alg4. Use labels F1, F2, F3, F4 for the basis vector for Alg4.

 Alg1 > image :=  HomomorphismSubalgebras(phi,"Image");
 ${\mathrm{image}}{≔}\left[{\mathrm{f1}}{,}{\mathrm{f2}}{,}{\mathrm{f3}}{,}{\mathrm{f4}}\right]$ (3.9)
 Alg2 > L4 := LieAlgebraData(image, Alg4);
 ${\mathrm{L4}}{≔}\left[\left[{\mathrm{e1}}{,}{\mathrm{e2}}\right]{=}{2}{}{\mathrm{e1}}{-}{\mathrm{e4}}{,}\left[{\mathrm{e1}}{,}{\mathrm{e3}}\right]{=}{2}{}{\mathrm{e1}}{-}{\mathrm{e4}}{,}\left[{\mathrm{e2}}{,}{\mathrm{e3}}\right]{=}{\mathrm{e1}}{+}{\mathrm{e2}}{-}{\mathrm{e3}}{,}\left[{\mathrm{e2}}{,}{\mathrm{e4}}\right]{=}{-}{\mathrm{e4}}{,}\left[{\mathrm{e3}}{,}{\mathrm{e4}}\right]{=}{-}{\mathrm{e4}}\right]$ (3.10)
 Alg2 > DGsetup(L4, [F] ,[omega]);
 ${\mathrm{Lie algebra: Alg4}}$ (3.11)

Step 3.  Define the projection map from Alg2 to Alg4.

 Alg4 > rho:= Transformation([[f1, F1],[f2, F2],[f3, F3], [f4, F4]]);
 ${\mathrm{ρ}}{≔}\left[\left[{\mathrm{f1}}{,}{\mathrm{F1}}\right]{,}\left[{\mathrm{f2}}{,}{\mathrm{F2}}\right]{,}\left[{\mathrm{f3}}{,}{\mathrm{F3}}\right]{,}\left[{\mathrm{f4}}{,}{\mathrm{F4}}\right]{,}\left[{\mathrm{f5}}{,}{0}{}{\mathrm{F1}}\right]\right]$ (3.12)

Step 4.  Let's summarize our computations. Here is the quotient algebra.

 Alg4 > MultiplicationTable(Alg3, "LieTable");

Here is the image algebra.

 Alg3 > MultiplicationTable(Alg4, "LieTable");

Here is the isomorphism from Alg3 to Alg4.

 Alg4 > psi := ComposeTransformations(rho, phi, Sigma);
 ${\mathrm{ψ}}{≔}\left[\left[{\mathrm{E1}}{,}{\mathrm{F1}}\right]{,}\left[{\mathrm{E2}}{,}{\mathrm{F2}}{-}{\mathrm{F3}}\right]{,}\left[{\mathrm{E3}}{,}{\mathrm{F3}}\right]{,}\left[{\mathrm{E4}}{,}{\mathrm{F4}}\right]\right]$ (3.13)

We check that psi is indeed an isomorphism by showing that is a homomorphism with trivial kernel.

 Alg4 > Query(Alg3, Alg4, psi, "Homomorphism");
 ${\mathrm{true}}$ (3.14)
 Alg4 > HomomorphismSubalgebras(psi, "Kernel");
 $\left[{}\right]$ (3.15)
 Alg3 >

The Second Isomorphism Theorem

The Second Isomorphism Theorem states that if h and k are ideals in a Lie algebra g, then (h + k)/h is isomorphic to k/(h intersect k).  We shall construct this isomorphism for the following ideals.

 > with(DifferentialGeometry): with(LieAlgebras):

First define and initialize the ambient Lie algebra Alg.

 Alg3 > L := _DG([["LieAlgebra", Alg, [8]], [[[1, 2, 1], 1], [[1, 2, 7], -1], [[1, 3, 2], 1], [[1, 3, 4], alpha], [[1, 3, 6], 1], [[1, 3, 7], -1], [[1, 5, 1], -1], [[1, 5, 2], -2], [[1, 5, 6], -2], [[1, 5, 7], 3], [[1, 6, 1], -1], [[1, 6, 7], 1], [[1, 8, 2], -1], [[1, 8, 6], -1], [[1, 8, 7], 1], [[2, 3, 1], -1], [[2, 3, 4], alpha], [[2, 3, 7], 1], [[2, 5, 1], 2], [[2, 5, 2], -1], [[2, 5, 6], -1], [[2, 5, 7], -1], [[2, 6, 2], -1], [[2, 6, 6], -1], [[2, 6, 7], 1], [[2, 8, 1], 1], [[2, 8, 2], -1], [[2, 8, 6], -1], [[3, 4, 4], 1], [[3, 5, 2], 1], [[3, 5, 3], 1], [[3, 5, 5], 1], [[3, 5, 7], -1], [[3, 5, 8], -1], [[3, 7, 4], -alpha], [[3, 8, 1], 1], [[3, 8, 7], -1], [[4, 5, 4], 1], [[5, 8, 1], -2], [[5, 8, 2], 1], [[5, 8, 6], 1], [[5, 8, 7], 1], [[6, 8, 2], 1], [[6, 8, 6], 1], [[6, 8, 7], -1]]]);
 ${L}{≔}\left[\left[{\mathrm{e1}}{,}{\mathrm{e2}}\right]{=}{\mathrm{e1}}{-}{\mathrm{e7}}{,}\left[{\mathrm{e1}}{,}{\mathrm{e3}}\right]{=}{\mathrm{e2}}{+}{\mathrm{α}}{}{\mathrm{e4}}{+}{\mathrm{e6}}{-}{\mathrm{e7}}{,}\left[{\mathrm{e1}}{,}{\mathrm{e5}}\right]{=}{-}{\mathrm{e1}}{-}{2}{}{\mathrm{e2}}{-}{2}{}{\mathrm{e6}}{+}{3}{}{\mathrm{e7}}{,}\left[{\mathrm{e1}}{,}{\mathrm{e6}}\right]{=}{-}{\mathrm{e1}}{+}{\mathrm{e7}}{,}\left[{\mathrm{e1}}{,}{\mathrm{e8}}\right]{=}{-}{\mathrm{e2}}{-}{\mathrm{e6}}{+}{\mathrm{e7}}{,}\left[{\mathrm{e2}}{,}{\mathrm{e3}}\right]{=}{-}{\mathrm{e1}}{+}{\mathrm{α}}{}{\mathrm{e4}}{+}{\mathrm{e7}}{,}\left[{\mathrm{e2}}{,}{\mathrm{e5}}\right]{=}{2}{}{\mathrm{e1}}{-}{\mathrm{e2}}{-}{\mathrm{e6}}{-}{\mathrm{e7}}{,}\left[{\mathrm{e2}}{,}{\mathrm{e6}}\right]{=}{-}{\mathrm{e2}}{-}{\mathrm{e6}}{+}{\mathrm{e7}}{,}\left[{\mathrm{e2}}{,}{\mathrm{e8}}\right]{=}{\mathrm{e1}}{-}{\mathrm{e2}}{-}{\mathrm{e6}}{,}\left[{\mathrm{e3}}{,}{\mathrm{e4}}\right]{=}{\mathrm{e4}}{,}\left[{\mathrm{e3}}{,}{\mathrm{e5}}\right]{=}{\mathrm{e2}}{+}{\mathrm{e3}}{+}{\mathrm{e5}}{-}{\mathrm{e7}}{-}{\mathrm{e8}}{,}\left[{\mathrm{e3}}{,}{\mathrm{e7}}\right]{=}{-}{\mathrm{α}}{}{\mathrm{e4}}{,}\left[{\mathrm{e3}}{,}{\mathrm{e8}}\right]{=}{\mathrm{e1}}{-}{\mathrm{e7}}{,}\left[{\mathrm{e4}}{,}{\mathrm{e5}}\right]{=}{\mathrm{e4}}{,}\left[{\mathrm{e5}}{,}{\mathrm{e8}}\right]{=}{-}{2}{}{\mathrm{e1}}{+}{\mathrm{e2}}{+}{\mathrm{e6}}{+}{\mathrm{e7}}{,}\left[{\mathrm{e6}}{,}{\mathrm{e8}}\right]{=}{\mathrm{e2}}{+}{\mathrm{e6}}{-}{\mathrm{e7}}\right]$ (4.1)
 Alg3 > DGsetup(L);
 ${\mathrm{Lie algebra: Alg}}$ (4.2)
 Alg > h := MinimalIdeal([e1, e5, e8]);
 ${h}{≔}\left[{\mathrm{e1}}{,}{\mathrm{e2}}{+}{\mathrm{e6}}{,}{\mathrm{e3}}{-}{\mathrm{e6}}{,}{\mathrm{e4}}{,}{\mathrm{e5}}{,}{\mathrm{e7}}{,}{\mathrm{e8}}\right]$ (4.3)
 Alg > k := MinimalIdeal([e4, e6]);
 ${k}{≔}\left[{\mathrm{e1}}{-}{\mathrm{e7}}{,}{\mathrm{e2}}{-}{\mathrm{e7}}{,}{\mathrm{e4}}{,}{\mathrm{e6}}\right]$ (4.4)

Let m = h + k and j be the intersection of h and k.  The  isomorphism is given by the composition of maps h/j --> h --> m --> m/k. The first map is any vector space map Sigma: h/j --> h such that pi_h o Sigma = identity on h/j.  The second map is the inclusion iota of h into m. The third map is the projection pi_m : m --> m/k from m to the quotient Lie algebra m/k.  We construct each of these maps, calculate the composition psi = pi_m o iota o Sigma and check that psi is a Lie algebra isomorphism.

Step 1. Construction of the quotient algebra h/j and the map Sigma.  First calculate the intersection of the subspaces h and k.

 Alg > j := IntersectSubspaces([h,k]);
 ${j}{≔}\left[{-}{\mathrm{e2}}{-}{\mathrm{e6}}{+}{\mathrm{e7}}{,}{-}{\mathrm{e4}}{,}{-}{\mathrm{e1}}{+}{\mathrm{e7}}\right]$ (4.5)

Now initialize the subalgebra h as the Lie algebra Alg1. At the same time calculate the components of the vectors in j as linear combinations of the vectors in h.

 Alg > L1, Comp1 := LieAlgebraData(h, [j], Alg1);
 ${\mathrm{L1}}{,}{\mathrm{Comp1}}{≔}\left[\left[{\mathrm{e1}}{,}{\mathrm{e3}}\right]{=}{\mathrm{e1}}{+}{\mathrm{e2}}{+}{\mathrm{α}}{}{\mathrm{e4}}{-}{2}{}{\mathrm{e6}}{,}\left[{\mathrm{e1}}{,}{\mathrm{e5}}\right]{=}{-}{\mathrm{e1}}{-}{2}{}{\mathrm{e2}}{+}{3}{}{\mathrm{e6}}{,}\left[{\mathrm{e1}}{,}{\mathrm{e7}}\right]{=}{-}{\mathrm{e2}}{+}{\mathrm{e6}}{,}\left[{\mathrm{e2}}{,}{\mathrm{e3}}\right]{=}{-}{\mathrm{e1}}{+}{\mathrm{e2}}{+}{\mathrm{α}}{}{\mathrm{e4}}{,}\left[{\mathrm{e2}}{,}{\mathrm{e5}}\right]{=}{2}{}{\mathrm{e1}}{-}{\mathrm{e2}}{-}{\mathrm{e6}}{,}\left[{\mathrm{e2}}{,}{\mathrm{e7}}\right]{=}{\mathrm{e1}}{-}{\mathrm{e6}}{,}\left[{\mathrm{e3}}{,}{\mathrm{e4}}\right]{=}{\mathrm{e4}}{,}\left[{\mathrm{e3}}{,}{\mathrm{e5}}\right]{=}{\mathrm{e2}}{+}{\mathrm{e3}}{+}{\mathrm{e5}}{-}{\mathrm{e6}}{-}{\mathrm{e7}}{,}\left[{\mathrm{e3}}{,}{\mathrm{e6}}\right]{=}{-}{\mathrm{α}}{}{\mathrm{e4}}{,}\left[{\mathrm{e3}}{,}{\mathrm{e7}}\right]{=}{\mathrm{e1}}{-}{\mathrm{e2}}{,}\left[{\mathrm{e4}}{,}{\mathrm{e5}}\right]{=}{\mathrm{e4}}{,}\left[{\mathrm{e5}}{,}{\mathrm{e7}}\right]{=}{-}{2}{}{\mathrm{e1}}{+}{\mathrm{e2}}{+}{\mathrm{e6}}\right]{,}\left[\left[\left[{0}{,}{-}{1}{,}{0}{,}{0}{,}{0}{,}{1}{,}{0}\right]{,}\left[{0}{,}{0}{,}{0}{,}{-}{1}{,}{0}{,}{0}{,}{0}\right]{,}\left[{-}{1}{,}{0}{,}{0}{,}{0}{,}{0}{,}{1}{,}{0}\right]\right]\right]$ (4.6)

Label the vectors in h (Alg1) by H1, H2, ... H7.

 Alg > DGsetup(L1, [H], [omega]):

Re-express the vectors in j (originally viewed as vectors in the Lie algebra Alg) as vectors in Alg1.

 Alg1 > J := map(DGzip,Comp1[1], [H1, H2, H3, H4, H5, H6, H7], "plus");
 ${J}{≔}\left[{-}{\mathrm{H2}}{+}{\mathrm{H6}}{,}{-}{\mathrm{H4}}{,}{-}{\mathrm{H1}}{+}{\mathrm{H6}}\right]$ (4.7)

Calculate the structure equations for the quotient H/J using the vectors in C as representative vectors and, at the same time, calculate the matrix for the projection map pi_H.

 Alg1 > C2 := [H2 + H6, H3, H5, H7 + H5];
 ${\mathrm{C2}}{≔}\left[{\mathrm{H2}}{+}{\mathrm{H6}}{,}{\mathrm{H3}}{,}{\mathrm{H5}}{,}{\mathrm{H7}}{+}{\mathrm{H5}}\right]$ (4.8)
 Alg1 > L2, P2 := QuotientAlgebra(J, C2, Alg2, "Matrix");

Initialize the quotient algebra H/J and label the basis vectors A1, A2, A3, A4.

 Alg1 > DGsetup(L2, [A], [omega]);
 ${\mathrm{Lie algebra: Alg2}}$ (4.9)

Define the projection map piH : H --> H/J.

 Alg2 > piH := Transformation(Alg1, Alg2, P2);
 ${\mathrm{piH}}{≔}\left[\left[{\mathrm{H1}}{,}\frac{{\mathrm{A1}}}{{2}}\right]{,}\left[{\mathrm{H2}}{,}\frac{{\mathrm{A1}}}{{2}}\right]{,}\left[{\mathrm{H3}}{,}{\mathrm{A2}}\right]{,}\left[{\mathrm{H4}}{,}{0}{}{\mathrm{A1}}\right]{,}\left[{\mathrm{H5}}{,}{\mathrm{A3}}\right]{,}\left[{\mathrm{H6}}{,}\frac{{\mathrm{A1}}}{{2}}\right]{,}\left[{\mathrm{H7}}{,}{-}{\mathrm{A3}}{+}{\mathrm{A4}}\right]\right]$ (4.10)

Define the 'cross-section'  Sigma : H/J to H to piH.

 Alg2 > Sigma :=Transformation([[A1, 2 &mult H1], [A2,H3], [A3, H5], [A4, H7 &plus H5]]);
 ${\mathrm{Σ}}{≔}\left[\left[{\mathrm{A1}}{,}{2}{}{\mathrm{H1}}\right]{,}\left[{\mathrm{A2}}{,}{\mathrm{H3}}\right]{,}\left[{\mathrm{A3}}{,}{\mathrm{H5}}\right]{,}\left[{\mathrm{A4}}{,}{\mathrm{H5}}{+}{\mathrm{H7}}\right]\right]$ (4.11)
 Alg1 > ComposeTransformations(piH, Sigma);
 $\left[\left[{\mathrm{A1}}{,}{\mathrm{A1}}\right]{,}\left[{\mathrm{A2}}{,}{\mathrm{A2}}\right]{,}\left[{\mathrm{A3}}{,}{\mathrm{A3}}\right]{,}\left[{\mathrm{A4}}{,}{\mathrm{A4}}\right]\right]$ (4.12)

Step 2.  Calculate the structure equations for m = h + k and initialize the result as Alg3.  Define the inclusion map iota : h ->m.

 Alg2 > m := MinimalIdeal([op(h), op(k)]);
 ${m}{≔}\left[{\mathrm{e1}}{,}{\mathrm{e2}}{+}{\mathrm{e6}}{,}{\mathrm{e3}}{-}{\mathrm{e6}}{,}{\mathrm{e4}}{,}{\mathrm{e5}}{,}{\mathrm{e7}}{,}{\mathrm{e8}}{,}{\mathrm{e2}}{-}{\mathrm{e7}}\right]$ (4.13)
 Alg > L3 := LieAlgebraData(m, Alg3);
 ${\mathrm{L3}}{≔}\left[\left[{\mathrm{e1}}{,}{\mathrm{e3}}\right]{=}{\mathrm{e1}}{+}{\mathrm{e2}}{+}{\mathrm{α}}{}{\mathrm{e4}}{-}{2}{}{\mathrm{e6}}{,}\left[{\mathrm{e1}}{,}{\mathrm{e5}}\right]{=}{-}{\mathrm{e1}}{-}{2}{}{\mathrm{e2}}{+}{3}{}{\mathrm{e6}}{,}\left[{\mathrm{e1}}{,}{\mathrm{e7}}\right]{=}{-}{\mathrm{e2}}{+}{\mathrm{e6}}{,}\left[{\mathrm{e1}}{,}{\mathrm{e8}}\right]{=}{\mathrm{e1}}{-}{\mathrm{e6}}{,}\left[{\mathrm{e2}}{,}{\mathrm{e3}}\right]{=}{-}{\mathrm{e1}}{+}{\mathrm{e2}}{+}{\mathrm{α}}{}{\mathrm{e4}}{,}\left[{\mathrm{e2}}{,}{\mathrm{e5}}\right]{=}{2}{}{\mathrm{e1}}{-}{\mathrm{e2}}{-}{\mathrm{e6}}{,}\left[{\mathrm{e2}}{,}{\mathrm{e7}}\right]{=}{\mathrm{e1}}{-}{\mathrm{e6}}{,}\left[{\mathrm{e2}}{,}{\mathrm{e8}}\right]{=}{\mathrm{e2}}{-}{\mathrm{e6}}{,}\left[{\mathrm{e3}}{,}{\mathrm{e4}}\right]{=}{\mathrm{e4}}{,}\left[{\mathrm{e3}}{,}{\mathrm{e5}}\right]{=}{\mathrm{e2}}{+}{\mathrm{e3}}{+}{\mathrm{e5}}{-}{\mathrm{e6}}{-}{\mathrm{e7}}{,}\left[{\mathrm{e3}}{,}{\mathrm{e6}}\right]{=}{-}{\mathrm{α}}{}{\mathrm{e4}}{,}\left[{\mathrm{e3}}{,}{\mathrm{e7}}\right]{=}{\mathrm{e1}}{-}{\mathrm{e2}}{,}\left[{\mathrm{e3}}{,}{\mathrm{e8}}\right]{=}{\mathrm{e1}}{-}{\mathrm{e2}}{,}\left[{\mathrm{e4}}{,}{\mathrm{e5}}\right]{=}{\mathrm{e4}}{,}\left[{\mathrm{e5}}{,}{\mathrm{e7}}\right]{=}{-}{2}{}{\mathrm{e1}}{+}{\mathrm{e2}}{+}{\mathrm{e6}}{,}\left[{\mathrm{e5}}{,}{\mathrm{e8}}\right]{=}{-}{2}{}{\mathrm{e1}}{+}{\mathrm{e2}}{+}{\mathrm{e6}}{,}\left[{\mathrm{e7}}{,}{\mathrm{e8}}\right]{=}{-}{\mathrm{e1}}{+}{\mathrm{e2}}\right]$ (4.14)

Label the basis vectors for m (Alg3) by M1, M2 , ...

 Alg > DGsetup(L3, [M], [omega]);
 ${\mathrm{Lie algebra: Alg3}}$ (4.15)

Define the inclusion map iota.

 Alg3 > iota := Transformation([[H1, M1], [H2, M2], [H3, M3],[H4, M4], [H5, M5], [H6, M6], [H7, M7]]);
 ${\mathrm{ι}}{≔}\left[\left[{\mathrm{H1}}{,}{\mathrm{M1}}\right]{,}\left[{\mathrm{H2}}{,}{\mathrm{M2}}\right]{,}\left[{\mathrm{H3}}{,}{\mathrm{M3}}\right]{,}\left[{\mathrm{H4}}{,}{\mathrm{M4}}\right]{,}\left[{\mathrm{H5}}{,}{\mathrm{M5}}\right]{,}\left[{\mathrm{H6}}{,}{\mathrm{M6}}\right]{,}\left[{\mathrm{H7}}{,}{\mathrm{M7}}\right]\right]$ (4.16)

Step 3. Re-express the vectors in the subalgebra k as elements of Alg3. Calculate the quotient of m (Alg3) by k and initialize the result as Alg4. Calculate the projection map piM.

 Alg3 > Comp := GetComponents(k,m);
 ${\mathrm{Comp}}{≔}\left[\left[{1}{,}{0}{,}{0}{,}{0}{,}{0}{,}{-}{1}{,}{0}{,}{0}\right]{,}\left[{0}{,}{0}{,}{0}{,}{0}{,}{0}{,}{0}{,}{0}{,}{1}\right]{,}\left[{0}{,}{0}{,}{0}{,}{1}{,}{0}{,}{0}{,}{0}{,}{0}\right]{,}\left[{0}{,}{1}{,}{0}{,}{0}{,}{0}{,}{-}{1}{,}{0}{,}{-}{1}\right]\right]$ (4.17)
 Alg > K := map(DGzip, Comp, [M1, M2, M3, M4, M5, M6, M7, M8], "plus");
 ${K}{≔}\left[{\mathrm{M1}}{-}{\mathrm{M6}}{,}{\mathrm{M8}}{,}{\mathrm{M4}}{,}{\mathrm{M2}}{-}{\mathrm{M6}}{-}{\mathrm{M8}}\right]$ (4.18)

Use the vectors in C4 as representative vectors for the quotient m/k.

 Alg3 > C4 := evalDG([M2 + M6 + M8, M3, M5, M7]);
 ${\mathrm{C4}}{≔}\left[{\mathrm{M2}}{+}{\mathrm{M6}}{+}{\mathrm{M8}}{,}{\mathrm{M3}}{,}{\mathrm{M5}}{,}{\mathrm{M7}}\right]$ (4.19)
 Alg3 > L4, P4:=  QuotientAlgebra(K,C4,Alg4, "Matrix");
 Alg3 > DGsetup(L4, [B],[omega]);
 ${\mathrm{Lie algebra: Alg4}}$ (4.20)
 Alg4 > piM := Transformation(Alg3, Alg4, P4);
 ${\mathrm{piM}}{≔}\left[\left[{\mathrm{M1}}{,}\frac{{\mathrm{B1}}}{{2}}\right]{,}\left[{\mathrm{M2}}{,}\frac{{\mathrm{B1}}}{{2}}\right]{,}\left[{\mathrm{M3}}{,}{\mathrm{B2}}\right]{,}\left[{\mathrm{M4}}{,}{0}{}{\mathrm{B1}}\right]{,}\left[{\mathrm{M5}}{,}{\mathrm{B3}}\right]{,}\left[{\mathrm{M6}}{,}\frac{{\mathrm{B1}}}{{2}}\right]{,}\left[{\mathrm{M7}}{,}{\mathrm{B4}}\right]{,}\left[{\mathrm{M8}}{,}{0}{}{\mathrm{B1}}\right]\right]$ (4.21)

Step 4.  Display the two quotient algebras h/j (Alg2) and m/k (Alg4).

 Alg4 > MultiplicationTable(Alg2, "LieTable");
 Alg2 > MultiplicationTable(Alg4, "LieTable");

Construct the isomorphism psi from Alg2 to Alg4.

 Alg4 > psi := ComposeTransformations(piM, iota, Sigma);
 ${\mathrm{ψ}}{≔}\left[\left[{\mathrm{A1}}{,}{\mathrm{B1}}\right]{,}\left[{\mathrm{A2}}{,}{\mathrm{B2}}\right]{,}\left[{\mathrm{A3}}{,}{\mathrm{B3}}\right]{,}\left[{\mathrm{A4}}{,}{\mathrm{B3}}{+}{\mathrm{B4}}\right]\right]$ (4.22)

Check that psi is a Lie algebra homomorphism.  Check the psi is an isomorphism by calculating its inverse.

 Alg4 > Query(Alg2, Alg4, psi, "Homomorphism");
 ${\mathrm{true}}$ (4.23)
 Alg4 > InverseTransformation(psi);
 $\left[\left[{\mathrm{B1}}{,}{\mathrm{A1}}\right]{,}\left[{\mathrm{B2}}{,}{\mathrm{A2}}\right]{,}\left[{\mathrm{B3}}{,}{\mathrm{A3}}\right]{,}\left[{\mathrm{B4}}{,}{-}{\mathrm{A3}}{+}{\mathrm{A4}}\right]\right]$ (4.24)
 Alg2 >

The Third Isomorphism Theorem

The Third Isomorphism Theorem states that if h and k are ideals in a Lie algebra g, with h a subset of k, then k/h is an ideal in g/h and (g/h)/ (k/h) is isomorphic to g/k.  We shall construct this isomorphism for the following ideals.

 > with(DifferentialGeometry): with(LieAlgebras):

First define the ambient Lie algebra>

 Alg2 > L := _DG([["LieAlgebra", Alg, [8]], [[[1, 2, 1], 1], [[1, 2, 7], -1], [[1, 3, 2], 1], [[1, 3, 4], alpha], [[1, 3, 6], 1], [[1, 3, 7], -1], [[1, 5, 1], -1], [[1, 5, 2], -2], [[1, 5, 6], -2], [[1, 5, 7], 3], [[1, 6, 1], -1], [[1, 6, 7], 1], [[1, 8, 2], -1], [[1, 8, 6], -1], [[1, 8, 7], 1], [[2, 3, 1], -1], [[2, 3, 4], alpha], [[2, 3, 7], 1], [[2, 5, 1], 2], [[2, 5, 2], -1], [[2, 5, 6], -1], [[2, 5, 7], -1], [[2, 6, 2], -1], [[2, 6, 6], -1], [[2, 6, 7], 1], [[2, 8, 1], 1], [[2, 8, 2], -1], [[2, 8, 6], -1], [[3, 4, 4], 1], [[3, 5, 2], 1], [[3, 5, 3], 1], [[3, 5, 5], 1], [[3, 5, 7], -1], [[3, 5, 8], -1], [[3, 7, 4], -alpha], [[3, 8, 1], 1], [[3, 8, 7], -1], [[4, 5, 4], 1], [[5, 8, 1], -2], [[5, 8, 2], 1], [[5, 8, 6], 1], [[5, 8, 7], 1], [[6, 8, 2], 1], [[6, 8, 6], 1], [[6, 8, 7], -1]]]);
 ${L}{≔}\left[\left[{\mathrm{e1}}{,}{\mathrm{e2}}\right]{=}{\mathrm{e1}}{-}{\mathrm{e7}}{,}\left[{\mathrm{e1}}{,}{\mathrm{e3}}\right]{=}{\mathrm{e2}}{+}{\mathrm{α}}{}{\mathrm{e4}}{+}{\mathrm{e6}}{-}{\mathrm{e7}}{,}\left[{\mathrm{e1}}{,}{\mathrm{e5}}\right]{=}{-}{\mathrm{e1}}{-}{2}{}{\mathrm{e2}}{-}{2}{}{\mathrm{e6}}{+}{3}{}{\mathrm{e7}}{,}\left[{\mathrm{e1}}{,}{\mathrm{e6}}\right]{=}{-}{\mathrm{e1}}{+}{\mathrm{e7}}{,}\left[{\mathrm{e1}}{,}{\mathrm{e8}}\right]{=}{-}{\mathrm{e2}}{-}{\mathrm{e6}}{+}{\mathrm{e7}}{,}\left[{\mathrm{e2}}{,}{\mathrm{e3}}\right]{=}{-}{\mathrm{e1}}{+}{\mathrm{α}}{}{\mathrm{e4}}{+}{\mathrm{e7}}{,}\left[{\mathrm{e2}}{,}{\mathrm{e5}}\right]{=}{2}{}{\mathrm{e1}}{-}{\mathrm{e2}}{-}{\mathrm{e6}}{-}{\mathrm{e7}}{,}\left[{\mathrm{e2}}{,}{\mathrm{e6}}\right]{=}{-}{\mathrm{e2}}{-}{\mathrm{e6}}{+}{\mathrm{e7}}{,}\left[{\mathrm{e2}}{,}{\mathrm{e8}}\right]{=}{\mathrm{e1}}{-}{\mathrm{e2}}{-}{\mathrm{e6}}{,}\left[{\mathrm{e3}}{,}{\mathrm{e4}}\right]{=}{\mathrm{e4}}{,}\left[{\mathrm{e3}}{,}{\mathrm{e5}}\right]{=}{\mathrm{e2}}{+}{\mathrm{e3}}{+}{\mathrm{e5}}{-}{\mathrm{e7}}{-}{\mathrm{e8}}{,}\left[{\mathrm{e3}}{,}{\mathrm{e7}}\right]{=}{-}{\mathrm{α}}{}{\mathrm{e4}}{,}\left[{\mathrm{e3}}{,}{\mathrm{e8}}\right]{=}{\mathrm{e1}}{-}{\mathrm{e7}}{,}\left[{\mathrm{e4}}{,}{\mathrm{e5}}\right]{=}{\mathrm{e4}}{,}\left[{\mathrm{e5}}{,}{\mathrm{e8}}\right]{=}{-}{2}{}{\mathrm{e1}}{+}{\mathrm{e2}}{+}{\mathrm{e6}}{+}{\mathrm{e7}}{,}\left[{\mathrm{e6}}{,}{\mathrm{e8}}\right]{=}{\mathrm{e2}}{+}{\mathrm{e6}}{-}{\mathrm{e7}}\right]$ (5.1)
 Alg2 > DGsetup(L);
 ${\mathrm{Lie algebra: Alg}}$ (5.2)

Define the ideals h and k.

 Alg > h := MinimalIdeal([e7]);
 ${h}{≔}\left[{\mathrm{e4}}{,}{\mathrm{e7}}\right]$ (5.3)
 Alg > k := MinimalIdeal([e1, e2]);
 ${k}{≔}\left[{\mathrm{e1}}{,}{\mathrm{e2}}{,}{\mathrm{e4}}{,}{\mathrm{e6}}{,}{\mathrm{e7}}\right]$ (5.4)

Let m = g/h and let q = k/h, as a subalgebra of m. The isomorphism phi : g/k -> (g/h)/(g/k) = m/q is given by the composition of 3 maps g/k --> g --> g/h --> m/qThe first map is any vector space map Sigma : g/k --> g such that pi_k o Sigma = identity on g/k.  The second map pi_g2 : g --> g/h is the canonical projection map  inclusion. The third map is the projection pi_m from m to the quotient Lie algebra m/q.  We construct each of these maps, calculate the composition psi = pi_m o pi_g2 o Sigma, and check that psi is a Lie algebra isomorphism.

Step 1. Construct the quotient algebra g/k, initialize as Alg1 and define the map Sigma. We use the vectors in C1 as representatives for the cosets in g/k

 Alg > C1:= evalDG([e3,e5,e3-e8]);
 ${\mathrm{C1}}{≔}\left[{\mathrm{e3}}{,}{\mathrm{e5}}{,}{\mathrm{e3}}{-}{\mathrm{e8}}\right]$ (5.5)
 Alg > L1, P1 := QuotientAlgebra(k, C1, Alg1, "Matrix");

Initialize the Lie algebra g/k (Alg1) and use A1, A2, A3 as labels for the basis vectors.

 Alg > DGsetup(L1, [A], [omega]);
 ${\mathrm{Lie algebra: Alg1}}$ (5.6)

Use the matrix P1 to define the canonical projection from g (Alg) to g/k (Alg1).

 Alg1 > pi_G1 := Transformation(Alg, Alg1, P1);
 ${\mathrm{pi_G1}}{≔}\left[\left[{\mathrm{e1}}{,}{0}{}{\mathrm{A1}}\right]{,}\left[{\mathrm{e2}}{,}{0}{}{\mathrm{A1}}\right]{,}\left[{\mathrm{e3}}{,}{\mathrm{A1}}\right]{,}\left[{\mathrm{e4}}{,}{0}{}{\mathrm{A1}}\right]{,}\left[{\mathrm{e5}}{,}{\mathrm{A2}}\right]{,}\left[{\mathrm{e6}}{,}{0}{}{\mathrm{A1}}\right]{,}\left[{\mathrm{e7}}{,}{0}{}{\mathrm{A1}}\right]{,}\left[{\mathrm{e8}}{,}{\mathrm{A1}}{-}{\mathrm{A3}}\right]\right]$ (5.7)
 Alg1 > Sigma := Transformation([[A1, e3], [A2, e5], [A3, -e8 +e3]]);
 ${\mathrm{Σ}}{≔}\left[\left[{\mathrm{A1}}{,}{\mathrm{e3}}\right]{,}\left[{\mathrm{A2}}{,}{\mathrm{e5}}\right]{,}\left[{\mathrm{A3}}{,}{\mathrm{e3}}{-}{\mathrm{e8}}\right]\right]$ (5.8)
 Alg > ComposeTransformations(pi_G1, Sigma);
 $\left[\left[{\mathrm{A1}}{,}{\mathrm{A1}}\right]{,}\left[{\mathrm{A2}}{,}{\mathrm{A2}}\right]{,}\left[{\mathrm{A3}}{,}{\mathrm{A3}}\right]\right]$ (5.9)

Step 2.  Construct the quotient space m = g/h and initialize as Alg3. Project the vectors in k into g/h to obtain the ideal q. We use the vectors in C2 as representatives for the cosets in g/h.

 Alg1 > ChangeFrame(Alg);
 ${\mathrm{Alg1}}$ (5.10)
 Alg > h;
 $\left[{\mathrm{e4}}{,}{\mathrm{e7}}\right]$ (5.11)
 Alg > C2 := evalDG([e1, e2, e3 + e5, e5, e6 - e8, e8]);
 ${\mathrm{C2}}{≔}\left[{\mathrm{e1}}{,}{\mathrm{e2}}{,}{\mathrm{e3}}{+}{\mathrm{e5}}{,}{\mathrm{e5}}{,}{\mathrm{e6}}{-}{\mathrm{e8}}{,}{\mathrm{e8}}\right]$ (5.12)
 Alg > L2, P2 := QuotientAlgebra(h, C2, Alg2, "Matrix");

Initialize the Lie algebra g/h (Alg2) and calculate the projection map.  Label the vectors in Alg2 as M1, M2, ...

 Alg > DGsetup(L2, [M], [omega]);
 ${\mathrm{Lie algebra: Alg2}}$ (5.13)
 Alg2 > pi_G2 := Transformation(Alg, Alg2, P2);
 ${\mathrm{pi_G2}}{≔}\left[\left[{\mathrm{e1}}{,}{\mathrm{M1}}\right]{,}\left[{\mathrm{e2}}{,}{\mathrm{M2}}\right]{,}\left[{\mathrm{e3}}{,}{\mathrm{M3}}{-}{\mathrm{M4}}\right]{,}\left[{\mathrm{e4}}{,}{0}{}{\mathrm{M1}}\right]{,}\left[{\mathrm{e5}}{,}{\mathrm{M4}}\right]{,}\left[{\mathrm{e6}}{,}{\mathrm{M5}}{+}{\mathrm{M6}}\right]{,}\left[{\mathrm{e7}}{,}{0}{}{\mathrm{M1}}\right]{,}\left[{\mathrm{e8}}{,}{\mathrm{M6}}\right]\right]$ (5.14)

Project each vector in k into g/h and check that the resulting list of vectors defines an ideal q in g/h (Alg2).

 Alg2 > Q0 := [seq(ApplyHomomorphism(pi_G2, x),  x= k)];
 ${\mathrm{Q0}}{≔}\left[{\mathrm{M1}}{,}{\mathrm{M2}}{,}{0}{}{\mathrm{M1}}{,}{\mathrm{M5}}{+}{\mathrm{M6}}{,}{0}{}{\mathrm{M1}}\right]$ (5.15)
 Alg2 > Q := DGbasis(Q0);
 ${Q}{≔}\left[{\mathrm{M1}}{,}{\mathrm{M2}}{,}{\mathrm{M5}}{+}{\mathrm{M6}}\right]$ (5.16)
 Alg2 > Query(Q, "Ideal");
 ${\mathrm{true}}$ (5.17)

Step 3.  Calculate the structure equations for the quotient algebra (g/h)/(k/h) = m/q = Alg2/ Q.  Initialize the result as Alg3 and calculate the projection map piM.  We use the vectors C3 as representatives for a basis for m/q.

 Alg2 > Q;
 $\left[{\mathrm{M1}}{,}{\mathrm{M2}}{,}{\mathrm{M5}}{+}{\mathrm{M6}}\right]$ (5.18)
 Alg2 > C3 := evalDG([M5 - M6, M3 +M4, M4]);
 ${\mathrm{C3}}{≔}\left[{\mathrm{M5}}{-}{\mathrm{M6}}{,}{\mathrm{M3}}{+}{\mathrm{M4}}{,}{\mathrm{M4}}\right]$ (5.19)
 Alg2 > L3, P3 := QuotientAlgebra(Q, C3, Alg3, "Matrix");
 Alg2 > DGsetup(L3, [B], [omega]);
 ${\mathrm{Lie algebra: Alg3}}$ (5.20)
 Alg3 > pi_M := Transformation(Alg2, Alg3, P3);
 ${\mathrm{pi_M}}{≔}\left[\left[{\mathrm{M1}}{,}{0}{}{\mathrm{B1}}\right]{,}\left[{\mathrm{M2}}{,}{0}{}{\mathrm{B1}}\right]{,}\left[{\mathrm{M3}}{,}{\mathrm{B2}}{-}{\mathrm{B3}}\right]{,}\left[{\mathrm{M4}}{,}{\mathrm{B3}}\right]{,}\left[{\mathrm{M5}}{,}\frac{{\mathrm{B1}}}{{2}}\right]{,}\left[{\mathrm{M6}}{,}{-}\frac{{\mathrm{B1}}}{{2}}\right]\right]$ (5.21)

Step 4.  Display the multiplication tables for g/k (Alg1) and (g/h)/(k/h) (Alg3).  Define the composition psi = pi_m o pi_g2 o Sigma, and check that psi is a Lie algebra isomorphism.

 Alg3 > MultiplicationTable(Alg1, "LieTable");
 Alg1 > MultiplicationTable(Alg3, "LieTable");
 Alg3 > psi := ComposeTransformations(pi_M, pi_G2, Sigma);
 ${\mathrm{ψ}}{≔}\left[\left[{\mathrm{A1}}{,}{\mathrm{B2}}{-}{2}{}{\mathrm{B3}}\right]{,}\left[{\mathrm{A2}}{,}{\mathrm{B3}}\right]{,}\left[{\mathrm{A3}}{,}\frac{{\mathrm{B1}}}{{2}}{+}{\mathrm{B2}}{-}{2}{}{\mathrm{B3}}\right]\right]$ (5.22)

We check that psi is an isomorphism by showing it is a homomorphism with non-singular Jacobian.

 Alg3 > Query(Alg1, Alg3, psi, "Homomorphism");
 ${\mathrm{true}}$ (5.23)
 Alg3 > J := Tools:-DGinfo(psi, "JacobianMatrix");
 Alg3 > LinearAlgebra:-Determinant(J);
 $\frac{{1}}{{2}}$ (5.24)