• A review of plotting in polar coordinates:
• Finding the limits of integration:
  • Setting up drd
    theta integrals
  • Setting up d
    thetadr integrals
  • Changing order of integration
• Integrating over a region in polar coordinates:
• Changing coordinates systems to integrate
• Extra credit -

Integration in polar coordinates

Worksheet by Mike May, S.J.- maymk@slu.edu

> restart:

A review of plotting in polar coordinates:

The first problem in trying to do double integrals in polar coordinates is to be able to sketch graphs in of functions described in polar coordinates. On your calculators you switch to polar mode. With Maple you use the coord=polar option on the plot command. You can either plot the curve either with r as a function of theta, or with both r and theta described as functions of a parameter t. When we plot in polar coordinates it is probably wise to use the scaling=CONSTRAINED option so the axes have the same scale.

> plot(cos(2*theta),theta=0..2*Pi, coords=polar, scaling=CONSTRAINED);
plot([2+sin(2*t),Pi*sin(t),t=0..Pi], coords=polar, scaling=CONSTRAINED);

To plot several curves together at the same time we use set notation, just like we did in Cartesian coordinates.

> plot({1,2*sin(theta)}, theta=0..2*Pi, coords=polar, scaling=CONSTRAINED);

Plotting several curves together lets up plot regions made of a number of curves. The region plotted below is the portion of an annulus between two specified angles.

> plot({[1+t,Pi/6,t=0..1],[1+t,Pi/3,t=0..1],[1,t,t=Pi/6..Pi/3],
[2,t,t=Pi/6..Pi/3],[0,0,t=0..0]},coords=polar, scaling=CONSTRAINED);

Exercise:

1) Plot the curves and . Find the points of intersection. (You may want to use either your calculator or a piece of paper to find the points of intersection.)

>

Once we can sketch curves, the problems involved in setting up an integral in polar coordinates are similar to the problems involved in setting up a double integral in Cartesian coordinates. The biggest problem is finding the correct limits of integration. We will also be concerned with switching the order of integration.

Finding the limits of integration:

Setting up drd integrals

Consider first the case of integrals using drd . Since dr is on the inside we have a region bounded by curves and with the value of bound by two constants. The integration with respect to r for a particular integrates along a radial line. The following block of code is designed to help you visualize what limits of integration mean.

> r:='r': theta := 'theta':
lowtheta := Pi/6;
hightheta := 3*Pi/2;
lowr := theta -> 1.5-sin(theta);
highr := theta -> 3 + cos(theta);
print(`Region of integration for `,
Int(Int(f(r, theta)*r,r=lowr(theta)..highr(theta)),
theta=lowtheta..hightheta));
inside := plot([lowr(theta), theta,theta=lowtheta..hightheta],
color=red, coords=polar, thickness=2):
outside := plot([highr(theta), theta,theta=lowtheta..hightheta],
color=green, coords=polar, thickness=2):
line := {}:
for i from 0 to 10 do
tval := evalf(lowtheta + i/10*(hightheta-lowtheta)):
line := line union
{[r,tval, r=evalf(lowr(tval))..evalf(highr(tval))]};
od:
plotlines := plot(line,coords=polar, color=blue) :
plots[display]({inside, outside, plotlines},scaling=CONSTRAINED);

Note that since we integrate with respect to r first, the r-limits are functions of theta while the theta limits are constants. WE integrate by first integrating, from the inside (red) curve to the outside (green) curve, along the radial lines.

Exercises:

2) Find the limits of integration to integrate over the region inside the curve and outside the curve r=1. Modify the code above to show that you have the correct region.

>

3) Find the limits of integration to integrate over the region inside the curve and outside the curve . Modify the code above to show that you have the correct region.

>

Setting up d dr integrals

Similarly we can set up integrals using drd . Now the region of integration is bounded by curves and with the value of r being bound by two constants. Instead of integrating first on radial lines, we start by integrating along circular arcs with a fixed value of r.

> r:='r': theta := 'theta':
lowr := 1;
highr := 5;
lowtheta := r -> Pi*r/6;
hightheta := r -> Pi*(2-r/12);
print(`Region of integration for `, Int(Int(f(r, theta)*r,
theta=lowtheta(r)..hightheta(r)),r=lowr..highr));
lowthetacurve := plot ([r,lowtheta(r), r=lowr..highr],
color=red, coords=polar, thickness=2) :
highthetacurve := plot ([r, hightheta(r), r=lowr..highr],
color=green, coords=polar, thickness=2) :
arcs := {} :
for i from 0 to 10 do
tempr := evalf(lowr + i/10*(highr-lowr)):
arcs := arcs union {[tempr, theta,
theta=lowtheta(tempr)..hightheta(tempr)]}:
od:
grapharcs := plot(arcs,coords=polar, color=blue) :
plots[display] ( {lowthetacurve, highthetacurve, grapharcs }
,scaling=CONSTRAINED) ;

Exercises:

4) Find the limits of integration to integrate over the region inside both curves and r=1. Modify the code above to show that you have the correct region. Explain why you want to use dthetadr rather than drdtheta for this problem.

>

5) Find the limits of integration to integrate over the region inside the curve and outsidethe curve . Modify the code above to show that you have the correct region.

>

Changing order of integration

Some regions can be described to use either drd or d dr. When we switch the order of integration we need to switch the limits as well.

Exercise:

6) The region inside the curve r=1 and outside the curve can be set up in either order. Find the limits of integration both ways. Show that you have the correct region.

>

Integrating over a region in polar coordinates:

Recall that dA is rdrd or r d dr. Thus to find the area of the region bounded by r=1, r=2, , and , we evaluate the integral .

> Int(Int(r,r=1..2),theta=Pi/6..Pi/3)=int(int(r,r=1..2),theta=Pi/6..Pi/3);

Exercises:

7) Find the area inside both curves r=1 and .

>

8) Integrate the function over the disk of radius 2 centered at the origin.

>

Changing coordinates systems to integrate

One of the reasons we want to be able to integrate in polar coordinates is that some integrals work out nicely in one coordinate system and are ugly in another. To change an integral in Cartesian into polar, we need to do several things. First sketch the region with its boundary curves. Then change the formulas of the boundary curves, the function to be integrated and dA into polar form. We are then ready to set up the integral and integrate.

Consider the integral .

> int(int(1/(a^2+x^2+y^2),y=-sqrt(b^2-x^2)..sqrt(b^2-x^2)),x=-b..b);

Depending on the version of Maple you are using, it either chokes on this integral, or gives an anwer involving functions we don't know how to evaluate. However the integral above converts to which can easily be done by hand using the substitution . Maple also has no problem with it.

> int(int(r/(a^2+r^2),theta=0..2*Pi),r=0..b);

Exercise:

9) Convert the integral to polar form and evaluate.

>

Extra credit -

At the beginning of this worksheet we plotted a region described by the parametric curve [2+sin(2*t),Pi*sin(t),t=0..Pi]. I am interested in finding the area of the region bounded by this curve to 3 decimal places. Find the area of the region and cleanly write up your work carefully justifying your method.

>

>